chore(ci): from Make to just

.github/workflows/test.yml

@@ -278,6 +278,8 @@ jobs:
 
   linkcheck-docs:
     runs-on: ubuntu-latest
+    env:
+      NO_RYE: 1
     steps:
     - name: Checkout repository
       uses: actions/checkout@v4
@@ -291,7 +293,8 @@ jobs:
     - name: Install dependencies
       run: pip install -r requirements-dev.lock
 
+    - name: Install Just
+      uses: taiki-e/install-action@just
+
     - name: Check links in documentation
-      run: |
-        cd docs
-        NB_OFF=1 make linkcheck
+      run: just docs/linkcheck

.gitignore

@@ -10,6 +10,7 @@ target/
 # Docs
 
 docs/build/
+docs/jupyter_execute/
 docs/source/reference/*.rst
 
 # Sionna data

README.md

@@ -53,10 +53,16 @@ To run build this package locally, you need:
 
 - [Python 3.9](https://www.python.org/) or above;
 - [Rust](https://www.rust-lang.org/) stable toolchain;
-- `make` (e.g., GNU Make or Make for Windows);
+- [just](https://github.com/casey/just) to easily run commands listed in `justfile`s;
 - [Maturin](https://www.maturin.rs/) for building Python bindings from Rust code;
 - and [Rye](https://rye.astral.sh/) to manage this project.
 
+This project contains `justfile`s with recipes[^1] for most common
+use cases, so feel free to use them instead of the commands listed below/
+
+[^1]: `just` is as alternative tool to Make, that provides more modern
+  user experience. Enter `just` to list all available recipes.
+
 ## Local development
 
 The following commands assume that you installed
@@ -77,11 +83,12 @@ and that you activated the corresponding Python virtual environment:
 To generate the documentation, please run the following:
 
 ```bash
-cd docs
-make html
+just docs/build
 ```
 
-Finally, you can open `build/html/index.html` to see the generated docs.
+Finally, you can open `docs/build/html/index.html` to see the generated docs.
+
+Other recipes are available, and you can list them with `just docs/`.
 
 ### Testing
 

docs/justfile

@@ -0,0 +1,24 @@
+# Run Python commands inside environment
+env-run := if env("NO_RYE", "") == "1" { "" } else { "rye run" }
+
+# Default command (list all commands)
+default:
+  @just --list
+
+# Clean build artifacts
+clean:
+  rm -rf build
+  rm -f source/reference/*.rst
+
+# Build docs
+build builder="html" *OPTIONS="-W --keep-going":
+  {{env-run}} sphinx-build {{OPTIONS}} -b={{builder}} source build
+
+# Build docs in "draft" mode
+draft *ARGS:
+    NB_OFF="1" just build {{ARGS}}
+
+# Check links
+linkcheck *ARGS: (draft "linkcheck" ARGS)
+
+alias check := linkcheck

justfile

@@ -0,0 +1,72 @@
+# Run Python commands inside environment
+env-run := if env("NO_RYE", "") == "1" { "" } else { "rye run" }
+
+# Default command (list all commands)
+default:
+  @just --list
+
+# Benchmark code
+[group('test')]
+bench: bench-python bench-rust
+
+# Benchmark Python code
+[group('python')]
+[group('test')]
+bench-python *ARGS:
+  pytest --benchmark-only {{ARGS}}
+
+# Benchmark Rust code
+[group('rust')]
+[group('test')]
+bench-rust *ARGS:
+  cargo bench {{ARGS}}
+
+# Build Python package(s)
+[group('dev')]
+build *ARGS:
+  rye build {{ARGS}}
+
+# Bump packages version
+[group('dev')]
+bump +ARGS="patch":
+  {{env-run}} bump-my-version {{ARGS}}
+
+# Check the code can compile
+[group('rust')]
+[group('test')]
+check:
+  cargo check
+
+# Clean build artifacts
+[group('dev')]
+clean:
+  cargo clean
+  rm -rf dist
+
+# Build and install Python packages
+[group('dev')]
+install:
+  rye sync
+
+# Run code linters and formatters
+[group('dev')]
+lint:
+  {{env-run}} pre-commit run --all-files
+
+alias fmt := lint
+
+# Test code
+[group('test')]
+test: test-python test-rust
+
+# Test Python code
+[group('python')]
+[group('test')]
+test-python *ARGS:
+  {{env-run}} pytest {{ARGS}}
+
+# Test Rust code
+[group('rust')]
+[group('test')]
+test-rust *ARGS:
+  cargo test {{ARGS}}