introduce native api to access RuntimeExecutor (facebook#42758)

Summary:

Changelog: [Added][iOS] introduce native api to access RuntimeExecutor

The goal of this API is to provide a safe way to access the `jsi::runtime` in bridgeless mode. The decision to limit access to the runtime in bridgeless was a conscious one - the runtime pointer is not thread-safe and its lifecycle must be managed correctly by owners.

However, interacting with the runtime is an advanced use case we would want to support. Our recommended ways to access the runtime in bridgeless mode is either 1) via the RuntimeExecutor, or 2) via a C++ TurboModule.

This diff introduces the API that would allow for 1). The integration consists of these parts:
- wrapper object for RuntimeExecutor access, `RCTRuntimeExecutorProvider`. The wrapper is necessary so it can be referenced in swift
- new API, i.e. `RCTRuntimeExecutionModule`, for modules to access the RuntimeExecutor block
- integration within the bridgeless infrastructure

Differential Revision: D53256188

packages/react-native/React/Base/RCTRuntimeExecutionModule.h

@@ -0,0 +1,18 @@
+/*
+ * Copyright (c) Meta Platforms, Inc. and affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+@class RCTRuntimeExecutorProvider;
+
+/**
+ * Have your module conform to this protocol to access the RuntimeExecutor.
+ * Only available in the bridgeless runtime.
+ */
+@protocol RCTRuntimeExecutionModule <NSObject>
+
+@property (nonatomic, nullable, readwrite) RCTRuntimeExecutorProvider *runtimeExecutorProvider;
+
+@end

packages/react-native/ReactCommon/react/nativemodule/core/platform/ios/ReactCommon/RCTRuntimeExecutorProvider.h

@@ -0,0 +1,31 @@
+/*
+ * Copyright (c) Meta Platforms, Inc. and affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#import <ReactCommon/RuntimeExecutor.h>
+#import <jsi/jsi.h>
+
+typedef void (^RCTJSIRuntimeHandlingBlock)(facebook::jsi::Runtime &runtime);
+typedef void (^RCTRuntimeExecutor)(_Nonnull RCTJSIRuntimeHandlingBlock);
+
+NS_ASSUME_NONNULL_BEGIN
+
+@interface RCTRuntimeExecutorProvider : NSObject
+
+- (instancetype)init NS_UNAVAILABLE;
+
+/**
+ Initializes an object that wraps ways to access the RuntimeExecutor.
+
+ @param runtimeExecutorBlock A block that provides thread-safe access to jsi::runtime.
+ */
+- (instancetype)initWithRuntimeExecutor:(facebook::react::RuntimeExecutor)runtimeExecutor NS_DESIGNATED_INITIALIZER;
+
+- (RCTRuntimeExecutor)runtimeExecutor;
+
+@end
+
+NS_ASSUME_NONNULL_END

packages/react-native/ReactCommon/react/nativemodule/core/platform/ios/ReactCommon/RCTRuntimeExecutorProvider.mm

@@ -0,0 +1,38 @@
+/*
+ * Copyright (c) Meta Platforms, Inc. and affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#import "RCTRuntimeExecutorProvider.h"
+
+@implementation RCTRuntimeExecutorProvider {
+  facebook::react::RuntimeExecutor _runtimeExecutor;
+}
+
+#pragma mark - Initializer
+
+- (instancetype)initWithRuntimeExecutor:(facebook::react::RuntimeExecutor)runtimeExecutor
+{
+  if (self = [super init]) {
+    _runtimeExecutor = runtimeExecutor;
+  }
+
+  return self;
+}
+
+#pragma mark - Public API
+
+- (RCTRuntimeExecutor)runtimeExecutor
+{
+  __weak __typeof(self) weakSelf = self;
+  return ^(RCTJSIRuntimeHandlingBlock block) {
+    __strong __typeof(self) strongSelf = weakSelf;
+    if (strongSelf && strongSelf->_runtimeExecutor) {
+      strongSelf->_runtimeExecutor([=](facebook::jsi::Runtime &runtime) { block(runtime); });
+    }
+  };
+}
+
+@end

packages/react-native/ReactCommon/react/nativemodule/core/platform/ios/ReactCommon/RCTTurboModuleManager.h

@@ -15,8 +15,11 @@
 #import <React/RCTTurboModuleRegistry.h>
 #import <ReactCommon/RuntimeExecutor.h>
 #import <ReactCommon/TurboModuleBinding.h>
+
 #import "RCTTurboModule.h"
 
+@class RCTTurboModuleManager;
+
 @protocol RCTTurboModuleManagerDelegate <NSObject>
 
 /**
@@ -52,6 +55,12 @@
 
 @end
 
+@protocol RCTTurboModuleManagerRuntimeHandler <NSObject>
+
+- (facebook::react::RuntimeExecutor)runtimeExecutorForTurboModuleManager:(RCTTurboModuleManager *)turboModuleManager;
+
+@end
+
 @interface RCTTurboModuleManager : NSObject <RCTTurboModuleRegistry>
 
 - (instancetype)initWithBridge:(RCTBridge *)bridge
@@ -67,4 +76,6 @@
 
 - (void)invalidate;
 
+@property (nonatomic, weak, readwrite) id<RCTTurboModuleManagerRuntimeHandler> runtimeHandler;
+
 @end

packages/react-native/ReactCommon/react/nativemodule/core/platform/ios/ReactCommon/RCTTurboModuleManager.mm

@@ -7,6 +7,7 @@
 
 #import "RCTTurboModuleManager.h"
 #import "RCTInteropTurboModule.h"
+#import "RCTRuntimeExecutorProvider.h"
 
 #import <atomic>
 #import <cassert>
@@ -24,8 +25,8 @@
 #import <React/RCTLog.h>
 #import <React/RCTModuleData.h>
 #import <React/RCTPerformanceLogger.h>
+#import <React/RCTRuntimeExecutionModule.h>
 #import <React/RCTUtils.h>
-#import <ReactCommon/RuntimeExecutor.h>
 #import <ReactCommon/TurboCxxModule.h>
 #import <ReactCommon/TurboModulePerfLogger.h>
 #import <ReactCommon/TurboModuleUtils.h>
@@ -676,6 +677,13 @@ - (BOOL)_shouldCreateObjCModule:(Class)moduleClass
     }
   }
 
+  // This is a more performant alternative for conformsToProtocol:@protocol(RCTRuntimeExecutionModule)
+  if ([module respondsToSelector:@selector(setRuntimeExecutorProvider:)]) {
+    RCTRuntimeExecutorProvider *runtimeExecutorProvider = [[RCTRuntimeExecutorProvider alloc]
+        initWithRuntimeExecutor:[_runtimeHandler runtimeExecutorForTurboModuleManager:self]];
+    [(id<RCTRuntimeExecutionModule>)module setRuntimeExecutorProvider:runtimeExecutorProvider];
+  }
+
   /**
    * Some modules need their own queues, but don't provide any, so we need to create it for them.
    * These modules typically have the following:

packages/react-native/ReactCommon/react/runtime/platform/ios/ReactCommon/RCTInstance.mm

@@ -63,7 +63,7 @@ void RCTInstanceSetRuntimeDiagnosticFlags(NSString *flags)
   sRuntimeDiagnosticFlags = [flags copy];
 }
 
-@interface RCTInstance () <RCTTurboModuleManagerDelegate>
+@interface RCTInstance () <RCTTurboModuleManagerDelegate, RCTTurboModuleManagerRuntimeHandler>
 @end
 
 @implementation RCTInstance {
@@ -208,6 +208,17 @@ - (Class)getModuleClassFromName:(const char *)name
   return nullptr;
 }
 
+#pragma mark - RCTTurboModuleManagerRuntimeHandler
+
+- (RuntimeExecutor)runtimeExecutorForTurboModuleManager:(RCTTurboModuleManager *)turboModuleManager
+{
+  if (_valid) {
+    return _reactInstance->getBufferedRuntimeExecutor();
+  }
+
+  return nullptr;
+}
+
 #pragma mark - Private
 
 - (void)_start
@@ -259,6 +270,7 @@ - (void)_start
       bridgeModuleDecorator:_bridgeModuleDecorator
                    delegate:self
                   jsInvoker:std::make_shared<BridgelessJSCallInvoker>(bufferedRuntimeExecutor)];
+  _turboModuleManager.runtimeHandler = self;
 
 #if RCT_DEV
   /**