Expose dynamic font vector outlines to the GDScript.

[bruvzg]

Exposes vector outlines to the scripts, might be useful for generating 3D meshes from the shaped text and other complex text effects.

Test code:

extends Control

var rid
var trid
var gl
var data = []

func _ready():
	# Load font and shape text
	rid = TextServerManager.get_primary_interface().create_font_resource("res://ComicNeue-Bold.otf", 72)
	trid = TextServerManager.get_primary_interface().create_shaped_text()
	TextServerManager.get_primary_interface().shaped_text_add_string(trid, "Abc", [rid], 72);
	gl = TextServerManager.get_primary_interface().shaped_text_get_glyphs(trid);
	# Get glyph outlines
	for g in gl:
		data.push_back(TextServerManager.get_primary_interface().font_get_glyph_contours(g.get("font_rid"), g.get("font_size"), g.get("index")))

func _exit_tree():
	# Unload text buffer and font
	TextServerManager.get_primary_interface().free_rid(rid)
	TextServerManager.get_primary_interface().free_rid(trid)

func draw_conic(p0, p1, p2, color):
	var prev = Vector2()
	var t = 0.0
	while(t <= 1.0):
		var omt = (1.0 - t)
		var omt2 = omt * omt
		var t2 = t * t
		
		var point = p1 + omt2 * (p0 - p1) + t2 * (p2 - p1)
		if prev != Vector2():
			draw_line(prev, point, color)
		prev = point
		t += 0.1

func draw_cubic(p0, p1, p2, p3, color):
	var prev = Vector2()
	var t = 0.0
	while(t <= 1.0):
		var omt = (1.0 - t)
		var omt2 = omt * omt
		var omt3 = omt2 * omt
		var t2 = t * t
		var t3 = t2 * t

		var point = p0 * omt3 + p1 * omt2 * t * 3.0 + p2 * omt * t2 * 3.0 + p3 * t3
		if prev != Vector2():
			draw_line(prev, point, color)
		prev = point
		t += 0.1

func _draw():
	var origin = Vector2(100, 100)
	var idx = 0
	for g in gl:
		var off = origin + g.get("offset") * 10
		var points = data[idx].get("points")
		var contours = data[idx].get("contours")

		# Draw glyph outline
		var point = 0
		for cnt in contours:
			var prev
			if points[cnt].z == TextServer.CONTOUR_CURVE_TAG_ON:
				prev = Vector2(points[cnt].x, points[cnt].y) * 10 + off
			else:
				prev = Vector2(points[point].x, points[point].y) * 10 + off
			var first = point
			while(point <= cnt):
				var p = points[point]
				if p.z == TextServer.CONTOUR_CURVE_TAG_ON:
					# Line segment
					draw_string(get_theme_font("font"), Vector2(p.x + 1, p.y + 1) * 10 + off, str(point))
					draw_circle(Vector2(p.x, p.y) * 10 + off, 5, Color(1,0,0))
					draw_line(prev, Vector2(p.x, p.y) * 10 + off, Color(0,0,1))
					prev = Vector2(p.x, p.y) * 10 + off
					point += 1
					continue

				if p.z == TextServer.CONTOUR_CURVE_TAG_OFF_CONIC:
					# Quadratic Bézier segment
					var p1
					if point == cnt:
						p1 = points[first]
					else:
						p1 = points[point + 1]
						draw_string(get_theme_font("font"), Vector2(p1.x + 1, p1.y + 1) * 10 + off, str(point + 1))
					draw_string(get_theme_font("font"), Vector2(p.x + 1, p.y + 1) * 10 + off, str(point))
					draw_conic(prev, Vector2(p.x, p.y) * 10 + off, Vector2(p1.x, p1.y) * 10 + off, Color(0,0,1))
					draw_arc(Vector2(p.x, p.y) * 10 + off, 5, 0, 3 * PI, 20, Color(1,0,0))
					draw_circle(Vector2(p1.x, p1.y) * 10 + off, 5, Color(1,0,0))
					prev = Vector2(p1.x, p1.y) * 10 + off
					point += 2
					continue

				if p.z == TextServer.CONTOUR_CURVE_TAG_OFF_CUBIC:
					# Cubic Bézier segment
					var p1
					var p2
					if point == cnt:
						p1 = points[first]
						p2 = points[first + 1]
					elif point == cnt - 1:
						p1 = points[point + 1]
						p2 = points[first]
						draw_string(get_theme_font("font"), Vector2(p1.x + 1, p1.y + 1) * 10 + off, str(point + 1))
					else:
						p1 = points[point + 1]
						p2 = points[point + 2]
						draw_string(get_theme_font("font"), Vector2(p1.x + 1, p1.y + 1) * 10 + off, str(point + 1))
						draw_string(get_theme_font("font"), Vector2(p2.x + 1, p2.y + 1) * 10 + off, str(point + 2))
					draw_string(get_theme_font("font"), Vector2(p.x + 1, p.y + 1) * 10 + off, str(point))
					draw_cubic(prev, Vector2(p.x, p.y) * 10 + off, Vector2(p1.x, p1.y) * 10 + off, Vector2(p2.x, p2.y) * 10 + off, Color(0,0,1))
					draw_arc(Vector2(p.x, p.y) * 10 + off, 5, 0, 3 * PI, 20, Color(1,0,0))
					draw_arc(Vector2(p1.x, p1.y) * 10 + off, 5, 0, 3 * PI, 20, Color(1,0,0))
					draw_circle(Vector2(p2.x, p2.y) * 10 + off, 5, Color(1,0,0))
					prev = Vector2(p2.x, p2.y) * 10 + off
					point += 3
					continue
			point = cnt + 1
		origin.x += g.get("advance") * 10
		idx += 1

func _process(delta):
	update()

[Calinou]

The feature looks good to me, although I can't see too many use cases for it personally. Maybe this is more useful with icon fonts, but icon fonts are generally considered to be on the way out (with SVG being favored for web icons nowadays).

Also, the documentation should be made more complete.