build.gradle

buildscript {
	repositories {
		// mavenLocal()
		mavenCentral()
		gradlePluginPortal()
		// maven { url 'https://oss.sonatype.org/content/repositories/snapshots/' }
	}

	dependencies {
		classpath 'org.anarres.gradle:gradle-stdproject-plugin:1.0.10'
		classpath 'org.anarres.gradle:gradle-sablecc-plugin:1.0.4'
	}
}

apply plugin: 'org.anarres.stdproject'
stdproject {
	javadocGroup "Graphviz Graph Builder", "org.anarres.graphviz.builder"
	javadocGroup "Graphviz Graph Parser", "org.anarres.graphviz.parser"
}

subprojects {
	group = "org.anarres.graphviz"

	apply plugin: 'org.anarres.stdmodule'
	stdmodule {
		description "GraphViz graph builder and parser."
		author id: 'shevek', name: 'Shevek', email: 'github@anarres.org'
		license 'Apache-2.0'
	}

	dependencies {
		compile 'com.google.code.findbugs:annotations:3.0.1'
		compile 'org.slf4j:slf4j-api:1.7.12'
	}

	sourceCompatibility = 1.6

	spotbugs {
		excludeFilter = file("$rootProject.projectDir/gradle/filter.xml")
	}
}

project(':graphviz-builder') {
	dependencies {
		compile 'com.google.guava:guava:18.0'
		// compile 'org.jgrapht:jgrapht-core:0.9.1'
	}
}

project(':graphviz-builder-jgrapht') {
	dependencies {
		compile project(':graphviz-builder')
		compile 'org.jgrapht:jgrapht-core:1.0.0'
	}
}

project(':graphviz-parser') {
	apply plugin: 'sablecc'

	dependencies {
		compile 'com.google.guava:guava:18.0'
	}
}