add weapon eventhandler framework

addons/events/CfgFunctions.hpp

@@ -88,6 +88,7 @@ class CfgFunctions {
             PATHTO_FNC(addMarkerEventHandler);
             PATHTO_FNC(removeMarkerEventHandler);
             PATHTO_FNC(registerChatCommand);
+            PATHTO_FNC(weaponEvents);
         };
     };
 };

addons/events/config.cpp

@@ -24,3 +24,24 @@ class RscDisplayChat {
         false\
     );
 };
+
+//#define DEBUG_MODE_FULL
+#ifdef DEBUG_MODE_FULL
+class CfgWeapons {
+    class arifle_MX_Base_F;
+    class arifle_MX_F: arifle_MX_Base_F {
+        class EventHandlers {
+            fired = "_this call CBA_fnc_weaponEvents"; // this weapon eventhandler is required!
+        };
+        class CBA_weaponEvents {
+            handAction = "gestureNo"; // hand animation, from CfgGesturesMale\States
+            sound = "Alarm"; // from CfgSounds
+            soundLocation = "LeftHandMiddle1"; // Where the sound is played. Selection on the soldier, not the weapon! Alternative: RightHandMiddle1
+            delay = 0.5; // delay for sound and hand animation, in seconds
+            onEmpty = 0; // 1: play sound and action defined above on the last round, 0: don't, default 1; the sound below is played anyway
+            soundEmpty = ""; // sound played on the last round
+            soundLocationEmpty = ""; // Where the sound for the last round is played.
+        };
+    };
+};
+#endif

addons/events/fnc_weaponEvents.sqf

@@ -0,0 +1,80 @@
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_weaponEvents
+
+Description:
+    Execute weapon events framework.
+
+    class MyWeapon: MyWeapon_base {
+        class EventHandlers {
+            fired = "_this call CBA_fnc_weaponEvents";
+        };
+    };
+
+Parameters:
+    _unit   - Unit that fired the weapon <OBJECT>
+    _weapon - The weapon fired by the unit <STRING>
+
+Returns:
+    Nothing
+
+Examples:
+    (begin example)
+        fired = "_this call CBA_fnc_weaponEvents";
+    (end)
+
+Author:
+    commy2
+---------------------------------------------------------------------------- */
+#include "script_component.hpp"
+
+params ["_unit", "_weapon"];
+
+private _config = configFile >> "CfgWeapons" >> _weapon >> "CBA_WeaponEvents";
+
+private _isEmpty = _unit ammo _weapon == 0;
+private _onEmpty = true;
+
+if (isNumber (_config >> "onEmpty")) then {
+    _onEmpty = getNumber (_config >> "onEmpty") == 1;
+};
+
+private _fnc_soundSource = {
+    private _soundSourceName = format [QGVAR(soundSource_%1), _soundLocation];
+    private _soundSource = _unit getVariable [_soundSourceName, objNull];
+
+    if !(_soundSource in attachedObjects _unit) then {
+        _soundSource = "Building" createVehicleLocal [0,0,0];
+        _soundSource attachTo [_unit, [0,0,0], _soundLocation];
+        _unit setVariable [_soundSourceName, _soundSource];
+    };
+
+    _soundSource
+};
+
+if (isEmpty) then {
+    private _sound = getText (_config >> "soundEmpty");
+    private _soundLocation = getText (_config >> "soundLocationEmpty");
+
+    if (_sound != "") then {
+        (call _fnc_soundSource) say3D _sound;
+    };
+};
+
+if (!_isEmpty || _onEmpty) then {
+    private _handAction = getText (_config >> "handAction");
+    private _sound = getText (_config >> "sound");
+    private _soundLocation = getText (_config >> "soundLocation");
+    private _delay = getNumber (_config >> "delay");
+
+    [{
+        params ["_unit", "_handAction", "_sound", "_soundSource"];
+
+        if (local _unit) then {
+            _unit playAction _handAction;
+        };
+
+        if (_sound != "") then {
+            _soundSource say3D _sound;
+        };
+    }, [_unit, _handAction, _sound, call _fnc_soundSource], _delay] call CBA_fnc_waitAndExecute;
+};