'forge-list-global-pullreqs' author filtering

[jtamagnan]

Foreword

First off I want to thank you for the wonderful forge and magit
packages I've been a grateful user for many years and don't know where
I would be without them.

The new topic view is additionally really nice and the new filtering
functions seem much more intuitive. This seems like a step right
direction in a big way.

Background

Before the recent refactor it was easy for me to define a function to
list all pull-requests that were owned by me. I would use this to
check on my pull-requests and see if there were any that I needed to
address issues with, bump, or generally continue working on. The code
was probably not very elegant but roughly looked like:

(defun forge--ls-all-authored-pullreqs ()
    (forge--select-pullreqs nil
      [:from [pullreq repository]
             :where (and (= pullreq:repository repository:id)
                         (in pullreq:author  $v1)
                         (isnull pullreq:closed))]
      (vconcat (mapcar #'car forge-owned-accounts))))
      
(defun forge-list-authored-pullreqs ()
    (interactive)
    (forge--pullreq-list-setup 'authored #'forge--ls-all-authored-pullreqs
                               nil t forge-global-topic-list-columns))

I essentially looked through all of my forge-owned-accounts and
created a new pullreq view from that list.

Problem

Generally it is no longer terribly clear how I can easily pass an
author to forge-list-global-pullreqs such that I can redefine
forge-list-authored-pullreqs in this new world.

This is further exacerbated by an issue where, when looking at the
global topics list I am able to filter by the author but the
pre-generated list of authors is subtly misleading. It is generated by:

(transient-define-suffix forge-topics-filter-author ()
  "Read an author and limit topic list to topics created by that author."
  :class 'forge--topics-filter-command
  :slot 'author
  :reader (lambda () (forge--read-filter-by-user "Author")))

...

(defun forge--read-filter-by-user (prompt)
  (let* ((repo (forge-get-repository :tracked))
         (choices (mapcar #'cadr (oref repo assignees))))
    (magit-completing-read prompt choices)))

This list of authors is actually the list of assignees from the
current repository instead of some global list or a list that is
made to include the owned repositories like:

(defun forge--read-filter-by-user (prompt)
  (let* ((repo (forge-get-repository :tracked))
         (choices (mapcar #'cadr (oref repo assignees))))
    (append (mapcar #'car forge-owned-accounts) choices)))

Solution

1. I think a way to pass in an author or more "filter" information to
   forge-list-global-pullreqs would make it much more flexible for
   others to look at this view as they want.

2. It would be great if one or more of:

   • forge--read-filter-by-user was made to behave differently in a
     global view
   • forge--read-filter-by-user was made to always include the owned
     accounts
   • a new function forge--read-filter-by-author was made to behave
     differently from the user variant

---

I'm not sure how much of this is considered a "bug" vs. a "feature"
but I figured I should go via discussions. I hope this is the right spot.

[jtamagnan]

Ahhh I've come back after a night's rest and thought more about - #676 - which I had found last night. I then cobbled together:

(defun forge-list-global-pullreqs-authored ()
  (interactive)
  (when-let (((forge-db t))
             (repo (forge-get-repository :tracked?))
             (user (ghub--username repo))
             (spec (clone forge-status-buffer-default-topic-filters)))
    (oset spec author user)
    (forge-topics-setup-buffer nil spec :type 'pullreq :global t)
    (transient-setup 'forge-topics-menu)))

This seems to work pretty well. Though it will only work for the github.user associated with the current repository.