Gradle 7.5->8

Upgrade breaks with projects (git modules) that have source in root of the module. Fix by creating empty projects and pointing the srcDirs to the existing git modules.

Could just move the sources of each modules into a subdir, but I don't want to mess with non-android usage (desktop client, i18n projects, automations, etc)

build.gradle

@@ -30,7 +30,7 @@ buildscript {
         gradlePluginPortal()
     }
     dependencies {
-        classpath 'com.android.tools.build:gradle:7.4.2'
+        classpath 'com.android.tools.build:gradle:8.1.4'
         // https://github.com/KeepSafe/dexcount-gradle-plugin
         classpath 'com.getkeepsafe.dexcount:dexcount-gradle-plugin:3.1.0'
         classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:${kotlin_version}"

gradle/wrapper/gradle-wrapper.properties

@@ -1,6 +1,6 @@
 #Tue Aug 22 21:17:02 PDT 2023
 distributionBase=GRADLE_USER_HOME
 distributionPath=wrapper/dists
-distributionUrl=https\://services.gradle.org/distributions/gradle-7.5-bin.zip
+distributionUrl=https\://services.gradle.org/distributions/gradle-8.0-bin.zip
 zipStoreBase=GRADLE_USER_HOME
 zipStorePath=wrapper/dists

modules-with-root-src/aercm/AndroidManifest.xml

@@ -0,0 +1,3 @@
+<?xml version="1.0" encoding="utf-8"?>
+<manifest>
+</manifest>

modules-with-root-src/aercm/build.gradle

@@ -0,0 +1,58 @@
+plugins {
+    id 'com.android.library'
+}
+
+android {
+    namespace 'com.aelitis.plugins.rcmplugin'
+    compileSdk rootProject.ext.compileSdkVersion
+
+    defaultConfig {
+        minSdkVersion 14
+        multiDexEnabled true
+    }
+
+
+    compileOptions {
+        encoding = "UTF-8"
+
+        sourceCompatibility JavaVersion.VERSION_1_8
+        targetCompatibility JavaVersion.VERSION_1_8
+    }
+
+
+    sourceSets {
+        main {
+            manifest.srcFile 'AndroidManifest.xml'
+            java {
+                srcDirs = [
+                        '../../BiglyBT-plugin-aercm'
+                ]
+                exclude 'com/aelitis/plugins/rcmplugin/RelatedContentUISWT**'
+                exclude 'com/aelitis/plugins/rcmplugin/SBC_RCMView*'
+                exclude 'com/aelitis/plugins/rcmplugin/RCM_SubViewHolder*'
+                exclude 'com/aelitis/plugins/rcmplugin/RCM_SubView*'
+                exclude 'com/aelitis/plugins/rcmplugin/columns/**'           
+            }
+
+            resources {
+                includes = [
+                        'com/aelitis/plugins/rcmplugin/internat/*.properties',
+                        'com/aelitis/plugins/rcmplugin/resources/**'
+                ]
+                srcDirs = [
+                        '../../BiglyBT-plugin-aercm'
+                ]
+                exclude 'plugin.properties'
+                exclude 'build/**'
+                exclude 'build'
+            }
+        }
+    }
+    lint {
+        abortOnError false
+    }
+}
+
+dependencies {
+    implementation project(path: ':core')
+}

modules-with-root-src/azutp/AndroidManifest.xml

@@ -0,0 +1,3 @@
+<?xml version="1.0" encoding="utf-8"?>
+<manifest>
+</manifest>

modules-with-root-src/azutp/build.gradle

@@ -0,0 +1,59 @@
+plugins {
+    id 'com.android.library'
+}
+
+/*
+To use this in Android Studio, place something like the following in your root settings.gradle
+    include ':BiglyBT-plugin-azutp'
+    project(':BiglyBT-plugin-azutp').buildFileName = 'android-build.gradle'
+or, just rename this file to build.gradle
+*/
+
+android {
+    namespace 'com.vuze.client.plugins.utp'
+    compileSdk rootProject.ext.compileSdkVersion
+
+    defaultConfig {
+        minSdkVersion 14
+        multiDexEnabled true
+    }
+
+
+    compileOptions {
+        encoding = "UTF-8"
+
+        sourceCompatibility JavaVersion.VERSION_1_8
+        targetCompatibility JavaVersion.VERSION_1_8
+    }
+
+
+    sourceSets {
+        main {
+            manifest.srcFile 'AndroidManifest.xml'
+
+            java {
+                srcDirs = [
+                        '../../BiglyBT-plugin-azutp'
+                ]
+            }
+
+            resources {
+                includes = ['**/*.properties']
+                srcDirs = [
+                        '../../BiglyBT-plugin-azutp'
+                ]
+                exclude 'plugin.properties'
+                exclude 'plugin_install.properties'
+                exclude 'build/**'
+                exclude 'build'
+            }
+        }
+    }
+    lint {
+        abortOnError false
+    }
+}
+
+dependencies {
+    implementation project(path: ':core')
+}

modules-with-root-src/xmwebui/AndroidManifest.xml

@@ -0,0 +1,3 @@
+<?xml version="1.0" encoding="utf-8"?>
+<manifest>
+</manifest>

modules-with-root-src/xmwebui/build.gradle

@@ -0,0 +1,60 @@
+plugins {
+    id 'com.android.library'
+}
+
+/*
+To use this in Android Studio, place something like the following in your root settings.gradle
+    include ':BiglyBT-plugin-xmwebui'
+    project(':BiglyBT-plugin-xmwebui').buildFileName = 'android-build.gradle'
+or, just rename this file to build.gradle
+*/
+
+android {
+    namespace 'com.aelitis.azureus.plugins.xmwebui'
+    compileSdk rootProject.ext.compileSdkVersion
+
+    defaultConfig {
+        minSdkVersion 14
+        multiDexEnabled true
+    }
+
+
+    compileOptions {
+        encoding = "UTF-8"
+
+        sourceCompatibility JavaVersion.VERSION_1_8
+        targetCompatibility JavaVersion.VERSION_1_8
+    }
+
+
+    sourceSets {
+        main {
+            manifest.srcFile 'AndroidManifest.xml'
+
+            java {
+                srcDirs = [
+                        '../../BiglyBT-plugin-xmwebui'
+                ]
+                exclude 'com/aelitis/azureus/plugins/xmwebui/swt/**'
+                exclude 'com/aelitis/azureus/plugins/xmwebui/console/**'
+            }
+
+            resources {
+                includes = ['**/*.properties']
+                srcDirs = [
+                        '../../BiglyBT-plugin-xmwebui'
+                ]
+                exclude "plugin.properties"
+                exclude 'build/**'
+                exclude 'build'
+            }
+        }
+    }
+    lint {
+        abortOnError false
+    }
+}
+
+dependencies {
+    implementation project(path: ':core')
+}

settings.gradle

@@ -1,15 +1,23 @@
-include ':recyclerview-fastscroll', ':jiechic-tray', ':Android-DirectoryChooser'
 include ':app'
+
 include ":net.i2p.android-helper"
-project(':jiechic-tray').projectDir = new File('jiechic-tray-version/jiechic-tray')
-project(':Android-DirectoryChooser').projectDir = new File('Android-DirectoryChooser/library')
+include ':recyclerview-fastscroll'
 include ':core'
 include ':mldht'
 include ':BiglyBT-plugin-mlDHT'
-include ":BiglyBT-plugin-aercm"
-project(':BiglyBT-plugin-aercm').buildFileName = 'android-build.gradle'
-include ':BiglyBT-plugin-xmwebui'
-project(':BiglyBT-plugin-xmwebui').buildFileName = 'android-build.gradle'
-include ':BiglyBT-plugin-azutp'
-project(':BiglyBT-plugin-azutp').buildFileName = 'android-build.gradle'
 include ':BiglyBT-plugin-mlDHT-Java6'
+
+include ':jiechic-tray'
+project(':jiechic-tray').projectDir = new File('jiechic-tray-version/jiechic-tray')
+
+include ':Android-DirectoryChooser'
+project(':Android-DirectoryChooser').projectDir = new File('Android-DirectoryChooser/library')
+
+include 'BiglyBT-plugin-aercm'
+project(':BiglyBT-plugin-aercm').projectDir = new File(rootDir, 'modules-with-root-src/aercm')
+
+include ':BiglyBT-plugin-xmwebui'
+project(':BiglyBT-plugin-xmwebui').projectDir = new File(rootDir, 'modules-with-root-src/xmwebui')
+
+include 'BiglyBT-plugin-azutp'
+project(':BiglyBT-plugin-azutp').projectDir = new File(rootDir, 'modules-with-root-src/azutp')