Add Music functionality

addons/music/CfgFunctions.hpp

@@ -0,0 +1,51 @@
+class CfgFunctions
+{
+    class CBA
+    {
+        class Music
+        {
+            // CBA_fnc_getMusicPath
+            class getMusicPath
+            {
+                description = "Get the config path of given music class";
+                file = "\x\cba\addons\music\fnc_getMusicPath.sqf";
+            };
+            // CBA_fnc_getMusicData
+            class getMusicData
+            {
+                description = "Get data attached to music class";
+                file = "\x\cba\addons\music\fnc_getMusicData.sqf";
+            };
+            // CBA_fnc_findMusic
+            class findMusic
+            {
+                description = "Find music of spesified type";
+                file = "\x\cba\addons\music\fnc_findMusic.sqf";
+            };
+            // CBA_fnc_compileMusic
+            class compileMusic
+            {
+                description = "Find all music in game";
+                file = "\x\cba\addons\music\fnc_compileMusic.sqf";
+            };
+            // CBA_fnc_getMusicPlaying
+            class getMusicPlaying
+            {
+                description = "Returns the data on currently playing music";
+                file = "\x\cba\addons\music\fnc_getMusicPlaying.sqf";
+            };
+            // CBA_fnc_playMusic
+            class playMusic
+            {
+                description = "Play a given track";
+                file = "\x\cba\addons\music\fnc_playMusic.sqf";
+            };
+            // CBA_fnc_stopMusic
+            class stopMusic
+            {
+                description = "Stops the music playing";
+                file = "\x\cba\addons\music\fnc_stopMusic.sqf";
+            };
+        };
+    };
+};

addons/music/CfgMusic.hpp

@@ -0,0 +1,3 @@
+class CfgMusic
+{
+};

addons/music/config.cpp

@@ -0,0 +1,17 @@
+#include "script_component.hpp"
+
+class CfgPatches {
+    class ADDON {
+        author = "$STR_CBA_Author";
+        name = CSTRING(component);
+        url = "$STR_CBA_URL";
+        units[] = {};
+        requiredVersion = REQUIRED_VERSION;
+        requiredAddons[] = {"CBA_common"};
+        version = VERSION;
+        authors[] = {"Fishy"};
+    };
+};
+
+#include "CfgFunctions.hpp"
+#include "CfgMusic.hpp"

addons/music/fnc_compileMusic.sqf

@@ -0,0 +1,54 @@
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_compileMusic
+
+Description:
+    A function used to gather a list of all usable music.
+
+Parameters:
+    none
+
+Returns:
+    Array of compiled music
+
+Example:
+    (begin example)
+        _allMusic = [] call CBA_fnc_compileMusic
+    (end example)
+
+Author:
+    Fishy
+---------------------------------------------------------------------------- */
+#include "script_component.hpp"
+
+if (isNil QGVARMAIN(compiledMusic)) then {
+    private "_config";
+    _config = configFile >> 'CfgMusic';
+    private "_missionConfig";
+    _missionConfig = missionConfigFile >> 'CfgMusic';
+    private "_unsortedSongs";
+    _unsortedSongs = [];
+
+    for [{_i=0}, {_i < (count _config)}, {INC(_i)}] do {
+        private "_song";
+        _song = _config select _i;
+        private "_songDuration";
+        _songDuration = getNumber (_song >> 'duration');
+        if (_songDuration > 0) then {
+            _unsortedSongs pushBack (configName _song);
+        };
+    };
+
+    for [{_i=0}, {_i < (count _missionConfig)}, {INC(_i)}] do {
+        private "_song";
+        _song = _missionConfig select _i;
+        private "_songDuration";
+        _songDuration = getNumber (_song >> 'duration');
+        if (_songDuration > 0) then {
+            _unsortedSongs pushBack (configName _song);
+        };
+    };
+
+    GVARMAIN(compiledMusic) = _unsortedSongs;
+};
+
+GVARMAIN(compiledMusic)

addons/music/fnc_getMusicData.sqf

@@ -0,0 +1,38 @@
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_getMusicData
+
+Description:
+    A function used to return data from the given music class
+
+Parameters:
+    one string OR one config path, and a data type (eg 'name')
+
+Returns:
+    data entry for requested music class
+
+Example:
+    (begin example)
+        _musicName = ["LeadTrack01_F_Bootcamp","Duration"] call CBA_fnc_getMusicData;
+    (end example)
+
+Author:
+    Fishy
+---------------------------------------------------------------------------- */
+#include "script_component.hpp"
+
+params [["_className",""],["_dataType","name"]];
+private "_config";
+
+if (IS_STRING(_classname)) then {
+    //Is a string, get config
+    _config = [_className] call CBA_fnc_getMusicPath;
+} else {
+    if (IS_CONFIG(_className)) then {
+        _config = _className;
+    };
+};
+
+if (!IS_CONFIG(_config)) exitWith {ERROR_1("Config not found",_className);};
+
+//Now we have a config, grab the data
+[_config,_dataType,nil] call BIS_fnc_returnConfigEntry

addons/music/fnc_getMusicPath.sqf

@@ -0,0 +1,36 @@
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_getMusicPath
+
+Description:
+    A function used to return the config path of a music file
+
+Parameters:
+    STRING- name of track
+
+Returns:
+    config entry of given track
+
+Example:
+    (begin example)
+        _configPath = ["LeadTrack01_F_Bootcamp"] call CBA_fnc_getMusicPath
+    (end example)
+
+Authors:
+    Fishy, Dorbedo
+---------------------------------------------------------------------------- */
+#include "script_component.hpp"
+
+if (!params [["_className","",[""]]]) exitWith {WARNING('No classname was provided');};
+
+private "_config";
+_config = configFile >> 'CfgMusic' >> _className;
+private "_duration";
+_duration = getNumber (_config >> "duration");
+
+if (_duration == 0) then {
+    _config = missionConfigFile >> "CfgMusic" >> _className;
+    _duration = getNumber (_config >> "name");
+    if (_duration == 0) exitWith {WARNING_1("No path found for class",_className);nil};
+};
+
+_config 

addons/music/fnc_getMusicPlaying.sqf

@@ -0,0 +1,44 @@
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_getMusicPlaying
+
+Description:
+    A function used to return the current time on playing music. Must have been started with CBA_fnc_playMusic
+
+Parameters:
+    BOOL: if true, return bool (default: false)
+
+Returns:
+    array [class, music time, time left] OR bool (true for playing music)
+
+Example:
+    (begin example)
+        _musicTime = [] call CBA_fnc_getMusicPlaying;
+    (end example)
+
+Author:
+    Fishy
+---------------------------------------------------------------------------- */
+#include "script_component.hpp"
+
+if (!params [["_bool",false,[false]]]) exitWith {WARNING('Incorrect param');};
+
+if (isNil QGVAR(track)) exitWith {
+    if (_bool) then {false} else {['', 0, 0, 0]}
+};
+
+if (_bool) exitWith {true};
+
+GVAR(track) params ["_class","_startTime","_playPos","_duration"];
+private "_trackTime";
+_trackTime = (CBA_missionTime - _startTime) + _playPos;
+private "_remainingTime";
+_remainingTime = _duration - _trackTime;
+if (_remainingTime <=0) then {
+    _remainingTime = 0;
+    _trackTime = 0;
+    _class = "";
+    GVAR(track) = nil;
+};
+
+[_class, _trackTime, _remainingTime]
+

addons/music/fnc_playMusic.sqf

@@ -0,0 +1,53 @@
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_playMusic
+
+Description:
+    A function used to play music. 
+
+Parameters:
+    1: CLASS Class to play
+    2: INT Position to play from (default: 0)
+    3: BOOL allowed to interupt already playing music (default: true)
+
+Returns:
+    BOOL -true if started playing music
+
+Example:
+    (begin example)
+        _bool = ["LeadTrack01_F_Bootcamp", 30, true] call CBA_fnc_playMusic;
+    (end example)
+
+
+Author:
+    Fishy
+---------------------------------------------------------------------------- */
+#include "script_component.hpp"
+
+params [["_className","",[""]],["_time",0,[0]],["_overWrite", true,[true]]];
+
+if (_className isEqualTo "") exitWith {
+    WARNING("No class given"); 
+    false
+};
+
+If ((!_overWrite)&&{[true] call CBA_fnc_getMusicPlaying}) exitWith {false};
+
+private "_return";
+_return = false;
+
+private "_duration";
+_duration = [_className,"duration"] call CBA_fnc_getMusicData;
+
+if (!isNil "_duration") then {
+    if (_time < _duration) then {
+        playMusic [_className, _time];
+        GVAR(track) = [_className,CBA_missionTime,_time,_duration];
+        _return = true;
+    } else {
+        WARNING("Time is greater than song length");
+    };
+} else {
+    WARNING("Music not found");
+};
+
+_return 

addons/music/fnc_stopMusic.sqf

@@ -0,0 +1,27 @@
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_stopMusic
+
+Description:
+    A function used to stop any music playing. Must have been started with CBA_fnc_playMusic, otherwise it is ignored. 
+
+Parameters:
+    none
+
+Returns:
+    BOOL: true if music was stopped, false if already stopped
+
+Example:
+    (begin example)
+        _bool = call CBA_fnc_stopMusic;
+    (end example)
+
+Author:
+    Fishy
+---------------------------------------------------------------------------- */
+#include "script_component.hpp"
+
+if (!([true] call CBA_fnc_getMusicPlaying)) exitWith {false};
+
+playMusic ["",0];
+GVAR(track) = nil;
+true 

addons/music/script_component.hpp

@@ -0,0 +1,7 @@
+#define COMPONENT music
+#include "\x\cba\addons\main\script_mod.hpp"
+
+
+#define DEBUG_MODE_FULL
+#define DEFAULT_SONG_TYPE "song"
+#include "\x\cba\addons\main\script_macros.hpp"