Added more test macro wrapping

cmake/ADIOSFunctions.cmake

@@ -149,7 +149,11 @@ function(SetupTestPipeline basename pipeline do_setup)
         -DDIR_NAME=${CMAKE_CURRENT_BINARY_DIR}/${basename}
         -P ${PROJECT_SOURCE_DIR}/cmake/EmptyDir.cmake
     )
-    list(INSERT pipeline 0 "Setup")
+    if(pipeline)
+      list(INSERT pipeline 0 "Setup")
+    else()
+      set(pipeline "Setup;")
+    endif()
   endif()
   unset(prev_suffix)
   foreach(curr_step IN LISTS pipeline)

testing/CMakeLists.txt

@@ -15,23 +15,52 @@ else()
 endif()
 
 include(GoogleTest)
-function(gtest_add_tests_helper testname mpi pfx sfx)
-  set(tgt Test.${pfx}${testname})
+# gtest_add_tests_helper:
+# Create a wrapper around gtest_add_tests that uses common patterns for test
+# names, execurtable names, mpi usage, etc.
+# 
+# Arguments:
+#   testname - The basename of the test file
+#   mpi      - TRUE - build with MPI, execute with mpiexec
+#              FALSE - no mpi
+#              NOEXEC - build with MPI but don't execute with MPI
+#   src_pfx  - Source filename prefix, Test${src_pfs}${testname}.cpp
+#   tst_pfx  - Test name prefix to be added to CTest
+#   tst_sfx  - Test name suffix to be added to CTest
+# all additional arguments are passed directly to gtest_add_tests
+#
+# Example:
+#   You have a gtest file, TestFooThings.cpp that containst Test1 and Test2
+#   gtest functions that can be called with different sets of arguments.
+#
+#     gtest_add_tests_helper(Things TRUE Foo Foo. .Bar EXTRA_ARGS "Bar")
+#     gtest_add_tests_helper(Things TRUE Foo Foo. .Baz EXTRA_ARGS "Baz")
+#
+#  will create the executable Test.Foo.Things and add the tests
+#    Foo.Things.Test1.Bar
+#    Foo.Things.Test2.Bar
+#    Foo.Things.Test1.Baz
+#    Foo.Things.Test2.Baz
+#
+function(gtest_add_tests_helper testname mpi src_pfx tst_pfx tst_sfx)
+  set(tgt Test.${tst_pfx}${testname})
   if(NOT TARGET ${tgt})
-    add_executable(${tgt} Test${testname}.cpp)
+    add_executable(${tgt} Test${src_pfx}${testname}.cpp)
     target_link_libraries(${tgt} adios2 gtest)
     if(mpi)
       target_link_libraries(${tgt} MPI::MPI_C)
     endif()
   endif()
-  if(mpi)
-    gtest_add_tests(TARGET ${tgt} TEST_PREFIX "${pfx}" TEST_SUFFIX "${sfx}"
+  if(mpi AND NOT mpi STREQUAL "NOEXEC")
+    gtest_add_tests(TARGET ${tgt}
+      TEST_PREFIX "${tst_pfx}" TEST_SUFFIX "${tst_sfx}"
       EXEC_WRAPPER ${MPIEXEC_COMMAND} TEST_LIST added_tests
       ${ARGN}
     )
     set_tests_properties(${added_tests} PROPERTIES PROCESSORS ${NUM_TEST_PROCS})
   else()
-    gtest_add_tests(TARGET ${tgt} TEST_PREFIX "${pfx}" TEST_SUFFIX "${sfx}"
+    gtest_add_tests(TARGET ${tgt}
+      TEST_PREFIX "${tst_pfx}" TEST_SUFFIX "${tst_sfx}"
       ${ARGN}
     )
   endif()

testing/adios2/bindings/C/CMakeLists.txt

@@ -9,9 +9,9 @@ else()
   set(mpi FALSE)
 endif()
 
-gtest_add_tests_helper(BPWriteTypes ${mpi} "Bindings.C." "")
-gtest_add_tests_helper(BPWriteReadMultiblock ${mpi} "Bindings.C." "")
-gtest_add_tests_helper(NullWriteRead ${mpi} "Bindings.C." "")
+gtest_add_tests_helper(WriteTypes ${mpi} BP Bindings.C. "")
+gtest_add_tests_helper(WriteReadMultiblock ${mpi} BP Bindings.C. "")
+gtest_add_tests_helper(NullWriteRead ${mpi} "" Bindings.C. "")
 if(mpi)
-  gtest_add_tests_helper(BPWriteAggregateReadLocal TRUE "Bindings.C." "")
+  gtest_add_tests_helper(WriteAggregateReadLocal TRUE BP Bindings.C. "")
 endif()

testing/adios2/engine/bp/CMakeLists.txt

@@ -9,52 +9,52 @@ file(MAKE_DIRECTORY ${BP3_DIR})
 file(MAKE_DIRECTORY ${BP4_DIR})
 
 macro(bp3_bp4_gtest_add_tests_helper testname)
-  gtest_add_tests_helper(${testname} ${test_mpi} Engine.BP. .BP3
+  gtest_add_tests_helper(${testname} ${test_mpi} BP Engine.BP. .BP3
     WORKING_DIRECTORY ${BP3_DIR} EXTRA_ARGS "BP3"
   )
-  gtest_add_tests_helper(${testname} ${test_mpi} Engine.BP. .BP4
+  gtest_add_tests_helper(${testname} ${test_mpi} BP Engine.BP. .BP4
     WORKING_DIRECTORY ${BP4_DIR} EXTRA_ARGS "BP4"
   )
 endmacro()
 
 add_subdirectory(operations)
 
-bp3_bp4_gtest_add_tests_helper(BPWriteReadADIOS2)
-bp3_bp4_gtest_add_tests_helper(BPWriteReadADIOS2fstream)
-bp3_bp4_gtest_add_tests_helper(BPWriteReadADIOS2stdio)
-bp3_bp4_gtest_add_tests_helper(BPWriteReadAsStreamADIOS2)
-bp3_bp4_gtest_add_tests_helper(BPWriteReadAsStreamADIOS2_Threads)
-bp3_bp4_gtest_add_tests_helper(BPWriteReadAttributesADIOS2)
-bp3_bp4_gtest_add_tests_helper(StreamWriteReadHighLevelAPI)
-bp3_bp4_gtest_add_tests_helper(BPWriteFlushRead)
-bp3_bp4_gtest_add_tests_helper(BPWriteMultiblockRead)
-bp3_bp4_gtest_add_tests_helper(BPWriteReadMultiblock)
-bp3_bp4_gtest_add_tests_helper(BPWriteReadVector)
-bp3_bp4_gtest_add_tests_helper(BPWriteReadAttributesMultirank)
-bp3_bp4_gtest_add_tests_helper(BPLargeMetadata)
-bp3_bp4_gtest_add_tests_helper(BPWriteMemorySelectionRead)
-bp3_bp4_gtest_add_tests_helper(BPWriteReadLocalVariables)
-bp3_bp4_gtest_add_tests_helper(BPWriteReadLocalVariablesSel)
-bp3_bp4_gtest_add_tests_helper(BPWriteReadLocalVariablesSelHighLevel)
-bp3_bp4_gtest_add_tests_helper(BPChangingShape)
-bp3_bp4_gtest_add_tests_helper(BPWriteReadBlockInfo)
+bp3_bp4_gtest_add_tests_helper(WriteReadADIOS2)
+bp3_bp4_gtest_add_tests_helper(WriteReadADIOS2fstream)
+bp3_bp4_gtest_add_tests_helper(WriteReadADIOS2stdio)
+bp3_bp4_gtest_add_tests_helper(WriteReadAsStreamADIOS2)
+bp3_bp4_gtest_add_tests_helper(WriteReadAsStreamADIOS2_Threads)
+bp3_bp4_gtest_add_tests_helper(WriteReadAttributesADIOS2)
+bp3_bp4_gtest_add_tests_helper(FStreamWriteReadHighLevelAPI)
+bp3_bp4_gtest_add_tests_helper(WriteFlushRead)
+bp3_bp4_gtest_add_tests_helper(WriteMultiblockRead)
+bp3_bp4_gtest_add_tests_helper(WriteReadMultiblock)
+bp3_bp4_gtest_add_tests_helper(WriteReadVector)
+bp3_bp4_gtest_add_tests_helper(WriteReadAttributesMultirank)
+bp3_bp4_gtest_add_tests_helper(LargeMetadata)
+bp3_bp4_gtest_add_tests_helper(WriteMemorySelectionRead)
+bp3_bp4_gtest_add_tests_helper(WriteReadLocalVariables)
+bp3_bp4_gtest_add_tests_helper(WriteReadLocalVariablesSel)
+bp3_bp4_gtest_add_tests_helper(WriteReadLocalVariablesSelHighLevel)
+bp3_bp4_gtest_add_tests_helper(ChangingShape)
+bp3_bp4_gtest_add_tests_helper(WriteReadBlockInfo)
 
 if(ADIOS2_HAVE_MPI)
-  bp3_bp4_gtest_add_tests_helper(BPWriteAggregateRead) 
+  bp3_bp4_gtest_add_tests_helper(WriteAggregateRead) 
 endif()
 
 # BP3 only for now
-gtest_add_tests_helper(BPWriteReadVariableSpan ${test_mpi} Engine.BP. .BP3
+gtest_add_tests_helper(WriteReadVariableSpan ${test_mpi} BP Engine.BP. .BP3
   WORKING_DIRECTORY ${BP3_DIR} EXTRA_ARGS "BP3"
 )
-gtest_add_tests_helper(BPWriteNull ${test_mpi} Engine.BP. .BP3
+gtest_add_tests_helper(WriteNull ${test_mpi} BP Engine.BP. .BP3
   WORKING_DIRECTORY ${BP3_DIR} EXTRA_ARGS "BP3"
 )
 
 # BP4 only for now
-gtest_add_tests_helper(BPWriteAppendReadADIOS2 ${test_mpi} Engine.BP. .BP4
+gtest_add_tests_helper(WriteAppendReadADIOS2 ${test_mpi} BP Engine.BP. .BP4
   WORKING_DIRECTORY ${BP4_DIR} EXTRA_ARGS "BP4"
 )
-gtest_add_tests_helper(BPTimeAggregationADIOS2 ${test_mpi} Engine.BP. .BP4
+gtest_add_tests_helper(TimeAggregationADIOS2 ${test_mpi} BP Engine.BP. .BP4
   WORKING_DIRECTORY ${BP4_DIR} EXTRA_ARGS "BP4"
 )

testing/adios2/engine/bp/operations/CMakeLists.txt

@@ -9,31 +9,31 @@ file(MAKE_DIRECTORY ${BP3_DIR})
 file(MAKE_DIRECTORY ${BP4_DIR})
 
 if(ADIOS2_HAVE_SZ)
-  bp3_bp4_gtest_add_tests_helper(BPWriteReadSZ)
+  bp3_bp4_gtest_add_tests_helper(WriteReadSZ)
 endif()
 
 
 if(ADIOS2_HAVE_ZFP)
-  bp3_bp4_gtest_add_tests_helper(BPWriteReadZfp)
-  bp3_bp4_gtest_add_tests_helper(BPWriteReadZfpHighLevelAPI)
-  bp3_bp4_gtest_add_tests_helper(BPWriteReadZfpConfig)
-  target_compile_definitions(Test.Engine.BP.BPWriteReadZfpConfig PRIVATE
+  bp3_bp4_gtest_add_tests_helper(WriteReadZfp)
+  bp3_bp4_gtest_add_tests_helper(WriteReadZfpHighLevelAPI)
+  bp3_bp4_gtest_add_tests_helper(WriteReadZfpConfig)
+  target_compile_definitions(Test.Engine.BP.WriteReadZfpConfig PRIVATE
     "XML_CONFIG_DIR=${CMAKE_CURRENT_SOURCE_DIR}"
   )
 endif()
 
 if(ADIOS2_HAVE_MGARD)
-  bp3_bp4_gtest_add_tests_helper(BPWriteReadMGARD)
+  bp3_bp4_gtest_add_tests_helper(WriteReadMGARD)
 endif()
 
 if(ADIOS2_HAVE_BZip2)
-  bp3_bp4_gtest_add_tests_helper(BPWriteReadBZIP2)
+  bp3_bp4_gtest_add_tests_helper(WriteReadBZIP2)
 endif()
 
 if(ADIOS2_HAVE_PNG)
-  bp3_bp4_gtest_add_tests_helper(BPWriteReadPNG)
+  bp3_bp4_gtest_add_tests_helper(WriteReadPNG)
 endif()
 
 if(ADIOS2_HAVE_Blosc)
-  bp3_bp4_gtest_add_tests_helper(BPWriteReadBlosc)
+  bp3_bp4_gtest_add_tests_helper(WriteReadBlosc)
 endif()

testing/adios2/engine/common/CMakeLists.txt

@@ -16,35 +16,33 @@ endif()
 #   2nd arg: 1 for serialized execution, 0 for concurrent execution of Writer/Reader
 #   3rd arg: engine parameters
 
-gtest_add_tests_helper(Common ${test_mpi} "Engine." ".File"
+gtest_add_tests_helper(Common ${test_mpi} "" Engine. .File
   EXTRA_ARGS "File" "1"
 )
 
 if(ADIOS2_HAVE_HDF5)
-  gtest_add_tests_helper(Common ${test_mpi} "Engine." ".HDF5"
+  gtest_add_tests_helper(Common ${test_mpi} "" Engine. .HDF5
     EXTRA_ARGS "HDF5" "1"
   )
 endif()
 
 if(ADIOS2_HAVE_SST)
-  gtest_add_tests_helper(Common ${test_mpi} "Engine." ".SST.FFS"
+  gtest_add_tests_helper(Common ${test_mpi} "" Engine. .SST.FFS
     EXTRA_ARGS "SST" "0" "MarshalMethod:FFS"
   )
-  gtest_add_tests_helper(Common ${test_mpi} "Engine." ".SST.BP"
+  gtest_add_tests_helper(Common ${test_mpi} "" Engine. .SST.BP
     EXTRA_ARGS "SST" "0" "MarshalMethod:BP"
   )
 endif()
 
 if(ADIOS2_HAVE_MPI)
-  gtest_add_tests_helper(Common TRUE "Engine." ".InSituMPI"
+  gtest_add_tests_helper(Common TRUE "" Engine. .InSituMPI
     EXTRA_ARGS "InSituMPI" "0"
   )
 endif()
 
 #if(ADIOS2_HAVE_DataMan)
-#gtest_add_tests(TARGET TestEngineCommon ${extra_test_args} 
-#                EXTRA_ARGS "DataMan" "0"
-#                TEST_SUFFIX _DataMan)
+#  gtest_add_tests_helper(Common TRUE "" Engine. .DataMan
+#    EXTRA_ARGS "DataMan" "0"
+#  )
 #endif()
-
-

testing/adios2/engine/dataman/CMakeLists.txt

@@ -3,39 +3,12 @@
 # accompanying file Copyright.txt for details.
 #------------------------------------------------------------------------------#
 
-if(ADIOS2_HAVE_MPI AND ADIOS2_HAVE_ZeroMQ)
-
-add_executable(TestDataManP2P2DMemSelect TestDataManP2P2DMemSelect.cpp)
-target_link_libraries(TestDataManP2P2DMemSelect adios2 gtest MPI::MPI_C)
-gtest_add_tests(TARGET TestDataManP2P2DMemSelect)
-
-add_executable(TestDataManP2P3DMemSelect TestDataManP2P3DMemSelect.cpp)
-target_link_libraries(TestDataManP2P3DMemSelect adios2 gtest MPI::MPI_C)
-gtest_add_tests(TARGET TestDataManP2P3DMemSelect)
-
-add_executable(TestDataManP2P1D TestDataManP2P1D.cpp)
-target_link_libraries(TestDataManP2P1D adios2 gtest MPI::MPI_C)
-gtest_add_tests(TARGET TestDataManP2P1D)
-
-add_executable(TestDataManP2PZfp2D TestDataManP2PZfp2D.cpp)
-target_link_libraries(TestDataManP2PZfp2D adios2 gtest MPI::MPI_C)
-gtest_add_tests(TARGET TestDataManP2PZfp2D)
-
-add_executable(TestDataManP2PSz2D TestDataManP2PSz2D.cpp)
-target_link_libraries(TestDataManP2PSz2D adios2 gtest MPI::MPI_C)
-gtest_add_tests(TARGET TestDataManP2PSz2D)
-
-add_executable(TestDataManSubscribe1D TestDataManSubscribe1D.cpp)
-target_link_libraries(TestDataManSubscribe1D adios2 gtest MPI::MPI_C)
-gtest_add_tests(TARGET TestDataManSubscribe1D)
-
-add_executable(TestDataManMpiBase TestDataManMpiBase.cpp)
-target_link_libraries(TestDataManMpiBase adios2 gtest MPI::MPI_C)
-add_test(
-    NAME DataManEngineTest.MpiBase
-    COMMAND ${CMAKE_COMMAND}
-    -DCMD1=TestDataManMpiBase.dataman
-    -DCMD2=$<TARGET_FILE:TestDataManMpiBase>
-    -P ${CMAKE_CURRENT_SOURCE_DIR}/RunTest.cmake)
-
+if(ADIOS2_HAVE_MPI)
+  gtest_add_tests_helper(P2P2DMemSelect NOEXEC DataMan Engine.DataMan. "")
+  gtest_add_tests_helper(P2P3DMemSelect NOEXEC DataMan Engine.DataMan. "")
+  gtest_add_tests_helper(P2P1D NOEXEC DataMan Engine.DataMan. "")
+  gtest_add_tests_helper(P2PZfp2D NOEXEC DataMan Engine.DataMan. "")
+  gtest_add_tests_helper(P2PSz2D NOEXEC DataMan Engine.DataMan. "")
+  gtest_add_tests_helper(Subscribe1D NOEXEC DataMan Engine.DataMan. "")
+  gtest_add_tests_helper(MpiBase TRUE DataMan Engine.DataMan. "")
 endif()

testing/adios2/engine/hdf5/CMakeLists.txt

@@ -3,31 +3,22 @@
 # accompanying file Copyright.txt for details.
 #------------------------------------------------------------------------------#
 
-add_executable(TestNativeHDF5WriteRead TestNativeHDF5WriteRead.cpp)
-add_executable(TestHDF5WriteReadAsStream TestHDF5WriteReadAsStream.cpp)
-add_executable(TestStreamWriteReadHighLevelAPI_HDF5 TestStreamWriteReadHighLevelAPI_HDF5.cpp)
-add_executable(TestHDF5WriteReadAttributesADIOS2 TestHDF5WriteReadAttributesADIOS2.cpp)	
+gtest_add_tests_helper(WriteReadAsStream ${test_mpi} HDF5 Engine.HDF5. "")
+gtest_add_tests_helper(StreamWriteReadHighLevelAPI ${test_mpi}
+  HDF5 Engine.HDF5. ""
+)
+gtest_add_tests_helper(WriteReadAttributesADIOS2 ${test_mpi}
+  HDF5 Engine.HDF5. ""
+)
 
-# Workaround for multiple versions of FindHDF5
+gtest_add_tests_helper(NativeHDF5WriteRead ${test_mpi} "" Engine.HDF5. "")
 if(HDF5_C_INCLUDE_DIRS)
-  target_include_directories(TestNativeHDF5WriteRead PRIVATE ${HDF5_C_INCLUDE_DIRS})
+  target_include_directories(Test.Engine.HDF5.NativeHDF5WriteRead
+    PRIVATE ${HDF5_C_INCLUDE_DIRS}
+  )
 else()
-  target_include_directories(TestNativeHDF5WriteRead PRIVATE ${HDF5_INCLUDE_DIRS})
+  target_include_directories(Test.Engine.HDF5.NativeHDF5WriteRead
+    PRIVATE ${HDF5_INCLUDE_DIRS}
+  )
 endif()
-target_link_libraries(TestNativeHDF5WriteRead adios2 gtest_interface ${HDF5_C_LIBRARIES})
-target_link_libraries(TestHDF5WriteReadAsStream adios2 gtest_interface ${HDF5_C_LIBRARIES})
-target_link_libraries(TestStreamWriteReadHighLevelAPI_HDF5 adios2 gtest_interface ${HDF5_C_LIBRARIES})
-target_link_libraries(TestHDF5WriteReadAttributesADIOS2 adios2 gtest_interface ${HDF5_C_LIBRARIES})
-
-if(ADIOS2_HAVE_MPI)
-  target_link_libraries(TestNativeHDF5WriteRead MPI::MPI_C)
-  target_link_libraries(TestHDF5WriteReadAsStream MPI::MPI_C)
-  target_link_libraries(TestStreamWriteReadHighLevelAPI_HDF5 MPI::MPI_C)
-  target_link_libraries(TestHDF5WriteReadAttributesADIOS2 MPI::MPI_C)
-  set(extra_test_args EXEC_WRAPPER ${MPIEXEC_COMMAND})
-endif()
-
-gtest_add_tests(TARGET TestNativeHDF5WriteRead ${extra_test_args})
-gtest_add_tests(TARGET TestHDF5WriteReadAsStream ${extra_test_args})
-gtest_add_tests(TARGET TestStreamWriteReadHighLevelAPI_HDF5 ${extra_test_args})
-gtest_add_tests(TARGET TestHDF5WriteReadAttributesADIOS2 ${extra_test_args})
+target_link_libraries(Test.Engine.HDF5.NativeHDF5WriteRead ${HDF5_C_LIBRARIES})

testing/adios2/engine/inline/CMakeLists.txt

@@ -3,14 +3,4 @@
 # accompanying file Copyright.txt for details.
 #------------------------------------------------------------------------------#
 
-add_executable(TestInlineWriteRead TestInlineWriteRead.cpp)
-target_link_libraries(TestInlineWriteRead adios2 gtest)
-
-if(ADIOS2_HAVE_MPI)
-
-  target_link_libraries(TestInlineWriteRead MPI::MPI_C)
-  set(extra_test_args EXEC_WRAPPER ${MPIEXEC_COMMAND})
-
-endif()
-
-gtest_add_tests(TARGET TestInlineWriteRead ${extra_test_args})
+gtest_add_tests_helper(WriteRead ${test_mpi} Inline Engine.Inline. "")

testing/adios2/engine/insitumpi/CMakeLists.txt

@@ -3,11 +3,4 @@
 # accompanying file Copyright.txt for details.
 #------------------------------------------------------------------------------#
 
-set(extra_test_args EXEC_WRAPPER ${MPIEXEC_COMMAND})
-
-add_executable(TestInSituMPIFunctionAssignPeers  TestInSituMPIFunctionAssignPeers.cpp)
-target_link_libraries(TestInSituMPIFunctionAssignPeers adios2 gtest_interface MPI::MPI_C)
-gtest_add_tests(TARGET TestInSituMPIFunctionAssignPeers ${extra_test_args})
-
-
-
+gtest_add_tests_helper(FunctionAssignPeers TRUE InSituMPI Engine.InSituMPI. "")

testing/adios2/engine/null/CMakeLists.txt

@@ -3,15 +3,4 @@
 # accompanying file Copyright.txt for details.
 #------------------------------------------------------------------------------#
 
-
-add_executable(TestNullWriteRead TestNullWriteRead.cpp)
-target_link_libraries(TestNullWriteRead adios2 gtest)
-
-if(ADIOS2_HAVE_MPI)
-  target_link_libraries(TestNullWriteRead MPI::MPI_C)
-
-  set(extra_test_args EXEC_WRAPPER ${MPIEXEC_COMMAND})
-endif(ADIOS2_HAVE_MPI)
-
-gtest_add_tests(TARGET TestNullWriteRead ${extra_test_args})
-
+gtest_add_tests_helper(WriteRead ${test_mpi} Null Engine.Null. "")