getLocalOneDrivePath to be updated (?)

[6DiegoDiego9]

Hi @GCuser99

I just noticed that the function in WebShared.getLocalOneDrivePath doesn't convert a OneDrive path to an existent local one, returning the original https path.
I then saw that the provided source link https://stackoverflow.com/a/72736800/11738627 currently shows a different code. I tested with that, and it works!

Do you remember why we have a different code?

If there are no good reasons to keep the different code, I would update it with that code that works.

Best,
Diego

[GCuser99]

Hi @6DiegoDiego9, unfortunately I don't use OneDrive so cannot debug why it is not working...
Below is the original version that we published (from your research) in SeleniumVBA v2.0, and for comparison the latest v6.3. The only differences that I can detect is that I changed the Application.PathSeparator to "\" likely to make the code compatible with MS Access, and then at some point we added the following (which I don't really understand because I don't use OneDrive):

Dim fso As New FileSystemObject
If Not fso.FolderExists(GetLocalOneDrivePath) Then GetLocalOneDrivePath = strPath 'OneDrive folder excluded from sync (@6DiegoDiego9)

Could either one of those changes have caused the issue?

'------------------------SELENIUMVBA VERSION 2.0-----------------------
Private Function GetLocalOneDrivePath(ByVal strPath As String) As String
    ' thanks to @6DiegoDiego9 for doing research on this (see https://stackoverflow.com/a/72736800/11738627)
    ' this function returns the original/local disk path associated with a synched OneDrive or SharePoint cloud url
    
    If isPathHTTPS(strPath) Then
        Const HKEY_CURRENT_USER = &H80000001
        Dim objReg As WbemScripting.SWbemObjectEx 'changed to early binding by GCUser99
        Dim regPath As String
        Dim subKeys() As Variant
        Dim subKey As Variant
        Dim strValue As String
        Dim strMountpoint As String
        Dim strSecPart As String

        Static pathSep As String
        If pathSep = "" Then pathSep = Application.PathSeparator
    
        Set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")

        regPath = "Software\SyncEngines\Providers\OneDrive\"
        objReg.EnumKey HKEY_CURRENT_USER, regPath, subKeys
        
        If isArrayInitialized(subKeys) Then 'found OneDrive in registry
            For Each subKey In subKeys
                objReg.getStringValue HKEY_CURRENT_USER, regPath & subKey, "UrlNamespace", strValue
                If InStr(strPath, strValue) > 0 Then
                    objReg.getStringValue HKEY_CURRENT_USER, regPath & subKey, "MountPoint", strMountpoint
                    strSecPart = Replace(Mid(strPath, Len(strValue)), "/", pathSep)
                    GetLocalOneDrivePath = strMountpoint & strSecPart
        
                    Do Until Dir(GetLocalOneDrivePath, vbDirectory) <> "" Or InStr(2, strSecPart, pathSep) = 0
                        strSecPart = Mid(strSecPart, InStr(2, strSecPart, pathSep))
                        GetLocalOneDrivePath = strMountpoint & strSecPart
                    Loop
                    Exit Function
                End If
            Next subKey
        End If
    End If
        
    GetLocalOneDrivePath = strPath 'pass unchanged
End Function

'------------------------SELENIUMVBA VERSION 6.3-----------------------
Private Function GetLocalOneDrivePath(ByVal strPath As String) As String
    'for more info, see https://stackoverflow.com/a/72736800/11738627 post by Guido Witt-Dorring
    'this function returns the original/local disk path associated with a synched OneDrive or SharePoint cloud url
    
    If isPathHTTPS(strPath) Then
        Const HKEY_CURRENT_USER = &H80000001
        Dim objReg As WbemScripting.SWbemObjectEx 'changed to early binding by GCUser99
        Dim regPath As String
        Dim subKeys() As Variant
        Dim subKey As Variant
        Dim strValue As String
        Dim strMountpoint As String
        Dim strSecPart As String

        Static pathSep As String

        If pathSep = vbNullString Then pathSep = "\" '<------------------------GCUser99 Changed this line
    
        Set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")

        regPath = "Software\SyncEngines\Providers\OneDrive\"
        objReg.EnumKey HKEY_CURRENT_USER, regPath, subKeys
        
        If isArrayInitialized(subKeys) Then 'found OneDrive in registry
            For Each subKey In subKeys
                objReg.getStringValue HKEY_CURRENT_USER, regPath & subKey, "UrlNamespace", strValue
                If InStr(strPath, strValue) > 0 Then
                    objReg.getStringValue HKEY_CURRENT_USER, regPath & subKey, "MountPoint", strMountpoint
                    strSecPart = Replace$(Mid$(strPath, Len(strValue)), "/", pathSep)
                    GetLocalOneDrivePath = strMountpoint & strSecPart
        
                    Do Until Dir(GetLocalOneDrivePath, vbDirectory) <> vbNullString Or InStr(2, strSecPart, pathSep) = 0
                        strSecPart = Mid$(strSecPart, InStr(2, strSecPart, pathSep))
                        GetLocalOneDrivePath = strMountpoint & strSecPart
                    Loop
                    '<------------------------At some point these two lines were added
                    Dim fso As New FileSystemObject         
                    If Not fso.FolderExists(GetLocalOneDrivePath) Then GetLocalOneDrivePath = strPath 'OneDrive folder excluded from sync (@6DiegoDiego9)
                    Exit Function
                End If
            Next subKey
        End If
    End If
        
    GetLocalOneDrivePath = strPath 'pass unchanged
End Function

Private Function isArrayInitialized(ByRef arry() As Variant) As Boolean
    If (Not arry) = -1 Then isArrayInitialized = False Else isArrayInitialized = True
End Function

As far as the original source, I think we used this short version:

Public Function GetLocalPath(ByVal Path As String) As String
    Const HKCU = &H80000001
    Dim objReg As Object, rPath As String, subKeys(), subKey
    Dim urlNamespace As String, mountPoint As String, secPart As String
    Set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\." & _
                           "\root\default:StdRegProv")
    rPath = "Software\SyncEngines\Providers\OneDrive\"
    objReg.EnumKey HKCU, rPath, subKeys
    For Each subKey In subKeys
        objReg.GetStringValue HKCU, rPath & subKey, "UrlNamespace", urlNamespace
        If InStr(Path, urlNamespace) > 0 Then
            objReg.GetStringValue HKCU, rPath & subKey, "MountPoint", mountPoint
            secPart = Replace(Mid(Path, Len(urlNamespace)), "/", "\")
            Path = mountPoint & secPart
            Do Until Dir(Path, vbDirectory) <> "" Or InStr(2, secPart, "\") = 0
                secPart = Mid(secPart, InStr(2, secPart, "\"))
                Path = mountPoint & secPart
            Loop
            Exit For
        End If
    Next
    GetLocalPath = Path
End Function

And then there is always the deluxe version.

[GCuser99]

Maybe it should be:

Dim fso As New FileSystemObject
If Not fso.FolderExists(fso.GetParentFolderName(GetLocalOneDrivePath)) Then GetLocalOneDrivePath = strPath 'OneDrive folder excluded from sync (@6DiegoDiego9)

or:

Dim fso As New FileSystemObject
If Not fso.FileExists(GetLocalOneDrivePath) Then GetLocalOneDrivePath = strPath 'OneDrive folder excluded from sync (@6DiegoDiego9)

?

[6DiegoDiego9]

The current "short version" on StackOverflow, with my mods at the beginning and at the end, works for me as expected for both my OneDrive situations (sync and not sync):

Public Function getLocalOneDrivePath(ByVal Path As String) As String
    Dim origPath As String: origPath = Path '(@6DiegoDiego9)

    Const HKCU = &H80000001
    Dim objReg As Object, rPath As String, subKeys(), subKey
    Dim urlNamespace As String, mountPoint As String, secPart As String
    Set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\." & _
                           "\root\default:StdRegProv")
    rPath = "Software\SyncEngines\Providers\OneDrive\"
    objReg.EnumKey HKCU, rPath, subKeys
    For Each subKey In subKeys
        objReg.GetStringValue HKCU, rPath & subKey, "UrlNamespace", urlNamespace
        If InStr(Path, urlNamespace) > 0 Then
            objReg.GetStringValue HKCU, rPath & subKey, "MountPoint", mountPoint
            secPart = Replace(Mid(Path, Len(urlNamespace)), "/", "\")
            Path = mountPoint & secPart
            Do Until Dir(Path, vbDirectory) <> "" Or InStr(2, secPart, "\") = 0
                secPart = Mid(secPart, InStr(2, secPart, "\"))
                Path = mountPoint & secPart
            Loop
            Exit For
        End If
    Next
    
    Dim fso As New FileSystemObject
    getLocalOneDrivePath = IIf(fso.FileExists(Path), Path, origPath) 'fallback to original path if it's online-only (excluded from sync) (@6DiegoDiego9)
End Function

I'd propose to update with this.

Thanks!

[GCuser99]

What if the path we are trying to resolve is either an existing folder or a file path that has not been created yet (like a save-file path)?
A - Path is to an existing file.
B - Path is to a file and it does not yet exist, but its parent folder exists.
C - Path is to an existing folder.

getLocalOneDrivePath = IIf(fso.FolderExists(fso.GetParentFolderName(Path)), Path, origPath) 'fallback to original path if it's online-only (excluded from sync) (@6DiegoDiego9)

[6DiegoDiego9]

Oh, sorry, you're right! I completely ignored/forgot that this function could be used for folders too, not only for files.

About your last line, it would be perfect, however it seems there is a "bug in the bug" in this "short version" since it skips the folder when converting an online-only fullpath:

In the selected line, "NonSync" is skipped (it's a bug).

fso.GetParentFolderName alone would return True because "C:\Users\i\OneDrive" exists, however I don't have the correct folder "C:\Users\i\OneDrive\NonSync".

I'm not sure how to solve this issue though, because it's not reliably possible(?) to distinguish a path from a fullpath (path+filename), to put two different tests for those cases, fso.GetParentFolderName and fso.FileExists.

[GCuser99]

Thanks for looking into details @6DiegoDiego9. I'm wondering if it would make this easier to solve if we required the callers to only send folder/file paths to getFullLocalPath that are assumed to exist, and/or to indicate whether caller is asking to resolve a folder or a file path.

For example, this line in CreateSettingsFile:

iniFilePath = getFullLocalPath(thisLibFolderPath) & "\SeleniumVBA.ini"

In that case the caller knows it wants to resolve an (assumed) existing folder, not a file. So we could change to:

iniFilePath = getFullLocalPath(thisLibFolderPath, pathType:=enumFolder) & "\SeleniumVBA.ini"

Another in start method of WebDriver class:

driverPath = getFullLocalPath(driverPath, defaultDriverFolder_)

In this case caller wants to resolve an (assumed) existing file path. So we change to:

driverPath = getFullLocalPath(driverPath, defaultDriverFolder_, pathType:=enumFile)

Gets a little trickier with a method like WaitForDownload because the file specified could exist or not. So caller would have to parse the folder path part from the filename part and then resolve the assumed-to-exist folder part of the path, then join back the filename part.

folderPath = parsePath(filePath).Folder
filePath = getFullLocalPath(folderPath , defaultDriverFolder_, pathType:=enumFolder) & "\" & parsePath(filePath).File

In almost all cases, we know what to do from the caller's perspective, and then we can call getFullLocalPath sending the appropriate instructions.

I don't mind reworking all of the callers if you can come up with a OneDrive solution that:

• assumes that input paths exist, whether folder or file (fso.FileExist(Path) Or fso.FolderExists(Path))
• knows ahead of time (from caller) whether it is being asked to resolve a folder or a file

What do you think Diego? Do you think it is possible to solve under those conditions?

[6DiegoDiego9]

Yes, given the circumstances I'm absolutely OK to add a mandatory argument to getLocalOneDrivePath for passing type pathType, provided the fallback to original http path if the final "thing" (folder or file) doesn't exist.
I reuse this function in procedures outside SeleniumVBA too, where I can test if the returned value is still "http" and adapt accordingly.

Thanks a lot for working on this issue Mike, very very appreciated! ♥️

[GCuser99]

@6DiegoDiego9, as far as solving the "bug", have you tried Cristian Buse's LibFileTools. The GetOneDriveLocalPath function there looks like it distinguishes between folder and file paths (requiring that the input path to resolve exists). Do you think that would help solve this problem?

[6DiegoDiego9]

LibFileTools.GetOneDriveLocalPath seems to not have the "bug in the bug":

However, it has plenty of required dependencies (other called procedures) in the module.

LibFileTools.GetLocalPath gives this error:

and unfortunately both LibFileTools.isFolder and LibFileTools.isFile return False :(

I also considered a solution including testing if an URL is a file or a folder, but I don't like to add half a second of running time always. I'd prefer to keep the testing function externally and use it only when needed, for example passing "isFile(myPath)" instead of True/False in our new mandatory argument of GetOneDriveLocalPath.

[GCuser99]

So just to be clear, are you saying that you can fix the bug if you know whether the input path is to a folder or a file? If so, then I will get started refactoring the callers. Please send the solution when you have it...

[6DiegoDiego9]

Yes, I mean, you can simply test if the final path exists using FileExists or FolderExists, depending on whether it is specified as a file or folder:

Dim fso As New FileSystemObject
If pathType = enumFile Then
    If Not fso.FileExists(Path) Then Path = origPath
Else 'folder
    If Not fso.FolderExists(Path) Then Path = origPath
End If

[GCuser99]

If so, then can't we just do:

If Not (fso.FileExists(Path) Or fso.FolderExists(Path)) Then Path = origPath

I would still have to refactor the callers to only send paths that are presumed to exist.

But I still don't see how that would resolve the "bug within the bug" issue (skipping "NonSync")?

[6DiegoDiego9]

I didn't solve the "bug within the bug" issue, and this is the only reason I can't rely on your solution.
Specifically, you would get an unwanted True from fso.FolderExists("C:\Users\i\OneDrive\MASTER_libreria_universale_-_copia.xlam") because "C:\Users\i\OneDrive" exists.
Without the "bug in the bug", it would test "C:\Users\i\OneDrive\NonSync", which doesn't exist and would make your solution work with the double False.

[GCuser99]

But I think fso.FolderExists("C:\Users\i\OneDrive\MASTER_libreria_universale_-_copia.xlam") actually returns False because it interprets MASTER_libreria_universale_-_copia.xlam as part of the folder path. In other words, I think you have to provide just a folder path to fso.FolderExists() to obtain the expected results.

[6DiegoDiego9]

Ahhhh, stupid me, you're 100% right! FolderExists tests the whole thing, not just the folder of it 🤦🏻‍♂️
Let's go with your super easy solution then ✌🏻

[GCuser99]

@6DiegoDiego9 I included the fix in v6.4, but of course since i don't have OneDrive installed, all I could do was test that the fix did not mess up normal Windows paths. Maybe if you get some time you can do a little testing to verify that the solution is good in a OneDrive situation... BTW, the fix is more than just refactoring getLocalOneDrivePath because we need to ensure that we send only existing paths to it. So for example if the path to resolve is to a save-file path, then I resolve the parent folder using getLocalOneDrivePath and then rebuild the save-file path from the results (see getFullLocalPath).