Question about pointDeviated() on smooth branch

[jiseonmin]

Hey @bhaller and @petrelharp, I have a question regarding pointDeviated method on the smooth branch. (Thank you for all the cool new features!) Following Peter's suggestion, I am trying to add a box with two examples to the spatial sims paper about how to set up dispersal without pointDeviated (like the code below) and with pointDeviated that should do something comparable.

So here is how reproduction looks like without `pointDeviated':
reproduction() {
mate = i2.drawByStrength(individual, 1);
if (mate.size()) {
nOff = rpois(1, FECUN);
for (i in seqLen(nOff)) {
pos = individual.spatialPosition + rnorm(2, 0, SD);
if (p1.pointInBounds(pos)) {
offspring = subpop.addCrossed(individual, mate);
offspring.setSpatialPosition(pos);
}
}
}
return;
}

Note that the number of new offspring would be less or equal to nOff because whenever new position is out of bound, it simply does not get added to the subpopulation.

Now, if I use reflecting boundary condition and n=nOff with pointDeviated, will the number of new offspring always be nOff or can it also be smaller than nOff? In other words, if I use reflecting boundary condition for pointDeviated, would the reproduction look the same as above?

[bhaller]

Hi Jiseon! First of all, note that I just merged the smooth branch, so now you want to be back on the main branch. :->

It looks like what you're modeling here are "absorbing" boundary conditions – if a point is generated out of bounds, the offspring gets "absorbed" by the boundary, i.e., is not generated. The pointDeviated() method isn't very useful for absorbing boundaries. As the doc for it says (you can see this if you build SLiMgui from sources now, but I am also about to send a PDF of the new doc to Slack):

The boundary condition must be one of "none", "periodic", "reflecting", "stopping", or "reprising". For "none", no boundary condition is enforced; the deviated points are simply returned as is. For "periodic", "reflecting", and "stopping", the boundary condition is enforced just as it is by the pointPeriodic(), pointReflected(), and pointStopped() methods; see their documentation for further details. For "reprising", if the deviated point is out of bounds a new deviated point will be chosen, based upon the same original point, until a point inside bounds is obtained. Note that absorbing boundaries (for which being out-of-bounds is lethal) would be implemented in script; this method cannot enforce them.

So I would recommend just not using absorbing boundaries as your example for this. :-> With pointDeviated(), you will always get the full number of points requested.

I'd also note that the target usage pattern for pointDeviated() is really setting offspring positions in bulk, which is much more efficient. Here's an example:

initialize() {
	initializeSLiMOptions(dimensionality="xy");
}
1 late() {
	sim.addSubpop("p1", 500);
	p1.individuals.setSpatialPosition(p1.pointUniform(500));
}
late() {
	inds = p1.individuals;
	inds.setSpatialPosition(p1.pointDeviated(size(inds), inds.spatialPosition,
		"reprising", INF, "n", 0.02));
}
20000 late() { }

You can do the same thing in a nonWF model. In (almost) all cases, reproduction now automatically sets the offspring position to the first parent's position, and so all you need is to do a vectorized call to pointDeviated() post-reproduction as above. It's particularly nice for reprising boundaries, as above, because that requires a do-while loop when implemented without pointDeviated() (see section 15.3 for example).

I hope this clears things up. Again, current doc will be posted in Slack soon. :->

[jiseonmin]

Ah okay, the new doc answers my question. Thanks! I will use reprising boundary condition for the example then.

[bhaller]

OK, great. Closing this discussion, then. :->