bintrayUpload.gradle

def projectVersionName = android.defaultConfig.versionName

// load properties
Properties properties = new Properties()
File localPropertiesFile = project.file("local.properties");
if (localPropertiesFile.exists()) {
  properties.load(localPropertiesFile.newDataInputStream())
}
File projectPropertiesFile = project.file("project.properties");
if (projectPropertiesFile.exists()) {
  properties.load(projectPropertiesFile.newDataInputStream())
}
def javadocName = properties.getProperty("javadoc.name")

// This generates sources.jar
task sourcesJar(type: Jar) {
  from android.sourceSets.main.java.srcDirs
  classifier = 'sources'
}

task javadoc(type: Javadoc) {
  source = android.sourceSets.main.java.srcDirs
  classpath += project.files(android.getBootClasspath().join(File.pathSeparator))
}

// This generates javadoc.jar
task javadocJar(type: Jar, dependsOn: javadoc) {
  classifier = 'javadoc'
  from javadoc.destinationDir
}

artifacts {
  archives javadocJar
  archives sourcesJar
}

// javadoc configuration
javadoc {
  options {
    encoding "UTF-8"
    charSet 'UTF-8'
    author true
    version projectVersionName
    links "http://docs.oracle.com/javase/7/docs/api"
    title javadocName
  }
}