main.tf

terraform {
    required_providers {
        aws = {
            source  = "hashicorp/aws"
            version = ">= 3.72.0"        
        }
    }
}

provider "aws" {
    region = var.region
}

data "aws_eks_cluster" "cluster" {
    name = module.eks.cluster_id
}

data "aws_eks_cluster_auth" "cluster" {
    name = module.eks.cluster_id    
}

resource "aws_security_group" "worker_group_mgmt_one" {
    name_prefix = "worker_group_mgmt_one"
    vpc_id = module.vpc.vpc_id

    ingress {
        from_port = 22
        to_port = 22
        protocol = "tcp"

        cidr_blocks = [
            "10.0.0.0/8"
        ]
    }
}

resource "aws_security_group" "all_worker_mgmt" {
    name_prefix = "all_worker_management"
    vpc_id = module.vpc.vpc_id

    ingress {
        from_port = 22
        to_port = 22
        protocol = "tcp"
    
        cidr_blocks = [
            "10.0.0.0/8",
            "172.16.0.0/12",
            "192.168.0.0/16"
        ]
    }
}

module "vpc" {
    source = "terraform-aws-modules/vpc/aws"
    version = "3.14.2"
    
    azs = ["${var.region}a", "${var.region}b", "${var.region}c"]

    name = "test-vpc"
    cidr = "10.0.0.0/16"
    private_subnets = [
        "10.0.1.0/24",
        "10.0.2.0/24",
        "10.0.3.0/24"
    ]
    public_subnets = [
        "10.0.4.0/24",
        "10.0.5.0/24",
        "10.0.6.0/24"
    ]

    enable_nat_gateway = true
    single_nat_gateway = true
    enable_dns_hostnames = true

    public_subnet_tags = {
        "kubernetes.io/cluster/${var.cluster_name}" = "shared"
        "kubernetes.io/role/elb" = "1"
    }

    private_subnet_tags = {
        "kubernetes.io/cluster/${var.cluster_name}" = "shared"
        "kubernetes.io/role/internal-elb" = "1"
    }
}

module "eks" {
    source = "terraform-aws-modules/eks/aws"
    version = "18.28.0"

    cluster_name = var.cluster_name
    cluster_version = "1.22"
    
    subnet_ids = module.vpc.private_subnets
    
    cluster_endpoint_private_access = true
    vpc_id = module.vpc.vpc_id

    eks_managed_node_groups = {
        worker-group-1 = {
            min_size     = 1
            max_size     = 10
            desired_size = 1

            instance_types = ["t2.small"]
            capacity_type  = "SPOT"
        }
    }
}

provider "kubernetes" {
    host = data.aws_eks_cluster.cluster.endpoint
    cluster_ca_certificate = base64decode(data.aws_eks_cluster.cluster.certificate_authority.0.data)
    token = data.aws_eks_cluster_auth.cluster.token
}

resource "kubernetes_deployment" "example" {
    metadata {
        name = "terraform-example"
        labels = {
            test = "MyExampleApp"
        }
    }

    spec {
        replicas = 2

        selector {
            match_labels = {
                test = "MyExampleApp"
            }
        }

        template {
            metadata {
                labels = {
                    test = "MyExampleApp"
                }
            }

            spec {
                container {
                    image = "nginx:1.7.8"
                    name = "example"
                
                    resources {
                        limits = {
                            cpu = "0.5"
                            memory = "512Mi"
                        }

                        requests = {
                            cpu = "250m"
                            memory = "50Mi"
                        }
                    }
                }
            }
        }
    }
}

resource "kubernetes_service" "example" {
    metadata { 
        name = "terraform-example"    
    }

    spec {
        selector = {
            test = "MyExampleApp"
        }

        port {
            port = 80
            target_port = 80
        }

        type = "LoadBalancer"
    }
}