Change URI#to_s to handle default ports for more schemes than http/https

spec/std/uri_spec.cr

@@ -128,6 +128,28 @@ describe "URI" do
     end
   end
 
+  describe ".default_ports" do
+    it "returns default port for well known schemes" do
+      URI.default_ports["http"].should eq(80)
+      URI.default_ports["https"].should eq(443)
+    end
+
+    it "returns nil for unknown schemes" do
+      URI.default_ports["xyz"].should eq(nil)
+    end
+
+    it "registers port for scheme" do
+      URI.default_ports["ponzi"] = 9999
+      URI.default_ports["ponzi"].should eq(9999)
+    end
+
+    it "unregisters port for scheme" do
+      URI.default_ports["ftp"].should eq(21)
+      URI.default_ports["ftp"] = nil
+      URI.default_ports["ftp"].should eq(nil)
+    end
+  end
+
   describe ".unescape" do
     {
       {"hello", "hello"},

src/uri.cr

@@ -1,3 +1,4 @@
+require "./uri/uri_default_ports"
 require "./uri/uri_parser"
 
 # This class represents a URI reference as defined by [RFC 3986: Uniform Resource Identifier
@@ -427,22 +428,41 @@ class URI
     end
   end
 
-  DEFAULT_PORTS = {
-    "ftp"    => 21,
-    "ftps"   => 990,
-    "gopher" => 70,
-    "http"   => 80,
-    "https"  => 443,
-    "ldap"   => 389,
-    "ldaps"  => 636,
-    "nntp"   => 119,
-    "scp"    => 22,
-    "sftp"   => 22,
-    "ssh"    => 22,
-    "telnet" => 23,
-  }
+  # The global registry for URI scheme default ports.
+  @@default_ports = DefaultPorts.new
 
+  # Returns the global registry for URI schemes and their respective
+  # default ports.
+  #
+  # The registry can then be used to query the default port for a
+  # given scheme.
+  #
+  # ```
+  # URI.default_ports["http"]  # => 80
+  # URI.default_ports["ponzi"] # => nil
+  # ```
+  #
+  # Or it can be used to register the default port for a given
+  # scheme.
+  #
+  # ```
+  # URI.default_ports["ponzi"] = 9999
+  # URI.default_ports["ponzi"] # => 9999
+  # ```
+  #
+  # Or it can be used to unregister the default port for a given
+  # scheme.
+  #
+  # ```
+  # URI.default_ports["ponzi"] = nil
+  # URI.default_ports["ponzi"] # => nil
+  # ```
+  def self.default_ports
+    @@default_ports
+  end
+
+  # Returns true if this URI's port is the default port for its scheme.
   private def default_port?
-    port == DEFAULT_PORTS[scheme]?
+    port == @@default_ports[scheme]
   end
 end

src/uri/uri_default_ports.cr

@@ -0,0 +1,49 @@
+class URI
+  # Global registry for URI scheme default ports.
+  private class DefaultPorts
+    # Well-known schemes and their respective default ports.
+    @@default_ports = {
+      "ftp"    => 21,
+      "ftps"   => 990,
+      "gopher" => 70,
+      "http"   => 80,
+      "https"  => 443,
+      "ldap"   => 389,
+      "ldaps"  => 636,
+      "nntp"   => 119,
+      "scp"    => 22,
+      "sftp"   => 22,
+      "ssh"    => 22,
+      "telnet" => 23,
+    }
+
+    # Returns the default port for the given `scheme` if known,
+    # otherwise returns `nil`.
+    #
+    # ```
+    # default_ports = DefaultPorts.new
+    # default_ports["http"]  # => 80
+    # default_ports["ponzi"] # => nil
+    # ```
+    def [](scheme : String?) : Int32?
+      return nil if scheme.nil?
+      @@default_ports[scheme.downcase]?
+    end
+
+    # Globally registers the default `port` for the given `scheme`.
+    #
+    # ```
+    # default_ports = DefaultPorts.new
+    # default_ports["ponzi"] # => nil
+    # default_ports["ponzi"] = 9999
+    # default_ports["ponzi"] # => 9999
+    # ```
+    def []=(scheme : String, port : Int32?)
+      if port
+        @@default_ports[scheme.downcase] = port
+      else
+        @@default_ports.delete scheme
+      end
+    end
+  end
+end