CTCI 6.10: Poison.groovy

src/main/groovy/Ch06_MathAndLogicPuzzles/_06_10_Poison.groovy

@@ -0,0 +1,21 @@
+package Ch06_MathAndLogicPuzzles
+
+/** You have bottles (from which 1 is poisoned) and poison detecting strips. 
+ *  You can reuse strips, but it takes several days for a strip to show the results (contained poison or not).
+ *  How long would it take to find the poison? */
+class _06_10_Poison {
+    static getPoisonedBottle(int bottleCount, Closure<List<Boolean>> test) {
+        def strips = markStrips(bottleCount)
+        def results = test(strips).collect { it ? 1 : 0 }
+        Integer.valueOf(results.join(), 2)
+    }
+
+    private static markStrips(int bottleCount) {
+        def strips = [].withDefault { [] }
+        bottleCount.times { bottle ->
+            for (strip in BitSet.valueOf(bottle).stream())
+                strips[strip] += bottle
+        }
+        strips.reverse()
+    }
+}

src/test/groovy/Ch06_MathAndLogicPuzzles/_06_10_PoisonTest.groovy

@@ -0,0 +1,19 @@
+package Ch06_MathAndLogicPuzzles
+
+import spock.lang.Specification
+import spock.lang.Unroll
+
+import static Ch06_MathAndLogicPuzzles._06_10_Poison.getPoisonedBottle
+
+@Unroll class _06_10_PoisonTest extends Specification {
+    /*@formatter:off*/
+    def 'poison?'() {
+        expect: bottleCount.times { poisonedBottle -> 
+                    def test = { List<List> strips -> strips.collect { it.contains(poisonedBottle) } }
+                    assert getPoisonedBottle(bottleCount, test) == poisonedBottle
+                }
+        where:  bottleCount | _
+                1000        | _        
+    }
+    /*@formatter:on*/
+}