build.upload

apply from: 'build.shared'
apply plugin: 'maven-publish'
apply plugin: 'signing'

sourceCompatibility = 1.8
targetCompatibility = 1.8

test {
  maxParallelForks = Math.max(1, (int)(Runtime.getRuntime().availableProcessors() / 2))
}

test.dependsOn("jar")

def findJVM() {
  String[] java8Paths = new String[5]
  java8Paths[0] = "/usr/lib/jvm/java-8-openjdk-amd64/jre/lib/"
  java8Paths[1] = "/usr/lib/jvm/java-8-openjdk/jre/lib/"
  java8Paths[2] = "/usr/lib/jvm/java-1.8.0-openjdk-amd64/jre/lib/"
  java8Paths[3] = "/usr/lib/jvm/java-1.8.0-openjdk/jre/lib/"
  java8Paths[4] = "/usr/lib/jvm/java-8-sun/jre/lib/"
  for (String path : java8Paths) {
    if (new java.io.File(path).exists()) {
      return path
    }
  }
  return null
}

compileJava {
  def jvmPath = findJVM()
  if (jvmPath == null) {
    println 'Unable to find java 8 rt.jar, will cause failure so exiting now'
    println ''
    System.exit(1)
  }
  println 'Using java 8: ' + jvmPath
  options.bootstrapClasspath = fileTree(include: ['*.jar'], dir: jvmPath)
}

compileTestJava {
  options.compilerArgs << "-Xlint:all" << "-Xlint:-deprecation" << "-Werror"

  options.bootstrapClasspath = fileTree(include: ['*.jar'], dir: findJVM())
}

signing {
  sign configurations.archives
  if (! version.contains('SNAPSHOT')) {
    sign publishing.publications
  }
}

publishing {
  publications {
    mavenJava(MavenPublication) {
      pom {
        name = 'Threadly'
        description = 'A library of tools to assist with safe concurrent java development.'
        url = 'http://threadly.org/'
   
        scm {
          url = 'scm:git@github.com:threadly/threadly.git'
          connection = 'scm:git@github.com:threadly/threadly.git'
          developerConnection = 'scm:git@github.com:threadly/threadly.git'
        }
   
        issueManagement {
          system = 'GitHub'
          url = 'https://github.com/threadly/threadly/issues'
        }

        licenses {
          license {
            name = 'Mozilla Public License Version 2.0'
            url = 'https://www.mozilla.org/MPL/2.0/'
            distribution = 'repo'
          }
        }
 
        developers {
          developer {
            id = 'jent'
            name = 'Mike Jensen'
            email = 'jent@threadly.org'
          }
        }
      }

      from components.java

      artifact(sourcesJar) {
        classifier = 'sources'
      }
      artifact(javadocJar) {
        classifier = 'javadoc'
      }
    }
  }
  repositories {
    maven {
      def releasesRepoUrl =  "https://oss.sonatype.org/service/local/staging/deploy/maven2"
      def snapshotsRepoUrl = "https://oss.sonatype.org/content/repositories/snapshots"
      url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
      credentials {
        username sonatypeUsername
        password sonatypePassword
      }
    }
  }
}

model {
  tasks.generatePomFileForMavenJavaPublication {
    destination = file("$buildDir/generated-pom.xml")
  }
  tasks.publishMavenJavaPublicationToMavenLocal {
    dependsOn project.tasks.signArchives
  }
  tasks.publishMavenJavaPublicationToMavenRepository {
    dependsOn project.tasks.signArchives
  }
}