Deprecate GetAllSelectedOptionsText, GetSelectTagsOptions, GetSelectedOptionText?

[GCuser99]

@6DiegoDiego9, I'd like to remove the methods GetAllSelectedOptionsText, GetSelectTagsOptions, and GetSelectedOptionText in the WebElement and WebDriver classes. These all return either a string or string array of text value(s) for dropdown options and were written by anonymous contributor before I wrote the WebElements class. As such I think they are less useful.

I would like to replace with the following more generally useful methods that return WebElement/WebElements:

'@Description("Returns all selected dropdown option elements")
Public Function GetAllSelectedOptions(element As WebElement) As WebElements
    Dim elems As WebElements
    Dim selectedElems As New WebElements
    Dim i As Long

    Set elems = FindElements(By.cssSelector, "option", element)
    For i = 1 To elems.Count
        If IsSelected(elems(i)) Then selectedElems.Add elems(i)
    Next i
    
    Set GetAllSelectedOptions = selectedElems
End Function

'@Description("Returns the first selected dropdown option element")
Public Function GetSelectedOption(element As WebElement) As WebElement
    Dim elems As WebElements
    Dim selectedElem As WebElement
    Dim i As Long

    Set elems = FindElements(By.cssSelector, "option", element)
    For i = 1 To elems.Count
        If IsSelected(elems(i)) Then
            Set selectedElem = elems(i)
            Exit For
        End If
    Next i
    
    Set GetSelectedOption = selectedElem
End Function

Usage:

'Debug.Print dropdownElem.GetSelectedOptionText  'the old way
Debug.Print dropdownElem.GetSelectedOption.GetText 'the new way

Just giving you a heads-up and an opportunity up to provide any feedback... Thanks

[6DiegoDiego9]

100% agree. No feedbacks :)