Support for bazel in garden

Signed-off-by: Michael Carroll <michael@openrobotics.org>

BUILD.bazel

@@ -0,0 +1,147 @@
+load(
+    "@gz//bazel/skylark:build_defs.bzl",
+    "GZ_FEATURES",
+    "GZ_ROOT",
+    "GZ_VISIBILITY",
+    "gz_configure_header",
+    "gz_export_header",
+    "gz_include_header",
+)
+load("@gz//bazel/skylark:gz_py.bzl", "gz_py_binary")
+
+package(
+    default_visibility = GZ_VISIBILITY,
+    features = GZ_FEATURES,
+)
+
+licenses(["notice"])  # Apache-2.0
+
+exports_files(["LICENSE"])
+
+gz_configure_header(
+    name = "config",
+    src = "include/sdf/config.hh.in",
+    cmakelists = ["CMakeLists.txt"],
+    defines = {
+        "CMAKE_INSTALL_FULL_DATAROOTDIR": "",
+    },
+    package = "sdformat",
+)
+
+gz_py_binary(
+    name = "embed_sdf",
+    srcs = ["sdf/embedSdf.py"],
+)
+
+genrule(
+    name = "embed_sdf_genrule",
+    srcs = glob([
+        "sdf/**/*.sdf",
+        "sdf/**/*.convert",
+    ]),
+    outs = ["EmbeddedSdf.cc"],
+    cmd = "$(execpath :embed_sdf) $(SRCS) > $@",  # noqa
+    tools = [":embed_sdf"],
+)
+
+public_headers_no_gen = glob([
+    "include/sdf/*.h",
+    "include/sdf/*.hh",
+])
+
+private_headers = glob(["src/*.hh"])
+
+sources = glob(
+    ["src/*.cc"],
+    exclude = [
+        "src/*_TEST.cc",
+        "src/gz.cc",
+    ],
+)
+
+gz_export_header(
+    name = "include/sdf/Export.hh",
+    export_base = "GZ_SDFORMAT",
+    lib_name = "sdf",
+    visibility = ["//visibility:private"],
+)
+
+gz_include_header(
+    name = "sdformat_hh_genrule",
+    out = "include/sdformat.hh",
+    hdrs = public_headers_no_gen + [
+        "include/sdf/config.hh",
+        "include/sdf/Export.hh",
+    ],
+)
+
+public_headers = public_headers_no_gen + [
+    "include/sdf/Export.hh",
+    "include/sdf/config.hh",
+    "include/sdformat.hh",
+]
+
+cc_library(
+    name = "urdf",
+    srcs = [
+        "src/urdf/urdf_parser/joint.cpp",
+        "src/urdf/urdf_parser/link.cpp",
+        "src/urdf/urdf_parser/model.cpp",
+        "src/urdf/urdf_parser/pose.cpp",
+        "src/urdf/urdf_parser/twist.cpp",
+        "src/urdf/urdf_parser/urdf_model_state.cpp",
+        "src/urdf/urdf_parser/urdf_sensor.cpp",
+        "src/urdf/urdf_parser/world.cpp",
+    ],
+    hdrs = glob(
+        ["src/urdf/**/*.h"],
+    ),
+    copts = ["-Wno-unknown-pragmas"],
+    includes = ["src/urdf"],
+    deps = [
+        "@tinyxml2",
+    ],
+)
+
+cc_library(
+    name = "sdformat",
+    srcs = sources + private_headers + ["EmbeddedSdf.cc"],
+    hdrs = public_headers,
+    includes = [
+        "include",
+        "src",
+    ],
+    deps = [
+        ":urdf",
+        GZ_ROOT + "math",
+        GZ_ROOT + "utils",
+        "@tinyxml2",
+    ],
+)
+
+test_sources = glob(
+    ["src/*_TEST.cc"],
+    exclude = ["src/gz_TEST.cc"],
+)
+
+[cc_test(
+    name = src.replace("/", "_").replace(".cc", "").replace("src_", ""),
+    srcs = [src],
+    data = [
+        "sdf",
+        GZ_ROOT + "sdformat/test:integration",
+        GZ_ROOT + "sdformat/test:sdf",
+    ],
+    env = {
+        "GZ_BAZEL": "1",
+        "GZ_BAZEL_PATH": "sdformat",
+    },
+    deps = [
+        ":sdformat",
+        GZ_ROOT + "sdformat/test:test_utils",
+        "@gtest",
+        "@gtest//:gtest_main",
+    ],
+) for src in test_sources]
+
+exports_files(["sdf"])

test/BUILD.bazel

@@ -0,0 +1,51 @@
+load(
+    "@gz//bazel/skylark:build_defs.bzl",
+    "GZ_ROOT",
+)
+
+cc_library(
+    name = "test_utils",
+    hdrs = ["test_utils.hh"],
+    includes = ["."],
+    visibility = ["//visibility:public"],
+    deps = [
+        GZ_ROOT + "common/testing",
+    ],
+)
+
+integration_test_sources = glob(
+    ["integration/*.cc"],
+    exclude = [
+        "integration/schema_test.cc",
+        "integration/element_memory_leak.cc",
+    ],
+)
+
+[cc_test(
+    name = src.replace("/", "_").replace(".cc", "").replace("integration_", "INTEGRATION_"),
+    srcs = [
+        src,
+        "integration/toml_parser.hh",
+    ],
+    data = [
+        GZ_ROOT + "sdformat:sdf",
+        "integration",
+        "sdf",
+    ],
+    env = {
+        "GZ_BAZEL": "1",
+        "GZ_BAZEL_PATH": "sdformat",
+    },
+    includes = ["integration"],
+    deps = [
+        GZ_ROOT + "sdformat:sdformat",
+        ":test_utils",
+        "@gtest",
+        "@gtest//:gtest_main",
+    ],
+) for src in integration_test_sources]
+
+exports_files([
+    "sdf",
+    "integration",
+])