rules.xml

<?xml version="1.0" encoding="UTF-8"?>
<rules
    xmlns="http://namespaces.plone.org/diazo"
    xmlns:css="http://namespaces.plone.org/diazo/css"
    xmlns:xi="http://www.w3.org/2001/XInclude"
    xmlns:esi="http://www.edge-delivery.org/esi/1.0"
    xmlns:str="http://exslt.org/strings"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <theme href="index.html" css:if-content="#visual-portal-wrapper" />

    <notheme if-path="source_editor.htm" />
    <notheme if-path="@@manage-viewlets" />
    <notheme if-path="ploneimage.htm" />
    <notheme if="$ajax_load" />

    <rules css:if-content="#visual-portal-wrapper">
        <!--Plone.app.toolbar-->
        <append theme="/html/body" content="//div[@data-iframe='toolbar']" />

        <!--Head-->
        <copy css:content="html" css:theme="html" attributes="lang dir" />
        <prepend css:content-children="head" css:theme="head" />
        <drop css:theme="head link[href='css/plone.css']" />
        <drop css:content="head link[rel='shortcut icon']" />
        <drop css:content="head link[rel='apple-touch-icon']" />
        <drop css:content="head meta[name='viewport']" />
        <drop css:theme="head title" />

        <!-- Header -->
        <replace css:content="#portal-personaltools" css:theme="#user" />
        <replace css:content="#portal-siteactions" css:theme="#siteactions" />
        
        <replace css:content="#portal-globalnav li" css:theme-children="nav ul" />
        <replace css:content="#portal-top form" css:theme-children="header form" />
        
        <!-- Logo transform -->
        <replace css:content="#portal-logo" css:theme=".home-link" />
        
        <replace css:content="#portal-logo">
            <a rel="home" title="Agnogueira's Weblog" href="http://agnogueira.wordpress.com/" class="home-link" sl-processed="1">
            <xsl:attribute name="title"><xsl:value-of select="./@title"/></xsl:attribute>
            <xsl:attribute name="href"><xsl:value-of select="./@href"/></xsl:attribute>
            
              <h1 class="site-title"><xsl:value-of select="./@title"/></h1>
            <h2 class="site-description">Just another <del>WordPress.com</del> <ins> Plone </ins> weblog</h2>
        </a>
        </replace>
            
        
        <!-- Search -->
        <replace css:content="#portal-top form">
        
        <form role="search" method="get" class="search-form">
            <xsl:copy-of select=".//*[@id='portal-searchbox']/form/@*" />
              
            <label>
        <span class="screen-reader-text">Pesquisar por:</span>
      </label>
              
              <input type="search" class="search-field">
                  <xsl:attribute name="placeholder">
                    <xsl:value-of select=".//label[@for='searchGadget']/text()"/>
                  </xsl:attribute> 
                  <xsl:copy-of select=".//input[@id='searchGadget']/@*[local-name() != 'class']"/>
              </input>

        </form>
    
        </replace>
        

        
        
        <!--Content  -->
        <merge attributes="class" css:content="body" css:theme="body" />
        <copy attributes="id dir" css:content="body" css:theme="body" />
        
        <replace css:content-children=".documentFirstHeading" css:theme-children="h1.entry-title" />
        <drop css:content-children=".documentModified span" />
        <replace css:content-children=".documentModified" css:theme-children="time" />
        <replace css:content-children="#category span" css:theme-children=".categories-links" />
        <replace css:content-children="#content-core" css:theme-children=".entry-content" />
        
        
      <!--Conteudo 
        <replace css:content-children="#portal-column-content" css:theme-children="#content>article" />

         -->


        <replace css:content-children="#portal-column-one" css:theme-children="#secondary" />
        <replace css:content-children="#portal-column-two" css:theme-children=".widget-area" />
        
        
        



  <replace css:content=".portlet:not(.managedPortlet)">
      <xsl:if css:test=".portletHeader">
          <h3 class="widget-title"><xsl:apply-templates css:select=".portletHeader > *"/></h3>
      </xsl:if>
      <ul class="nav nav-list">
          <xsl:for-each css:select=".portletItem">
              <li>
                  <xsl:apply-templates select="./*"/>
              </li>
          </xsl:for-each>
      </ul>
      <xsl:if css:test=".portletFooter">
          <xsl:apply-templates css:select=".portletFooter"/>
      </xsl:if>
  </replace>

<replace css:content=".portletNews, .portletEvents">
      <h3 class="widget-title"><xsl:apply-templates css:select=".portletHeader > *"/></h3>
      <ul class="nav nav-list">
          <xsl:for-each css:select=".portletItem">
              <li>
                  <a>
                      <xsl:copy-of select="./a/@*" />
                      <xsl:value-of select="./a/text()"/>
                      <small class="muted">
                          <xsl:copy-of select="./span"/>
                      </small>
                  </a>
              </li>
          </xsl:for-each>
      </ul>
      <xsl:if css:test=".portletFooter">
          <xsl:apply-templates css:select=".portletFooter"/>
      </xsl:if>
  </replace>
  
  <replace css:content=".portletStaticText">
      <div class="well">
          <xsl:if css:test=".portletHeader">
              <h3 class="widget-title"><xsl:apply-templates css:select=".portletHeader > *"/></h3>
          </xsl:if>
          <xsl:apply-templates css:select=".portletItem"/>
          <xsl:apply-templates css:select="div.portletStaticText > *"/>
          <xsl:if css:test=".portletFooter">
              <footer><xsl:apply-templates css:select=".portletFooter"/></footer>
          </xsl:if>
      </div>
  </replace>

  <replace css:content=".portletCalendar">
      <h3 class="widget-title calendarHeader">
          <xsl:apply-templates css:select="#calendar-previous"/>
          <xsl:apply-templates select=".//caption/text()" />
          <xsl:apply-templates css:select="#calendar-next"/>
      </h3>
      <table class="ploneCalendar table table-hover table-condensed" summary="Calendar">
          <xsl:apply-templates select=".//thead" />
          <tbody class="table-bordered">
              <xsl:apply-templates select=".//tbody/tr" />
          </tbody>
      </table>

  </replace>

  <replace css:content=".portletWrapper">
      <aside class="widget">
          <xsl:apply-templates select="./*" />
      </aside>
  </replace>

  <strip css:content=".portletHeader"/>
  <strip css:content=".portletLogin br"/>
  <strip css:content="span[class*='portlet']"/>
  <strip css:content=".portletItem"/>
  <strip css:content=".portletFooter"/>
  
  <replace css:content="span.portletItemDetails">
      <small class="portletItemDetails muted">
          <xsl:apply-templates select="./text()" />
      </small>
  </replace>

     
    </rules>

</rules>