Create interaction test harness.

code/modules/interaction_tests/_interaction_tests.dm

@@ -0,0 +1,5 @@
+#ifdef UNIT_TESTS
+#include "attack_chain_interaction_test.dm"
+#include "interaction_test.dm"
+#include "test_puppeteer.dm"
+#endif

code/modules/interaction_tests/attack_chain_interaction_test.dm

@@ -0,0 +1,23 @@
+/datum/interaction_test/attack_chain
+
+/datum/interaction_test/attack_chain/Run()
+	var/datum/test_puppeteer/cultist = make_puppeteer()
+	var/datum/test_puppeteer/target = make_puppeteer_near(cultist)
+	cultist.puppet.mind.add_antag_datum(/datum/antagonist/cultist)
+	cultist.spawn_obj_in_hand(/obj/item/melee/cultblade/dagger)
+	cultist.set_intent("harm")
+	cultist.click_on(target)
+
+	if(!target.check_attack_log("Attacked with ritual dagger"))
+		Fail("non-cultist missing dagger attack log")
+	if(target.puppet.health == target.puppet.getMaxHealth())
+		Fail("cultist attacking non-cultist with dagger caused no damage")
+
+	target.rejuvenate()
+	target.puppet.mind.add_antag_datum(/datum/antagonist/cultist)
+
+	cultist.click_on(target)
+	if(target.puppet.health < target.puppet.getMaxHealth())
+		Fail("cultist attacking cultist with dagger caused damage")
+
+

code/modules/interaction_tests/interaction_test.dm

@@ -0,0 +1,34 @@
+/datum/interaction_test
+	var/list/tracked_puppets
+	var/succeeded = TRUE
+	var/list/fail_reasons
+
+/datum/interaction_test/Destroy()
+	for(var/datum/test_puppeteer/puppet in tracked_puppets)
+		qdel(puppet)
+	return ..()
+
+/datum/interaction_test/proc/Run()
+	SHOULD_CALL_PARENT(FALSE)
+	Fail("Run() not implemented")
+
+/datum/interaction_test/proc/Fail(reason = "No reason")
+	succeeded = FALSE
+
+	if(!istext(reason))
+		reason = "FORMATTED: [reason != null ? reason : "NULL"]"
+
+	LAZYADD(fail_reasons, reason)
+
+/datum/interaction_test/proc/make_puppeteer(carbon_type = /mob/living/carbon/human)
+	var/datum/test_puppeteer/puppet = new(carbon_type)
+	LAZYADD(tracked_puppets, puppet)
+	return puppet
+
+/datum/interaction_test/proc/make_puppeteer_near(datum/test_puppeteer/near, carbon_type = /mob/living/carbon/human)
+	for(var/turf/T in RANGE_TURFS(1, near.puppet.loc))
+		if(!is_blocked_turf(T, exclude_mobs = FALSE))
+			var/datum/test_puppeteer/new_puppet = new(carbon_type, T)
+			LAZYADD(tracked_puppets, new_puppet)
+			return new_puppet
+

code/modules/interaction_tests/test_puppeteer.dm

@@ -0,0 +1,49 @@
+/datum/test_puppeteer
+	var/mob/living/carbon/puppet
+	var/list/tracked_atoms
+
+/datum/test_puppeteer/New(carbon_type, turf/initial_location)
+	if(!initial_location)
+		initial_location = locate(179, 136, 1) // Center of admin testing area
+	puppet = new carbon_type(initial_location)
+	var/datum/mind/new_mind = new("interaction_test_[rand(1, 999999)]")
+	new_mind.transfer_to(puppet)
+
+/datum/test_puppeteer/proc/spawn_obj_in_hand(obj_type)
+	var/obj/new_obj = new obj_type(null)
+	puppet.put_in_hands(new_obj)
+	LAZYADD(tracked_atoms, new_obj)
+	return new_obj
+
+/datum/test_puppeteer/proc/click_on(target, params)
+	var/datum/test_puppeteer/puppet_target = target
+	if(istype(puppet_target))
+		puppet.ClickOn(puppet_target.puppet, params)
+		return
+
+	puppet.ClickOn(target, params)
+
+/datum/test_puppeteer/proc/spawn_mob_nearby(mob_type)
+	for(var/turf/T in RANGE_TURFS(1, puppet))
+		if(!is_blocked_turf(T, exclude_mobs = FALSE))
+			var/mob/new_mob = new mob_type(T)
+			LAZYADD(tracked_atoms, new_mob)
+			return new_mob
+
+/datum/test_puppeteer/Destroy(force, ...)
+	qdel(puppet)
+	for(var/atom/A in tracked_atoms)
+		qdel(A)
+
+	return ..()
+
+/datum/test_puppeteer/proc/check_attack_log(snippet)
+	for(var/log_text in puppet.attack_log_old)
+		if(findtextEx(log_text, snippet))
+			return TRUE
+
+/datum/test_puppeteer/proc/set_intent(new_intent)
+	puppet.a_intent_change(new_intent)
+
+/datum/test_puppeteer/proc/rejuvenate()
+	puppet.rejuvenate()

code/modules/unit_tests/test_runner.dm

@@ -76,6 +76,25 @@
 
 		CHECK_TICK
 
+	for(var/interaction_test_type in subtypesof(/datum/interaction_test))
+		var/datum/interaction_test/test = new interaction_test_type
+		test_logs[interaction_test_type] = list()
+		current_test = test
+		var/duration = REALTIMEOFDAY
+
+		test.Run()
+
+		durations[interaction_test_type] = REALTIMEOFDAY - duration
+		current_test = null
+
+		if(!test.succeeded)
+			failed_any_test = TRUE
+			test_logs[interaction_test_type] += test.fail_reasons
+
+		qdel(test)
+
+		CHECK_TICK
+
 	SSticker.reboot_helper("Unit Test Reboot", "tests ended", 0)
 
 

paradise.dme

@@ -2050,6 +2050,7 @@
 #include "code\modules\instruments\songs\_song_ui.dm"
 #include "code\modules\instruments\songs\play_legacy.dm"
 #include "code\modules\instruments\songs\play_synthesized.dm"
+#include "code\modules\interaction_tests\_interaction_tests.dm"
 #include "code\modules\lavaland\caves_theme.dm"
 #include "code\modules\lavaland\lavaland_theme.dm"
 #include "code\modules\library\book.dm"

tools/ci/unticked_files.py

@@ -22,6 +22,7 @@
     'paradise.dme',
     'code/modules/tgs/includes.dm',
     'code/modules/unit_tests/_unit_tests.dm',
+    'code/modules/interaction_tests/_interaction_tests.dm',
 ]
 
 IGNORE_FILES = {