add nix

.envrc

@@ -0,0 +1 @@
+use flake

devshell.nix

@@ -0,0 +1,40 @@
+{ pkgs }:
+
+with pkgs;
+
+let
+  jdk = pkgs.jdk17;
+in
+with pkgs;
+
+# Configure your development environment.
+#
+# Documentation: https://github.com/numtide/devshell
+devshell.mkShell {
+  name = "branch-sdk-android";
+  motd = ''
+    Entered the Branch SDK Android development environment.
+  '';
+  env = [
+    {
+      name = "ANDROID_HOME";
+      value = "${android-sdk}/share/android-sdk";
+    }
+    {
+      name = "ANDROID_SDK_ROOT";
+      value = "${android-sdk}/share/android-sdk";
+    }
+    {
+      name = "JAVA_HOME";
+      value = jdk.home;
+    }
+  ];
+  packages = [
+    android-sdk
+    jdk17 # for android build-tools
+    bun # faster scripting
+    coreutils # for date
+    ngrok
+    jq
+  ];
+}

flake.nix

@@ -0,0 +1,65 @@
+{
+  description = "Branch Android SDK for deep linking and attribution";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs";
+    devshell.url = "github:numtide/devshell";
+    flake-utils.url = "github:numtide/flake-utils";
+    android.url = "github:tadfisher/android-nixpkgs";
+  };
+
+  outputs = { self, nixpkgs, devshell, flake-utils, android }:
+    {
+      overlay = final: prev: {
+        inherit (self.packages.${final.system}) android-sdk;
+      };
+    }
+    //
+    flake-utils.lib.eachSystem [ "aarch64-darwin" "x86_64-darwin" "x86_64-linux" ] (system:
+      let
+        inherit (nixpkgs) lib;
+        pkgs = import nixpkgs {
+          inherit system;
+          config.allowUnfree = true;
+          overlays = [
+            devshell.overlays.default
+            self.overlay
+          ];
+        };
+      in
+      {
+        packages = {
+          android-sdk = android.sdk.${system} (sdkPkgs: with sdkPkgs; [
+            # Useful packages for building and testing.
+            build-tools-34-0-0
+            # build-tools-30-0-3
+            cmdline-tools-latest
+            emulator
+            platform-tools
+            platforms-android-34
+
+            # Other useful packages for a development environment.
+            # ndk-26-1-10909125
+            # skiaparser-3
+            # sources-android-34
+          ]
+          ++ lib.optionals (system == "aarch64-darwin") [
+            system-images-android-34-google-apis-arm64-v8a
+            # system-images-android-34-google-apis-playstore-arm64-v8a
+          ]
+          ++ lib.optionals (system == "x86_64-darwin" || system == "x86_64-linux") [
+            system-images-android-34-google-apis-x86-64
+            # system-images-android-34-google-apis-playstore-x86-64
+          ]);
+        } // lib.optionalAttrs (system == "x86_64-linux") {
+          # Android Studio in nixpkgs is currently packaged for x86_64-linux only.
+          # android-studio = pkgs.androidStudioPackages.stable;
+          # android-studio = pkgs.androidStudioPackages.beta;
+          # android-studio = pkgs.androidStudioPackages.preview;
+          # android-studio = pkgs.androidStudioPackage.canary;
+        };
+
+        devShell = import ./devshell.nix { inherit pkgs; };
+      }
+    );
+}