Can twinBASIC DLL be used without registration?

[GCuser99]

With SeleniumVBA version 3.5, the ActiveX DLL can be used without registration using API declarations to instantiate the class objects late-bound, just like one would with using Windows API functions. Of course using an unregistered copy of the DLL in this manner would not be the recommended practice if one wants the benefits of IntelliSense and the Object browser in the VBA IDE. But just to illustrate the possibilities...

First we need to setup the declare section for the Class constructors and Enums in a Standard module in your project:

'These declarations are the Class constructors
'Make sure to substitute [Path to DLL Folder]\SeleniumVBA_win64.dll with the full path to the unregistered copy of the DLL
Option Explicit

Public Declare PtrSafe Function New_WebDriver Lib "[Path to DLL]\SeleniumVBA_win64.dll" () As Object
Public Declare PtrSafe Function New_WebElements Lib "[Path to DLL]\SeleniumVBA_win64.dll" () As Object
Public Declare PtrSafe Function New_WebCookie Lib "[Path to DLL]\SeleniumVBA_win64.dll" () As Object
Public Declare PtrSafe Function New_WebPrintSettings Lib "[Path to DLL]\SeleniumVBA_win64.dll" () As Object
Public Declare PtrSafe Function New_New_WebJsonConverter Lib "[Path to DLL]\SeleniumVBA_win64.dll" () As Object
Public Declare PtrSafe Function New_WebKeyboard Lib "[Path to DLL]\SeleniumVBA_win64.dll" () As Object
Public Declare PtrSafe Function New_WebDriverManager Lib "[Path to DLL]\SeleniumVBA_win64.dll" () As Object

'Next, we declare the Enums...

Public Enum By
    ID = 0
    TagName = 1
    ClassName = 2
    Name = 3
    CssSelector = 4
    XPath = 5
    LinkText = 6
    PartialLinkText = 7
End Enum

Public Enum ScrollIntoViewOptions_speed
    jump_smooth = 1
    jump_instant = 2
    jump_auto = 3
End Enum

Public Enum ScrollIntoViewOptions_alignment
    align_start = 1
    align_center = 2
    align_end = 3
    align_nearest = 4
End Enum

Public Enum svbaWindowType
    svbaWindow = 0
    svbaTab = 1
End Enum

Public Enum svbaCompatibility
    svbaNotCompatible = 0
    svbaMajor = 1
    svbaMinor = 2
    svbaBuildMajor = 3
    svbaExactMatch = 4
End Enum

Public Enum svbaBrowser
    Chrome = 1
    Edge = 2
    Firefox = 3
    IE = 4
End Enum

Public Enum svbaPlatform
    svbaSystem = 0
    svbaWin32 = 1
    svbaWin64 = 2
End Enum

Public Enum svbaChannel
    svbaStable = 0
    svbaBeta = 1
    svbaDev = 2
    svbaCanary = 3
End Enum

Public Enum svbaAlertHandling
    svbaAccept
    svbaDismiss
    svbaIgnore
    svbaDismissAndNotify
    svbaAcceptAndNotify
End Enum

Public Enum svbaOrientation
    svbaLandscape = 0
    svbaPortrait = 1
End Enum

Public Enum svbaUnits
    svbaCentimeters = 0
    svbaInches = 1
End Enum

Public Enum VBAcolors
    Unchanged = -1
    Black = VBA.ColorConstants.vbBlack
    Blue = VBA.ColorConstants.vbBlue
    Cyan = VBA.ColorConstants.vbCyan
    Green = VBA.ColorConstants.vbGreen
    Magenta = VBA.ColorConstants.vbMagenta
    Red = VBA.ColorConstants.vbRed
    Yellow = VBA.ColorConstants.vbYellow
End Enum

Unfortunately, I could not find a way to define [Path to DLL Folder] in above code as a single constant - API function declares only except string literals for the full path of an unregistered DLL, so the path must be specified for each declaration.

Once you have the declarations and enums, then the rest is straight forward:

Sub test_sendkeys()
    Dim driver As Object
    Dim keys As Object
    Dim keySeq As String
    
    Set driver = New_WebDriver
    Set keys = New_WebKeyboard

    driver.StartEdge
    
    driver.OpenBrowser
    
    driver.NavigateTo "https://www.wikipedia.org/"
    driver.Wait 1000
    
    keySeq = "Leonardo da VinJci" & keys.LeftKey & keys.LeftKey & keys.LeftKey & keys.DeleteKey & keys.ReturnKey
    
    driver.FindElement(By.ID, "searchInput").SendKeys keySeq

    driver.Wait 1500
    
    driver.CloseBrowser
    driver.Shutdown
End Sub

For a complete example set, see the no_registration folder in the repo.