enable changing install prefix for PKG config

CMakeLists.txt

@@ -428,18 +428,6 @@ if(GINKGO_BUILD_DOC)
 endif()
 
 
-# add escape character '\' for space
-string(REPLACE " " "\ " PKG_CMAKE_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
-# add escape character '\' for space in regex mode
-list(TRANSFORM GINKGO_INTERFACE_LINK_FLAGS REPLACE " " "\\\\ ")
-list(TRANSFORM GINKGO_INTERFACE_CXX_FLAGS REPLACE " " "\\\\ ")
-# convert the list to string
-string(REPLACE ";" " " GINKGO_INTERFACE_CXX_FLAGS "${GINKGO_INTERFACE_CXX_FLAGS}")
-string(REPLACE ";" " " GINKGO_INTERFACE_LINK_FLAGS "${GINKGO_INTERFACE_LINK_FLAGS}")
-configure_file(${Ginkgo_SOURCE_DIR}/cmake/ginkgo.pc.in
-    ${Ginkgo_BINARY_DIR}/ginkgo.pc.in @ONLY)
-file(GENERATE OUTPUT ${Ginkgo_BINARY_DIR}/ginkgo_$<CONFIG>.pc
-    INPUT ${Ginkgo_BINARY_DIR}/ginkgo.pc.in)
 
 # WINDOWS NVCC has " inside the string, add escape character
 # to avoid config problem.

cmake/generate_pkg.cmake.in

@@ -0,0 +1,28 @@
+# This is run as a standalone script. Thus no cmake variables related to Ginkgo are
+# available through the ${...} syntax. Instead, the file containing the actual values
+# of the necessary variables is generated through `configure_file`. But this leaves
+# generator expressions unresolved, so another pass through `file(GENERATE ...)` is
+# necessary. That call can't be put into this file, since the script is used as part
+# of `install(SCRIPT ...)` which doesn't support generator expressions in the script
+# content
+
+# add escape character '\' for space
+string(REPLACE " " "\ " GINKGO_PKG_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
+# add escape character '\' for space in regex mode
+string(REPLACE ";" "\ " GINKGO_INTERFACE_LINK_FLAGS "@GINKGO_INTERFACE_LINK_FLAGS@")
+string(REPLACE ";" "\ " GINKGO_INTERFACE_CXX_FLAGS "@GINKGO_INTERFACE_CXX_FLAGS@")
+
+set(GINKGO_INSTALL_LIBDIR "@CMAKE_INSTALL_LIBDIR@")
+set(GINKGO_INSTALL_INCLUDEDIR "@CMAKE_INSTALL_INCLUDEDIR@")
+set(GINKGO_PROJECT_NAME "@CMAKE_PROJECT_NAME@")
+set(GINKGO_DESCRIPTION "@Ginkgo_DESCRIPTION@")
+set(GINKGO_VERSION "@Ginkgo_VERSION@")
+
+set(GINKGO_INSTALL_PKGCONFIG_DIR "${GINKGO_PKG_INSTALL_PREFIX}/${GINKGO_INSTALL_LIBDIR}/pkgconfig")
+
+set(GINKGO_SOURCE_DIR "@Ginkgo_SOURCE_DIR@")
+set(GINKGO_BINARY_DIR "@Ginkgo_BINARY_DIR@")
+
+configure_file(${GINKGO_SOURCE_DIR}/cmake/ginkgo.pc.in
+               ${GINKGO_INSTALL_PKGCONFIG_DIR}/ginkgo_$<CONFIG>.pc
+               @ONLY)

cmake/ginkgo.pc.in

@@ -1,10 +1,10 @@
-prefix=@PKG_CMAKE_INSTALL_PREFIX@
-libdir=@CMAKE_INSTALL_FULL_LIBDIR@
-includedir=@CMAKE_INSTALL_FULL_INCLUDEDIR@
+prefix=@GINKGO_PKG_INSTALL_PREFIX@
+libdir=${prefix}/@GINKGO_INSTALL_LIBDIR@
+includedir=${prefix}/@GINKGO_INSTALL_INCLUDEDIR@
 
-Name: @CMAKE_PROJECT_NAME@
-Description: @Ginkgo_DESCRIPTION@
-Version: @Ginkgo_VERSION@
+Name: @GINKGO_PROJECT_NAME@
+Description: @GINKGO_DESCRIPTION@
+Version: @GINKGO_VERSION@
 URL: https://ginkgo-project.github.io/
 
 Requires:

cmake/install_helpers.cmake

@@ -2,7 +2,6 @@ include(CMakePackageConfigHelpers)
 include(GNUInstallDirs)
 
 
-set(GINKGO_INSTALL_PKGCONFIG_DIR "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
 set(GINKGO_INSTALL_CONFIG_DIR "${CMAKE_INSTALL_LIBDIR}/cmake/Ginkgo")
 set(GINKGO_INSTALL_MODULE_DIR "${CMAKE_INSTALL_LIBDIR}/cmake/Ginkgo/Modules")
 
@@ -60,10 +59,18 @@ function(ginkgo_install_library name)
 endfunction()
 
 function(ginkgo_install)
-    # pkg-config file
-    install(FILES ${Ginkgo_BINARY_DIR}/ginkgo_$<CONFIG>.pc
-        DESTINATION "${GINKGO_INSTALL_PKGCONFIG_DIR}"
-        RENAME ginkgo.pc
+    # generate pkg-config file, a three-step process is necessary to include the correct install prefix
+    # Step 1: substitute project variables in the generation script
+    configure_file("${Ginkgo_SOURCE_DIR}/cmake/generate_pkg.cmake.in"
+                   "${Ginkgo_BINARY_DIR}/cmake/generate_pkg.cmake"
+                   @ONLY)
+    # Step 2: substitute generator expressions
+    file(GENERATE OUTPUT ${Ginkgo_BINARY_DIR}/cmake/generate_pkg_$<CONFIG>.cmake
+         INPUT ${Ginkgo_BINARY_DIR}/cmake/generate_pkg.cmake)
+    # Step 3: at install time, call the generation script which has all variables
+    #         except the install prefix already replaced. Use the install prefix
+    #         that is specified at install time
+    install(SCRIPT "${Ginkgo_BINARY_DIR}/cmake/generate_pkg_$<CONFIG>.cmake"
         COMPONENT Ginkgo_Development)
 
     # install the public header files