feat: add supports for split get/set declaration field

[converter]

Fix #82
Fix #106

Author: MangelMaxime

src/Glutinum.Converter/GlueAST.fs

@@ -79,6 +79,24 @@ type GlueProperty =
         IsPrivate: bool
     }
 
+type GlueSetAccessor =
+    {
+        Name: string
+        Documentation: GlueComment list
+        ArgumentType: GlueType
+        IsStatic: bool
+        IsPrivate: bool
+    }
+
+type GlueGetAccessor =
+    {
+        Name: string
+        Documentation: GlueComment list
+        Type: GlueType
+        IsStatic: bool
+        IsPrivate: bool
+    }
+
 type GlueIndexSignature =
     {
         Parameters: GlueParameter list
@@ -103,6 +121,8 @@ type GlueConstructSignature =
 type GlueMember =
     | Method of GlueMethod
     | Property of GlueProperty
+    | GetAccessor of GlueGetAccessor
+    | SetAccessor of GlueSetAccessor
     | CallSignature of GlueCallSignature
     | IndexSignature of GlueIndexSignature
     | MethodSignature of GlueMethodSignature

src/Glutinum.Converter/Reader/Declaration.fs

@@ -122,6 +122,60 @@ let readDeclaration
         : GlueProperty)
         |> GlueMember.Property
 
+    | Ts.SyntaxKind.GetAccessor ->
+        let getAccessorDeclaration = declaration :?> Ts.GetAccessorDeclaration
+        let name = unbox<Ts.Identifier> getAccessorDeclaration.name
+
+        let hasPrivateModifier =
+            ModifierUtil.HasModifier(
+                getAccessorDeclaration.modifiers,
+                Ts.SyntaxKind.PrivateKeyword
+            )
+
+        let isPrivateIdentifier = name.kind = Ts.SyntaxKind.PrivateIdentifier
+
+        ({
+            Name = name.getText ()
+            Documentation = reader.ReadDocumentationFromNode name
+            Type = reader.ReadTypeNode getAccessorDeclaration.``type``
+            IsStatic =
+                ModifierUtil.HasModifier(
+                    getAccessorDeclaration.modifiers,
+                    Ts.SyntaxKind.StaticKeyword
+                )
+            IsPrivate = hasPrivateModifier || isPrivateIdentifier
+        }
+        : GlueGetAccessor)
+        |> GlueMember.GetAccessor
+
+    | Ts.SyntaxKind.SetAccessor ->
+        let setAccessorDeclaration = declaration :?> Ts.SetAccessorDeclaration
+        let name = unbox<Ts.Identifier> setAccessorDeclaration.name
+
+        let hasPrivateModifier =
+            ModifierUtil.HasModifier(
+                setAccessorDeclaration.modifiers,
+                Ts.SyntaxKind.PrivateKeyword
+            )
+
+        let isPrivateIdentifier = name.kind = Ts.SyntaxKind.PrivateIdentifier
+
+        ({
+            Name = name.getText ()
+            Documentation = reader.ReadDocumentationFromNode name
+            ArgumentType =
+                reader.ReadTypeNode
+                    setAccessorDeclaration.parameters.[0].``type``
+            IsStatic =
+                ModifierUtil.HasModifier(
+                    setAccessorDeclaration.modifiers,
+                    Ts.SyntaxKind.StaticKeyword
+                )
+            IsPrivate = hasPrivateModifier || isPrivateIdentifier
+        }
+        : GlueSetAccessor)
+        |> GlueMember.SetAccessor
+
     | _ ->
         generateReaderError
             "declaration"

src/Glutinum.Converter/Transform.fs

@@ -382,6 +382,8 @@ let rec private transformType
                 | GlueMember.IndexSignature _ -> false
                 | GlueMember.MethodSignature _
                 | GlueMember.Property _
+                | GlueMember.GetAccessor _
+                | GlueMember.SetAccessor _
                 | GlueMember.CallSignature _
                 | GlueMember.Method _
                 | GlueMember.ConstructSignature _ -> true
@@ -827,6 +829,61 @@ module private TransformMembers =
         : FSharpMember list
         =
         members
+        // We want to transform GetAccessor / SetAccessor
+        // into a single Property if they are related to the same property
+        |> List.choose (
+            function
+            | GlueMember.GetAccessor getAccessorInfo as self ->
+                let associatedSetAccessor =
+                    members
+                    |> List.tryFind (
+                        function
+                        | GlueMember.SetAccessor setPropertyInfo ->
+                            getAccessorInfo.Name = setPropertyInfo.Name
+                        | _ -> false
+                    )
+
+                match associatedSetAccessor with
+                // If we found an associated SetAccessor, we want to transform into a Property
+                // and it is now a read-write property
+                | Some _ ->
+                    {
+                        Name = getAccessorInfo.Name
+                        Documentation = getAccessorInfo.Documentation
+                        Type = getAccessorInfo.Type
+                        IsOptional = false
+                        IsStatic = getAccessorInfo.IsStatic
+                        Accessor = GlueAccessor.ReadWrite
+                        IsPrivate = getAccessorInfo.IsPrivate
+                    }
+                    |> GlueMember.Property
+                    |> Some
+                // Otherwise, we keep the GetAccessor as is
+                | None -> Some self
+
+            | GlueMember.SetAccessor setAccessorInfo as self ->
+                let associatedGetAccessor =
+                    members
+                    |> List.tryFind (
+                        function
+                        | GlueMember.GetAccessor getPropertyInfo ->
+                            setAccessorInfo.Name = getPropertyInfo.Name
+                        | _ -> false
+                    )
+
+                // If we found an associated GetAccessor, we want to remove the SetAccessor
+                // the property has been transformed into a Property during the GetAccessor check
+                match associatedGetAccessor with
+                | Some _ -> None
+                // Otherwise, we keep the SetAccessor as is
+                | None -> Some self
+            | GlueMember.CallSignature _ as self -> Some self
+            | GlueMember.Method _ as self -> Some self
+            | GlueMember.Property _ as self -> Some self
+            | GlueMember.IndexSignature _ as self -> Some self
+            | GlueMember.MethodSignature _ as self -> Some self
+            | GlueMember.ConstructSignature _ as self -> Some self
+        )
         |> List.choose (
             function
             | GlueMember.Method methodInfo ->
@@ -934,6 +991,52 @@ module private TransformMembers =
                     |> FSharpMember.Property
                     |> Some
 
+            | GlueMember.GetAccessor getAccessorInfo ->
+                let name, context =
+                    sanitizeNameAndPushScope getAccessorInfo.Name context
+
+                let xmlDocInfo = transformComment getAccessorInfo.Documentation
+
+                {
+                    Attributes = [ yield! xmlDocInfo.ObsoleteAttributes ]
+                    Name = name
+                    OriginalName = getAccessorInfo.Name
+                    Parameters = []
+                    Type = transformType context getAccessorInfo.Type
+                    TypeParameters = []
+                    IsOptional = false
+                    IsStatic = getAccessorInfo.IsStatic
+                    Accessor = Some FSharpAccessor.ReadOnly
+                    Accessibility = FSharpAccessibility.Public
+                    XmlDoc = xmlDocInfo.XmlDoc
+                    Body = FSharpMemberInfoBody.NativeOnly
+                }
+                |> FSharpMember.Property
+                |> Some
+
+            | GlueMember.SetAccessor setAccessorInfo ->
+                let name, context =
+                    sanitizeNameAndPushScope setAccessorInfo.Name context
+
+                let xmlDocInfo = transformComment setAccessorInfo.Documentation
+
+                {
+                    Attributes = [ yield! xmlDocInfo.ObsoleteAttributes ]
+                    Name = name
+                    OriginalName = setAccessorInfo.Name
+                    Parameters = []
+                    Type = transformType context setAccessorInfo.ArgumentType
+                    TypeParameters = []
+                    IsOptional = false
+                    IsStatic = setAccessorInfo.IsStatic
+                    Accessor = Some FSharpAccessor.WriteOnly
+                    Accessibility = FSharpAccessibility.Public
+                    XmlDoc = xmlDocInfo.XmlDoc
+                    Body = FSharpMemberInfoBody.NativeOnly
+                }
+                |> FSharpMember.Property
+                |> Some
+
             | GlueMember.IndexSignature indexSignature ->
                 let name, context = sanitizeNameAndPushScope "Item" context
 
@@ -1036,6 +1139,30 @@ module private TransformMembers =
                 }
                 : FSharpParameter
 
+            | GlueMember.GetAccessor getAccessorInfo ->
+                let name, context =
+                    sanitizeNameAndPushScope getAccessorInfo.Name context
+
+                {
+                    Attributes = []
+                    Name = name
+                    IsOptional = false
+                    Type = transformType context getAccessorInfo.Type
+                }
+                : FSharpParameter
+
+            | GlueMember.SetAccessor setAccessorInfo ->
+                let name, context =
+                    sanitizeNameAndPushScope setAccessorInfo.Name context
+
+                {
+                    Attributes = []
+                    Name = name
+                    IsOptional = false
+                    Type = transformType context setAccessorInfo.ArgumentType
+                }
+                : FSharpParameter
+
             | GlueMember.IndexSignature indexSignature ->
                 let name, context = sanitizeNameAndPushScope "Item" context
 
@@ -1206,7 +1333,9 @@ module TypeAliasDeclaration =
                     match m with
                     | GlueMember.Method { Name = caseName }
                     | GlueMember.MethodSignature { Name = caseName }
-                    | GlueMember.Property { Name = caseName } ->
+                    | GlueMember.Property { Name = caseName }
+                    | GlueMember.GetAccessor { Name = caseName }
+                    | GlueMember.SetAccessor { Name = caseName } ->
 
                         let sanitizeResult =
                             Naming.sanitizeNameWithResult caseName
@@ -1524,6 +1653,8 @@ let private transformTypeAliasDeclaration
                         match m with
                         | GlueMember.Method { Type = typ }
                         | GlueMember.Property { Type = typ }
+                        | GlueMember.GetAccessor { Type = typ }
+                        | GlueMember.SetAccessor { ArgumentType = typ }
                         | GlueMember.CallSignature { Type = typ }
                         | GlueMember.ConstructSignature { Type = typ }
                         | GlueMember.MethodSignature { Type = typ }

src/Glutinum.Web/Pages/Editors.GlueAST.GlueASTViewer.fs

@@ -186,6 +186,26 @@ type GlueASTViewer =
                 GlueASTViewer.Type constructSignature.Type
             ]
 
+        | GlueMember.GetAccessor getAccessorInfo ->
+            ASTViewer.renderNode "GetAccessor" [
+                GlueASTViewer.Name getAccessorInfo.Name
+                GlueASTViewer.Documentation getAccessorInfo.Documentation
+                GlueASTViewer.IsStatic getAccessorInfo.IsStatic
+                GlueASTViewer.IsPrivate getAccessorInfo.IsPrivate
+                GlueASTViewer.Type getAccessorInfo.Type
+            ]
+
+        | GlueMember.SetAccessor setAccessorInfo ->
+            ASTViewer.renderNode "SetAccessor" [
+                GlueASTViewer.Name setAccessorInfo.Name
+                GlueASTViewer.Documentation setAccessorInfo.Documentation
+                GlueASTViewer.IsStatic setAccessorInfo.IsStatic
+                GlueASTViewer.IsPrivate setAccessorInfo.IsPrivate
+                ASTViewer.renderNode "ArgumentType" [
+                    GlueASTViewer.GlueType setAccessorInfo.ArgumentType
+                ]
+            ]
+
     static member private Members(members: GlueMember list) =
         members
         |> List.map GlueASTViewer.GlueMember

tests/specs/references/class/propertyDeclaration/getAccessor.d.ts

@@ -0,0 +1,3 @@
+export class Foo {
+    get id(): string;
+}

tests/specs/references/class/propertyDeclaration/getAccessor.fsx

@@ -0,0 +1,20 @@
+module rec Glutinum
+
+open Fable.Core
+open Fable.Core.JsInterop
+open System
+
+[<AbstractClass>]
+[<Erase>]
+type Exports =
+    [<Import("Foo", "REPLACE_ME_WITH_MODULE_NAME"); EmitConstructor>]
+    static member Foo () : Foo = nativeOnly
+
+[<AllowNullLiteral>]
+[<Interface>]
+type Foo =
+    abstract member id: string with get
+
+(***)
+#r "nuget: Fable.Core"
+(***)

tests/specs/references/class/propertyDeclaration/getAndSetAccessor.d.ts

@@ -0,0 +1,4 @@
+export class Foo {
+    get id(): string;
+    set id(value: string);
+}

tests/specs/references/class/propertyDeclaration/getAndSetAccessor.fsx

@@ -0,0 +1,20 @@
+module rec Glutinum
+
+open Fable.Core
+open Fable.Core.JsInterop
+open System
+
+[<AbstractClass>]
+[<Erase>]
+type Exports =
+    [<Import("Foo", "REPLACE_ME_WITH_MODULE_NAME"); EmitConstructor>]
+    static member Foo () : Foo = nativeOnly
+
+[<AllowNullLiteral>]
+[<Interface>]
+type Foo =
+    abstract member id: string with get, set
+
+(***)
+#r "nuget: Fable.Core"
+(***)

tests/specs/references/class/propertyDeclaration/setAccessor.d.ts

@@ -0,0 +1,3 @@
+export class Foo {
+    set id(value: string);
+}

tests/specs/references/class/propertyDeclaration/setAccessor.fsx

@@ -0,0 +1,20 @@
+module rec Glutinum
+
+open Fable.Core
+open Fable.Core.JsInterop
+open System
+
+[<AbstractClass>]
+[<Erase>]
+type Exports =
+    [<Import("Foo", "REPLACE_ME_WITH_MODULE_NAME"); EmitConstructor>]
+    static member Foo () : Foo = nativeOnly
+
+[<AllowNullLiteral>]
+[<Interface>]
+type Foo =
+    abstract member id: string with set
+
+(***)
+#r "nuget: Fable.Core"
+(***)