quaternion: update, libquotient: init

pkgs/applications/networking/instant-messengers/quaternion/default.nix

@@ -1,46 +1,47 @@
 { mkDerivation, stdenv, lib, fetchFromGitHub, cmake
-, qtbase, qtquickcontrols, qtkeychain, qtmultimedia, qttools
-, libqmatrixclient_0_5
-, libsecret
+, qtbase, qtquickcontrols, qtquickcontrols2, qtkeychain, qtmultimedia, qttools
+, libquotient, libsecret
 }:
 
-let
-  generic = version: sha256: prefix: library: mkDerivation {
-    pname = "quaternion";
-    inherit version;
-
-    src = fetchFromGitHub {
-      owner = "QMatrixClient";
-      repo  = "Quaternion";
-      rev   = "${prefix}${version}";
-      inherit sha256;
-    };
-
-    buildInputs = [ qtbase qtmultimedia qtquickcontrols qtkeychain library libsecret ];
-
-    nativeBuildInputs = [ cmake qttools ];
+mkDerivation rec {
+  pname = "quaternion";
+  version = "0.0.9.4e";
 
-    postInstall = if stdenv.isDarwin then ''
-      mkdir -p $out/Applications
-      mv $out/bin/quaternion.app $out/Applications
-      rmdir $out/bin || :
-    '' else ''
-      substituteInPlace $out/share/applications/quaternion.desktop \
-        --replace 'Exec=quaternion' "Exec=$out/bin/quaternion"
-    '';
-
-    meta = with lib; {
-      description = "Cross-platform desktop IM client for the Matrix protocol";
-      homepage    = "https://matrix.org/docs/projects/client/quaternion.html";
-      license     = licenses.gpl3;
-      maintainers = with maintainers; [ peterhoeg ];
-      inherit (qtbase.meta) platforms;
-      inherit version;
-    };
+  src = fetchFromGitHub {
+    owner = "QMatrixClient";
+    repo = "Quaternion";
+    rev = "${version}";
+    sha256 = "sha256-2yEiILiitRPj2hCodUDM8UNVq8crb9nyX21ebuh5EEM=";
   };
 
-in rec {
-  quaternion     = generic "0.0.9.4c"     "12mkwiqqbi4774kwl7gha72jyf0jf547acy6rw8ry249zl4lja54" "" libqmatrixclient_0_5;
-
-  quaternion-git = quaternion;
+  buildInputs = [
+    qtbase
+    qtmultimedia
+    qtquickcontrols
+    qtquickcontrols2
+    qtkeychain
+    libquotient
+    libsecret
+  ];
+
+  nativeBuildInputs = [ cmake qttools ];
+
+  postInstall = if stdenv.isDarwin then ''
+    mkdir -p $out/Applications
+    mv $out/bin/quaternion.app $out/Applications
+    rmdir $out/bin || :
+  '' else ''
+    substituteInPlace $out/share/applications/com.github.quaternion.desktop \
+      --replace 'Exec=quaternion' "Exec=$out/bin/quaternion"
+  '';
+
+  meta = with lib; {
+    description =
+      "Cross-platform desktop IM client for the Matrix protocol";
+    homepage = "https://matrix.org/docs/projects/client/quaternion.html";
+    license = licenses.gpl3;
+    maintainers = with maintainers; [ peterhoeg ];
+    inherit (qtbase.meta) platforms;
+    inherit version;
+  };
 }

pkgs/development/libraries/libquotient/default.nix

@@ -0,0 +1,24 @@
+{ mkDerivation, lib, fetchFromGitHub, cmake, qtbase, qtmultimedia }:
+
+mkDerivation rec {
+  pname = "libquotient";
+  version = "0.5.3.2";
+
+  src = fetchFromGitHub {
+    owner = "quotient-im";
+    repo = "libQuotient";
+    rev = version;
+    sha256 = "0gkwr3yw6k2m0j8cc085b5p2q788rf5nhp1p5hc5d55pc7mci2qs";
+  };
+
+  buildInputs = [ qtbase qtmultimedia ];
+
+  nativeBuildInputs = [ cmake ];
+
+  meta = with lib; {
+    description = "A Qt5 library to write cross-platfrom clients for Matrix";
+    homepage = "https://matrix.org/docs/projects/sdk/quotient";
+    maintainers = with maintainers; [ colemickens ];
+    license = licenses.lgpl21;
+  };
+}

pkgs/top-level/aliases.nix

@@ -250,6 +250,7 @@ mapAliases ({
   libtxc_dxtn_s2tc = throw "removed 2020-03-16, now integrated in Mesa";
   libudev = udev; # added 2018-04-25
   libsexy = throw "libsexy has been removed from nixpkgs, as it's abandoned and no package needed it."; # 2019-12-10
+  libqmatrixclient = throw "libqmatrixclient was renamed to libquotient"; # added 2020-04-09
   links = links2; # added 2016-01-31
   linux_rpi0 = linux_rpi1;
   linuxPackages_rpi0 = linuxPackages_rpi1;
@@ -432,6 +433,7 @@ mapAliases ({
   quake3game = ioquake3; # added 2016-01-14
   qwt6 = libsForQt5.qwt;  # added 2015-12-19
   qtpfsgui = throw "Is now luminanceHDR"; # added 2019-06-26
+  quaternion-git = throw "quaternion-git has been removed in favor of the stable version 'quaternion'"; # added 2020-04-09
   rdf4store = throw "rdf4store has been removed from nixpkgs."; # added 2019-12-21
   rdiff_backup = rdiff-backup;  # added 2014-11-23
   rdmd = dtools;  # added 2017-08-19

pkgs/top-level/all-packages.nix

@@ -1240,14 +1240,9 @@ in
     charles4
   ;
 
-  inherit (libsForQt5.callPackage ../development/libraries/libqmatrixclient { })
-    libqmatrixclient_0_4
-    libqmatrixclient_0_5
-    libqmatrixclient;
-
-  inherit (libsForQt5.callPackage ../applications/networking/instant-messengers/quaternion { })
-    quaternion
-    quaternion-git;
+  libquotient = libsForQt5.callPackage ../development/libraries/libquotient {};
+
+  quaternion = libsForQt5.callPackage ../applications/networking/instant-messengers/quaternion { };
 
   tensor = libsForQt5.callPackage ../applications/networking/instant-messengers/tensor { };