CreatePageTurns.plg


{
	Initialize "() {
// v.1.0.0

AddToPluginsMenu('Create Page Turns','Run');}"
	Run "() {
pageTurnStyle = 'Page Turns';
score = Sibelius.ActiveScore;
selection = Sibelius.ActiveScore.Selection;
turnText = '';

if (isSelectionEmpty(selection)) {
	return false;
}

bottomStaff = score.NthStaff(selection.BottomStaff);
firstBar = bottomStaff.NthBar(selection.FirstBarNumber);

dialogResult = Sibelius.ShowDialog(PageTurnDialog, Self);
if (not dialogResult) {
	return false;
}

deleteTextStyleForBar(pageTurnStyle, firstBar);

if (Length(turnText) = 0) {
	return false;
}

turnText = '-' & turnText & '-\n↳';
txtInstance = firstBar.AddText(firstBar.Length, turnText, pageTurnStyle);
txtInstance.ShowInParts();
}"
	PageTurnDialog "Dialog"
	{
		Title "Page Turn Text"
		X "584"
		Y "451"
		Width "111"
		Height "57"
		Controls
		{
			Edit
			{
				Title
				X "5"
				Y "4"
				Width "103"
				Height "14"
				ID "uiTurnText"
				Value "turnText"
				Method
				SetFocus "1"
			}
			Button
			{
				Title "Cancel"
				X "5"
				Y "23"
				Width "50"
				Height "14"
				DefaultButton "0"
				ID "uiCancelBtn"
				Value
				Method
				SetFocus "0"
				EndDialog "0"
			}
			Button
			{
				Title "OK"
				X "57"
				Y "23"
				Width "50"
				Height "14"
				DefaultButton "1"
				ID "uiOkBtn"
				Value
				Method
				SetFocus "0"
				EndDialog "1"
			}
		}
	}
	isSelectionEmpty "(selection) {
for each obj in selection {
	if (IsObject(obj)) {
		 return false;
	}
}

return true;}"
	deleteTextStyleForBar "(txtStyle, bar) {
textToDelete = CreateSparseArray();

for each Text txt in bar {
	if (txt.StyleAsText = txtStyle) {
		textToDelete.Push(txt);
	}
}
for each item in textToDelete {
	item.Delete();
}
}"
	turnText "-Fast-
↳"
}