Added pharo7 model package

source/Magritte-Pharo7-Model.package/.filetree

@@ -0,0 +1,5 @@
+{
+	"separateMethodMetaAndSource" : false,
+	"noMethodMetaData" : true,
+	"useCypressPropertiesFile" : true
+}

source/Magritte-Pharo7-Model.package/GRPackage.extension/class/magrittePharoModel.st

@@ -0,0 +1,7 @@
+*Magritte-Pharo7-Model
+magrittePharoModel
+	^ self new
+		name: 'Magritte-Pharo-Model';
+		addDependency: 'Magritte-Model';
+		url: #magritteUrl;
+		yourself

source/Magritte-Pharo7-Model.package/GRPackage.extension/properties.json

@@ -0,0 +1,3 @@
+{
+	"name" : "GRPackage"
+}

source/Magritte-Pharo7-Model.package/GRPharoPlatform.extension/instance/magritteAllSubInstancesOf.do..st

@@ -0,0 +1,5 @@
+*Magritte-Pharo7-Model
+magritteAllSubInstancesOf: aClass do: aBlock
+	"Evaluate the aBlock for all instances of aClass and all its subclasses."
+
+	aClass allSubInstancesDo: aBlock

source/Magritte-Pharo7-Model.package/GRPharoPlatform.extension/instance/magritteClassNamed..st

@@ -0,0 +1,5 @@
+*Magritte-Pharo7-Model
+magritteClassNamed: aString
+	"Return the class named aString, nil if the class can't be found."
+
+	^ Smalltalk classNamed: aString

source/Magritte-Pharo7-Model.package/GRPharoPlatform.extension/instance/magritteColorClass.st

@@ -0,0 +1,5 @@
+*Magritte-Pharo7-Model
+magritteColorClass
+	"Return a Color class"
+
+	^ Color

source/Magritte-Pharo7-Model.package/GRPharoPlatform.extension/instance/magritteEvaluatorClassFor..st

@@ -0,0 +1,6 @@
+*Magritte-Pharo7-Model
+magritteEvaluatorClassFor: aClass
+	"Answer an evaluator class appropriate for evaluating expressions in the 
+	context of this class."
+
+	^ aClass compilerClass

source/Magritte-Pharo7-Model.package/GRPharoPlatform.extension/instance/magritteTimeStampClass.st

@@ -0,0 +1,7 @@
+*Magritte-Pharo7-Model
+magritteTimeStampClass
+	"Return the platform's TimeStamp class. It is currently assumed that all platforms
+	have one, though this may not be correct and could require moving timestamp stuff
+	to its own package in order to resolve."
+
+	^ DateAndTime

source/Magritte-Pharo7-Model.package/GRPharoPlatform.extension/instance/magritteTimeStampIfAbsent..st

@@ -0,0 +1,6 @@
+*Magritte-Pharo7-Model
+magritteTimeStampIfAbsent: absentBlock
+	"Return the TimeStamp class, or if the platform does not have a TimeStamp
+	return the result of evaluating absentBlock."
+
+	^ DateAndTime

source/Magritte-Pharo7-Model.package/GRPharoPlatform.extension/instance/magritteUniqueObject.st

@@ -0,0 +1,6 @@
+*Magritte-Pharo7-Model
+magritteUniqueObject
+	"Answer a random object, such as a UUID, that is extremely likely to
+	be unique over space and time."
+
+	^ ByteArray withAll: UUID new

source/Magritte-Pharo7-Model.package/GRPharoPlatform.extension/properties.json

@@ -0,0 +1,3 @@
+{
+	"name" : "GRPharoPlatform"
+}

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/README.md

@@ -0,0 +1,3 @@
+I manage the file-data I represent on the file-system. From the programmer this looks the same as if the file would be in memory (==*MAMemoryFileModel*==), as it is transparently loaded and written out as necessary.
+
+I delegate my actual location on disk to MAFileDatabase (see class comment).

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/class/baseDirectoryPath..st

@@ -0,0 +1,4 @@
+accessing
+baseDirectoryPath: aString 
+	" deprecated, but still used by pier "
+	MAFileDatabase baseDirectory: aString

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/class/baseDirectoryPath.st

@@ -0,0 +1,4 @@
+accessing
+baseDirectoryPath
+	" deprecated: use MAFileDatabase baseDirectoryPath instead "
+	^MAFileDatabase baseDirectory fullName

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/class/baseUrl..st

@@ -0,0 +1,4 @@
+accessing
+baseUrl: aString
+	" deprecated: use MAFileDatabase baseUrl instead "
+	^ MAFileDatabase baseUrl: aString

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/class/baseUrl.st

@@ -0,0 +1,4 @@
+accessing
+baseUrl
+	" deprecated: use MAFileDatabase baseDirectoryPath instead "
+	^ MAFileDatabase baseUrl

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/instance/^equals.st

@@ -0,0 +1,3 @@
+comparing
+= anObject
+    ^ super = anObject and: [ self directory = anObject directory ]

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/instance/baseUrl.st

@@ -0,0 +1,3 @@
+configuration
+baseUrl
+	^ self database baseUrl

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/instance/contents..st

@@ -0,0 +1,7 @@
+accessing
+contents: aByteArray
+	| stream |
+	stream := self writeStream.
+	[ stream nextPutAll: aByteArray asByteArray ]
+		ensure: [ stream close ].
+	super contents: aByteArray

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/instance/contents.st

@@ -0,0 +1,9 @@
+accessing
+contents
+	| stream |
+	^ self file exists
+		ifFalse: [ ByteArray new ]
+		ifTrue: [
+			stream := self readStream.
+			[ stream contents ]
+				ensure: [ stream close ] ]

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/instance/database.st

@@ -0,0 +1,4 @@
+private
+database
+
+	^ MAFileDatabase new.

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/instance/directory.st

@@ -0,0 +1,4 @@
+accessing-dynamic
+directory
+
+	^ directory ifNil: [ directory := self database uniqueLocation ].

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/instance/file.st

@@ -0,0 +1,3 @@
+accessing-dynamic
+file
+	^(self directory / self filename) asFileReference

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/instance/finalize.st

@@ -0,0 +1,10 @@
+initialization
+finalize
+	|  dir |
+	dir := self directory.
+	dir exists
+		ifTrue: [ dir deleteAll ].
+	[ (dir := dir parent) hasChildren ]
+		whileFalse: [ dir ensureDelete ].
+	super finalize.
+	location := nil

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/instance/hash.st

@@ -0,0 +1,3 @@
+comparing
+hash
+	^ super hash bitXor: self directory hash

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/instance/postCopy.st

@@ -0,0 +1,7 @@
+copying
+postCopy
+	| previous |
+	super postCopy.
+	previous := self contents.
+	location := nil.
+	self contents: previous

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/instance/readStream.st

@@ -0,0 +1,3 @@
+accessing-dynamic
+readStream
+	^ self file binaryReadStream 

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/instance/writeStream.st

@@ -0,0 +1,3 @@
+accessing-dynamic
+writeStream
+	^ self file binaryWriteStream 

source/Magritte-Pharo7-Model.package/MAExternalFileModel.class/properties.json

@@ -0,0 +1,14 @@
+{
+	"commentStamp" : "<historical>",
+	"super" : "MAFileModel",
+	"category" : "Magritte-Pharo7-Model",
+	"classinstvars" : [ ],
+	"pools" : [ ],
+	"classvars" : [ ],
+	"instvars" : [
+		"location",
+		"directory"
+	],
+	"name" : "MAExternalFileModel",
+	"type" : "normal"
+}

source/Magritte-Pharo7-Model.package/MAFileDatabase.class/README.md

@@ -0,0 +1,14 @@
+I provide locations for external files.
+
+- The ==#baseDirectory== is the place where Magritte puts its file-database. Keep this value to nil to make it default to a subdirectory next to the Smalltalk image.
+- The ==#baseUrl== is a nice optimization to allow Apache (or any other Web Server) to directly serve the files. ==#baseUrl== is an absolute URL-prefix that is used to generate the path to the file. If you have specified one the file data does not go trough the image anymore, but instead is directly served trough the properly configured Web Server.
+
+The files are currently stored using the following scheme:
+
+=/files/9d/bsy8kyp45g0q7blphknk48zujap2wd/earthmap1k.jpg
+=1     2   3                            						  4
+
+1. is the #baseDirectory as specified in the settings.
+2. Are 256 directories named '00' to 'ff' to avoid having thousands of files in the same directory. Unfortunately this leads to problems with the Squeak file primitives and some filesystems don't handle that well. This part is generated at random.
+3. This is a secure ID, similar to the Seaside session key. It is generated at random and provides a security system that even works through Apache (you have to disable directory listings of course): if you don't know the filename you can not access the file.
+4. This is the original filename. Subclasses might want to store other cached versions of the same file there, for example resized images, etc.

source/Magritte-Pharo7-Model.package/MAFileDatabase.class/class/baseDirectory..st

@@ -0,0 +1,5 @@
+accessing
+baseDirectory: aStringOrDirectory
+	"Defines where the files are stored. If this value is set to nil, it defaults to a subdirectory of of the current image-location."
+
+	baseDirectory := aStringOrDirectory asFileReference.

source/Magritte-Pharo7-Model.package/MAFileDatabase.class/class/baseDirectory.st

@@ -0,0 +1,3 @@
+accessing
+baseDirectory
+	^ baseDirectory ifNil: [ FileLocator imageDirectory / 'files' ].

source/Magritte-Pharo7-Model.package/MAFileDatabase.class/class/baseUrl..st

@@ -0,0 +1,8 @@
+accessing
+baseUrl: aString
+	"Defines the base-URL where the files are served from, when using an external web server. This setting is left to nil by default, causing the files to be served trough the image."
+
+	baseUrl := aString isNil ifFalse: [
+		aString last = $/
+			ifFalse: [ aString ]
+			ifTrue: [ aString copyUpToLast: $/ ] ]

source/Magritte-Pharo7-Model.package/MAFileDatabase.class/class/baseUrl.st

@@ -0,0 +1,3 @@
+accessing
+baseUrl
+	^ baseUrl

source/Magritte-Pharo7-Model.package/MAFileDatabase.class/class/garbageCollect.st

@@ -0,0 +1,14 @@
+public
+garbageCollect
+	"Remove obsolete files from the file-system that are not referenced from the image anymore. This method has to be called manually and is not intended to be portable."
+
+	| mark sweep |
+	mark := self allInstances
+		collect: [ :each | each directory ].
+	sweep := Array with: self baseDirectory.
+	self locationDefinition do: [ :definition |
+		sweep := sweep gather: [ :directory |
+			directory hasChildren ifFalse: [ directory delete ].
+			FileLocator imageDirectory directories select: [ :e | e basename size = definition first ] ] ].
+	sweep do: [ :directory |
+		(mark includes: directory) ifFalse: [ directory recursiveDelete ] ]

source/Magritte-Pharo7-Model.package/MAFileDatabase.class/class/locationDefinition.st

@@ -0,0 +1,3 @@
+public
+locationDefinition
+	^ #( ( 2 '63450af8d9c2e17b' ) ( 30 'iaojv41bw67e0tud5m9rgplqfy8x3cs2kznh' ) )

source/Magritte-Pharo7-Model.package/MAFileDatabase.class/instance/baseDirectory.st

@@ -0,0 +1,4 @@
+accessing
+baseDirectory
+
+	^ self class baseDirectory.

source/Magritte-Pharo7-Model.package/MAFileDatabase.class/instance/baseUrl.st

@@ -0,0 +1,4 @@
+accessing
+baseUrl
+
+	^ self class baseUrl.

source/Magritte-Pharo7-Model.package/MAFileDatabase.class/instance/randomIdentifierName.st

@@ -0,0 +1,9 @@
+private
+randomIdentifierName
+
+	| digits idLength allowedCharacters |
+	digits := $0 to: $9.
+	allowedCharacters := digits, Character alphabet.
+	idLength := 30.
+	^ String streamContents: [ :str |
+		idLength timesRepeat: [ str nextPut: allowedCharacters atRandom ] ].

source/Magritte-Pharo7-Model.package/MAFileDatabase.class/instance/randomPartitionFolderName.st

@@ -0,0 +1,7 @@
+private
+randomPartitionFolderName
+	"Returns a string between '00' to 'FF'"
+
+	| twoCharacterHexString |
+	twoCharacterHexString := 16rFF atRandom printStringBase: 16 length: 2 padded: true.
+	^ twoCharacterHexString asLowercase.

source/Magritte-Pharo7-Model.package/MAFileDatabase.class/instance/uniqueLocation.st

@@ -0,0 +1,12 @@
+public
+uniqueLocation
+	"Finds an unique path to be used and create the necessary sub directories."
+
+	| partition id result |
+	[
+		partition := self randomPartitionFolderName.
+		id := self randomIdentifierName.
+		result := self baseDirectory ensureCreateDirectory / partition / id.
+	] doWhileTrue: [ result exists ].
+
+	^ result ensureCreateDirectory.

source/Magritte-Pharo7-Model.package/MAFileDatabase.class/properties.json

@@ -0,0 +1,14 @@
+{
+	"commentStamp" : "<historical>",
+	"super" : "Object",
+	"category" : "Magritte-Pharo7-Model",
+	"classinstvars" : [
+		"baseDirectory",
+		"baseUrl"
+	],
+	"pools" : [ ],
+	"classvars" : [ ],
+	"instvars" : [ ],
+	"name" : "MAFileDatabase",
+	"type" : "normal"
+}

source/Magritte-Pharo7-Model.package/MAFileSystem.class/class/extensionFor..st

@@ -0,0 +1,4 @@
+paths
+extensionFor: aString 
+
+	^ aString asFileReference extension.

source/Magritte-Pharo7-Model.package/MAFileSystem.class/class/fileSizeFor..st

@@ -0,0 +1,3 @@
+entries
+fileSizeFor: filenameString 
+	^ filenameString asFileReference size

source/Magritte-Pharo7-Model.package/MAFileSystem.class/class/fullNameFor..st

@@ -0,0 +1,4 @@
+paths
+fullNameFor: aString 
+
+	^ aString asFileReference fullName.

source/Magritte-Pharo7-Model.package/MAFileSystem.class/class/imageDirectory.st

@@ -0,0 +1,4 @@
+locations
+imageDirectory
+
+	^ FileLocator imageDirectory.

source/Magritte-Pharo7-Model.package/MAFileSystem.class/class/mimeTypesForExtension..st

@@ -0,0 +1,6 @@
+mime types
+mimeTypesForExtension: aString 
+
+	| types |
+	types := MIMEType forExtensionReturnMimeTypesOrNil: aString.
+	^ types ifNotNil: [ types collect: [ :e | e asString ] ].

source/Magritte-Pharo7-Model.package/MAFileSystem.class/properties.json

@@ -0,0 +1,11 @@
+{
+	"commentStamp" : "",
+	"super" : "Object",
+	"category" : "Magritte-Pharo7-Model",
+	"classinstvars" : [ ],
+	"pools" : [ ],
+	"classvars" : [ ],
+	"instvars" : [ ],
+	"name" : "MAFileSystem",
+	"type" : "normal"
+}

source/Magritte-Pharo7-Model.package/MorphicUIManager.extension/instance/chooseFile.in..st

@@ -0,0 +1,10 @@
+*Magritte-Pharo7-Model
+chooseFile: windowTitle in: directoryString
+
+	| chooser |
+	chooser := FileDialogWindow newWithTheme: UITheme current.
+	chooser
+		title: windowTitle;
+		selectDirectory: directoryString;
+		answerFileEntry.
+	^ chooser openModal answer ifNotNil: [ :answer | answer asFileReference ].

source/Magritte-Pharo7-Model.package/MorphicUIManager.extension/properties.json

@@ -0,0 +1,3 @@
+{
+	"name" : "MorphicUIManager"
+}

source/Magritte-Pharo7-Model.package/monticello.meta/categories.st

@@ -0,0 +1 @@
+SystemOrganization addCategory: #'Magritte-Pharo7-Model'!

source/Magritte-Pharo7-Model.package/monticello.meta/package

@@ -0,0 +1 @@
+(name 'Magritte-Pharo7-Model')