forked from nf-core/viralrecon
-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathillumina.nf
694 lines (623 loc) · 26.4 KB
/
illumina.nf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
/*
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
PRINT PARAMS SUMMARY
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
*/
include { paramsSummaryLog; paramsSummaryMap } from 'plugin/nf-validation'
def logo = NfcoreTemplate.logo(workflow, params.monochrome_logs)
def citation = '\n' + WorkflowMain.citation(workflow) + '\n'
def summary_params = paramsSummaryMap(workflow)
// Print parameter summary log to screen
log.info logo + paramsSummaryLog(workflow) + citation
/*
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
VALIDATE INPUTS
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
*/
def valid_params = [
protocols : ['metagenomic', 'amplicon'],
variant_callers : ['ivar', 'bcftools'],
consensus_callers : ['ivar', 'bcftools'],
assemblers : ['spades', 'unicycler', 'minia'],
spades_modes : ['rnaviral', 'corona', 'metaviral', 'meta', 'metaplasmid', 'plasmid', 'isolate', 'rna', 'bio']
]
// Validate input parameters
WorkflowIllumina.initialise(params, log, valid_params)
// Check input path parameters to see if they exist
def checkPathParamList = [
params.input, params.fasta, params.gff, params.bowtie2_index,
params.kraken2_db, params.primer_bed, params.primer_fasta,
params.blast_db, params.spades_hmm, params.multiqc_config,
params.freyja_barcodes, params.freyja_lineages
]
for (param in checkPathParamList) { if (param) { file(param, checkIfExists: true) } }
if (params.input) { ch_input = file(params.input) } else { exit 1, 'Input samplesheet file not specified!' }
if (params.spades_hmm) { ch_spades_hmm = file(params.spades_hmm) } else { ch_spades_hmm = [] }
def assemblers = params.assemblers ? params.assemblers.split(',').collect{ it.trim().toLowerCase() } : []
def variant_caller = params.variant_caller
if (!variant_caller) { variant_caller = params.protocol == 'amplicon' ? 'ivar' : 'bcftools' }
/*
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
CONFIG FILES
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
*/
ch_multiqc_config = file("$projectDir/assets/multiqc_config_illumina.yml", checkIfExists: true)
ch_multiqc_custom_config = params.multiqc_config ? file(params.multiqc_config) : []
// Header files
ch_blast_outfmt6_header = file("$projectDir/assets/headers/blast_outfmt6_header.txt", checkIfExists: true)
ch_ivar_variants_header_mqc = file("$projectDir/assets/headers/ivar_variants_header_mqc.txt", checkIfExists: true)
/*
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
IMPORT LOCAL MODULES/SUBWORKFLOWS
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
*/
//
// MODULE: Loaded from modules/local/
//
include { CUTADAPT } from '../modules/local/cutadapt'
include { MULTIQC } from '../modules/local/multiqc_illumina'
include { PLOT_MOSDEPTH_REGIONS as PLOT_MOSDEPTH_REGIONS_GENOME } from '../modules/local/plot_mosdepth_regions'
include { PLOT_MOSDEPTH_REGIONS as PLOT_MOSDEPTH_REGIONS_AMPLICON } from '../modules/local/plot_mosdepth_regions'
//
// SUBWORKFLOW: Consisting of a mix of local and nf-core/modules
//
include { INPUT_CHECK } from '../subworkflows/local/input_check'
include { PREPARE_GENOME } from '../subworkflows/local/prepare_genome_illumina'
include { VARIANTS_IVAR } from '../subworkflows/local/variants_ivar'
include { VARIANTS_BCFTOOLS } from '../subworkflows/local/variants_bcftools'
include { CONSENSUS_IVAR } from '../subworkflows/local/consensus_ivar'
include { CONSENSUS_BCFTOOLS } from '../subworkflows/local/consensus_bcftools'
include { VARIANTS_LONG_TABLE } from '../subworkflows/local/variants_long_table'
include { ASSEMBLY_SPADES } from '../subworkflows/local/assembly_spades'
include { ASSEMBLY_UNICYCLER } from '../subworkflows/local/assembly_unicycler'
include { ASSEMBLY_MINIA } from '../subworkflows/local/assembly_minia'
include { BAM_TRIM_PRIMERS_IVAR } from '../subworkflows/local/bam_trim_primers_ivar'
include { FASTQ_TRIM_FASTP_FASTQC } from '../subworkflows/local/fastq_trim_fastp_fastqc'
/*
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
IMPORT NF-CORE MODULES/SUBWORKFLOWS
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
*/
//
// MODULE: Installed directly from nf-core/modules
//
include { CAT_FASTQ } from '../modules/nf-core/cat/fastq/main'
include { FASTQC } from '../modules/nf-core/fastqc/main'
include { KRAKEN2_KRAKEN2 } from '../modules/nf-core/kraken2/kraken2/main'
include { PICARD_COLLECTMULTIPLEMETRICS } from '../modules/nf-core/picard/collectmultiplemetrics/main'
include { CUSTOM_DUMPSOFTWAREVERSIONS } from '../modules/nf-core/custom/dumpsoftwareversions/main'
include { MOSDEPTH as MOSDEPTH_GENOME } from '../modules/nf-core/mosdepth/main'
include { MOSDEPTH as MOSDEPTH_AMPLICON } from '../modules/nf-core/mosdepth/main'
//
// SUBWORKFLOW: Consisting entirely of nf-core/modules
//
include { FASTQ_ALIGN_BOWTIE2 } from '../subworkflows/nf-core/fastq_align_bowtie2/main'
include { BAM_MARKDUPLICATES_PICARD } from '../subworkflows/nf-core/bam_markduplicates_picard/main'
include { BAM_VARIANT_DEMIX_BOOT_FREYJA } from '../subworkflows/nf-core/bam_variant_demix_boot_freyja/main'
/*
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
RUN MAIN WORKFLOW
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
*/
// Info required for completion email and summary
def multiqc_report = []
def pass_mapped_reads = [:]
def fail_mapped_reads = [:]
workflow ILLUMINA {
ch_versions = Channel.empty()
//
// SUBWORKFLOW: Uncompress and prepare reference genome files
//
PREPARE_GENOME ()
ch_versions = ch_versions.mix(PREPARE_GENOME.out.versions)
// Check genome fasta only contains a single contig
PREPARE_GENOME
.out
.fasta
.map { WorkflowIllumina.isMultiFasta(it, log) }
if (params.protocol == 'amplicon' && !params.skip_variants) {
// Check primer BED file only contains suffixes provided --primer_left_suffix / --primer_right_suffix
PREPARE_GENOME
.out
.primer_bed
.map { WorkflowCommons.checkPrimerSuffixes(it, params.primer_left_suffix, params.primer_right_suffix, log) }
// Check whether the contigs in the primer BED file are present in the reference genome
PREPARE_GENOME
.out
.primer_bed
.map { [ WorkflowCommons.getColFromFile(it, col=0, uniqify=true, sep='\t') ] }
.set { ch_bed_contigs }
PREPARE_GENOME
.out
.fai
.map { [ WorkflowCommons.getColFromFile(it, col=0, uniqify=true, sep='\t') ] }
.concat(ch_bed_contigs)
.collect()
.map { fai, bed -> WorkflowCommons.checkContigsInBED(fai, bed, log) }
// Check whether the primer BED file supplied to the pipeline is from the SWIFT/SNAP protocol
if (!params.ivar_trim_offset) {
PREPARE_GENOME
.out
.primer_bed
.map { WorkflowIllumina.checkIfSwiftProtocol(it, 'covid19genome', log) }
}
}
//
// SUBWORKFLOW: Read in samplesheet, validate and stage input files
//
INPUT_CHECK (
ch_input,
params.platform
)
.sample_info
.map {
meta, fastq ->
meta.id = meta.id.split('_')[0..-2].join('_')
[ meta, fastq ]
}
.groupTuple(by: [0])
.branch {
meta, fastq ->
single : fastq.size() == 1
return [ meta, fastq.flatten() ]
multiple: fastq.size() > 1
return [ meta, fastq.flatten() ]
}
.set { ch_fastq }
ch_versions = ch_versions.mix(INPUT_CHECK.out.versions)
//
// MODULE: Concatenate FastQ files from same sample if required
//
CAT_FASTQ (
ch_fastq.multiple
)
.reads
.mix(ch_fastq.single)
.set { ch_cat_fastq }
ch_versions = ch_versions.mix(CAT_FASTQ.out.versions.first().ifEmpty(null))
//
// SUBWORKFLOW: Read QC and trim adapters
//
FASTQ_TRIM_FASTP_FASTQC (
ch_cat_fastq,
[],
params.save_trimmed_fail,
false
)
ch_variants_fastq = FASTQ_TRIM_FASTP_FASTQC.out.reads
ch_versions = ch_versions.mix(FASTQ_TRIM_FASTP_FASTQC.out.versions)
//
// Filter empty FastQ files after adapter trimming
//
ch_fail_reads_multiqc = Channel.empty()
if (!params.skip_fastp) {
ch_variants_fastq
.join(FASTQ_TRIM_FASTP_FASTQC.out.trim_json)
.map {
meta, reads, json ->
pass = WorkflowIllumina.getFastpReadsAfterFiltering(json) > 0
[ meta, reads, json, pass ]
}
.set { ch_pass_fail_reads }
ch_pass_fail_reads
.map { meta, reads, json, pass -> if (pass) [ meta, reads ] }
.set { ch_variants_fastq }
ch_pass_fail_reads
.map {
meta, reads, json, pass ->
if (!pass) {
fail_mapped_reads[meta.id] = 0
num_reads = WorkflowIllumina.getFastpReadsBeforeFiltering(json)
return [ "$meta.id\t$num_reads" ]
}
}
.collect()
.map {
tsv_data ->
def header = ['Sample', 'Reads before trimming']
WorkflowCommons.multiqcTsvFromList(tsv_data, header)
}
.set { ch_fail_reads_multiqc }
}
//
// MODULE: Run Kraken2 for removal of host reads
//
ch_assembly_fastq = ch_variants_fastq
ch_kraken2_multiqc = Channel.empty()
if (!params.skip_kraken2) {
KRAKEN2_KRAKEN2 (
ch_variants_fastq,
PREPARE_GENOME.out.kraken2_db,
params.kraken2_variants_host_filter || params.kraken2_assembly_host_filter,
params.kraken2_variants_host_filter || params.kraken2_assembly_host_filter
)
ch_kraken2_multiqc = KRAKEN2_KRAKEN2.out.report
ch_versions = ch_versions.mix(KRAKEN2_KRAKEN2.out.versions.first().ifEmpty(null))
if (params.kraken2_variants_host_filter) {
ch_variants_fastq = KRAKEN2_KRAKEN2.out.unclassified_reads_fastq
}
if (params.kraken2_assembly_host_filter) {
ch_assembly_fastq = KRAKEN2_KRAKEN2.out.unclassified_reads_fastq
}
}
//
// SUBWORKFLOW: Alignment with Bowtie2
//
ch_bam = Channel.empty()
ch_bai = Channel.empty()
ch_bowtie2_multiqc = Channel.empty()
ch_bowtie2_flagstat_multiqc = Channel.empty()
if (!params.skip_variants) {
FASTQ_ALIGN_BOWTIE2 (
ch_variants_fastq,
PREPARE_GENOME.out.bowtie2_index,
params.save_unaligned,
false,
PREPARE_GENOME.out.fasta
)
ch_bam = FASTQ_ALIGN_BOWTIE2.out.bam
ch_bai = FASTQ_ALIGN_BOWTIE2.out.bai
ch_bowtie2_multiqc = FASTQ_ALIGN_BOWTIE2.out.log_out
ch_bowtie2_flagstat_multiqc = FASTQ_ALIGN_BOWTIE2.out.flagstat
ch_versions = ch_versions.mix(FASTQ_ALIGN_BOWTIE2.out.versions)
}
//
// Filter channels to get samples that passed Bowtie2 minimum mapped reads threshold
//
ch_fail_mapping_multiqc = Channel.empty()
if (!params.skip_variants) {
ch_bowtie2_flagstat_multiqc
.map { meta, flagstat -> [ meta ] + WorkflowIllumina.getFlagstatMappedReads(flagstat, params) }
.set { ch_mapped_reads }
ch_bam
.join(ch_mapped_reads, by: [0])
.map { meta, ofile, mapped, pass -> if (pass) [ meta, ofile ] }
.set { ch_bam }
ch_bai
.join(ch_mapped_reads, by: [0])
.map { meta, ofile, mapped, pass -> if (pass) [ meta, ofile ] }
.set { ch_bai }
ch_mapped_reads
.branch { meta, mapped, pass ->
pass: pass
pass_mapped_reads[meta.id] = mapped
return [ "$meta.id\t$mapped" ]
fail: !pass
fail_mapped_reads[meta.id] = mapped
return [ "$meta.id\t$mapped" ]
}
.set { ch_pass_fail_mapped }
ch_pass_fail_mapped
.fail
.collect()
.map {
tsv_data ->
def header = ['Sample', 'Mapped reads']
WorkflowCommons.multiqcTsvFromList(tsv_data, header)
}
.set { ch_fail_mapping_multiqc }
}
//
// SUBWORKFLOW: Trim primer sequences from reads with iVar
//
ch_ivar_trim_flagstat_multiqc = Channel.empty()
if (!params.skip_variants && !params.skip_ivar_trim && params.protocol == 'amplicon') {
BAM_TRIM_PRIMERS_IVAR (
ch_bam.join(ch_bai, by: [0]),
PREPARE_GENOME.out.primer_bed,
PREPARE_GENOME.out.fasta
)
ch_bam = BAM_TRIM_PRIMERS_IVAR.out.bam
ch_bai = BAM_TRIM_PRIMERS_IVAR.out.bai
ch_ivar_trim_flagstat_multiqc = BAM_TRIM_PRIMERS_IVAR.out.flagstat
ch_versions = ch_versions.mix(BAM_TRIM_PRIMERS_IVAR.out.versions)
}
//
// SUBWORKFLOW: Mark duplicate reads
//
ch_markduplicates_flagstat_multiqc = Channel.empty()
if (!params.skip_variants && !params.skip_markduplicates) {
BAM_MARKDUPLICATES_PICARD (
ch_bam,
PREPARE_GENOME.out.fasta,
PREPARE_GENOME.out.fai
)
ch_bam = BAM_MARKDUPLICATES_PICARD.out.bam
ch_bai = BAM_MARKDUPLICATES_PICARD.out.bai
ch_markduplicates_flagstat_multiqc = BAM_MARKDUPLICATES_PICARD.out.flagstat
ch_versions = ch_versions.mix(BAM_MARKDUPLICATES_PICARD.out.versions)
}
//
// MODULE: Picard metrics
//
if (!params.skip_variants && !params.skip_picard_metrics) {
PICARD_COLLECTMULTIPLEMETRICS (
ch_bam.join(ch_bai, by: [0]),
PREPARE_GENOME.out.fasta.map { [ [:], it ] },
[ [:], [] ]
)
ch_versions = ch_versions.mix(PICARD_COLLECTMULTIPLEMETRICS.out.versions.first().ifEmpty(null))
}
//
// MODULE: Genome-wide and amplicon-specific coverage QC plots
//
ch_mosdepth_multiqc = Channel.empty()
ch_amplicon_heatmap_multiqc = Channel.empty()
if (!params.skip_variants && !params.skip_mosdepth) {
MOSDEPTH_GENOME (
ch_bam.join(ch_bai, by: [0]),
[ [:], [] ],
[ [:], [] ]
)
ch_mosdepth_multiqc = MOSDEPTH_GENOME.out.global_txt
ch_versions = ch_versions.mix(MOSDEPTH_GENOME.out.versions.first().ifEmpty(null))
PLOT_MOSDEPTH_REGIONS_GENOME (
MOSDEPTH_GENOME.out.regions_bed.collect { it[1] }
)
ch_versions = ch_versions.mix(PLOT_MOSDEPTH_REGIONS_GENOME.out.versions)
if (params.protocol == 'amplicon') {
MOSDEPTH_AMPLICON (
ch_bam.join(ch_bai, by: [0]),
PREPARE_GENOME.out.primer_collapsed_bed.map { [ [:], it ] },
[ [:], [] ]
)
ch_versions = ch_versions.mix(MOSDEPTH_AMPLICON.out.versions.first().ifEmpty(null))
PLOT_MOSDEPTH_REGIONS_AMPLICON (
MOSDEPTH_AMPLICON.out.regions_bed.collect { it[1] }
)
ch_amplicon_heatmap_multiqc = PLOT_MOSDEPTH_REGIONS_AMPLICON.out.heatmap_tsv
ch_versions = ch_versions.mix(PLOT_MOSDEPTH_REGIONS_AMPLICON.out.versions)
}
}
//
// SUBWORKFLOW: Call variants with IVar
//
ch_vcf = Channel.empty()
ch_tbi = Channel.empty()
ch_ivar_counts_multiqc = Channel.empty()
ch_bcftools_stats_multiqc = Channel.empty()
ch_snpsift_txt = Channel.empty()
ch_snpeff_multiqc = Channel.empty()
if (!params.skip_variants && variant_caller == 'ivar') {
VARIANTS_IVAR (
ch_bam,
PREPARE_GENOME.out.fasta,
(params.protocol == 'amplicon' || !params.skip_asciigenome || !params.skip_markduplicates) ? PREPARE_GENOME.out.fai : [],
(params.protocol == 'amplicon' || !params.skip_asciigenome || !params.skip_markduplicates) ? PREPARE_GENOME.out.chrom_sizes : [],
params.gff ? PREPARE_GENOME.out.gff : [],
(params.protocol == 'amplicon' && params.primer_bed) ? PREPARE_GENOME.out.primer_bed : [],
PREPARE_GENOME.out.snpeff_db,
PREPARE_GENOME.out.snpeff_config,
ch_ivar_variants_header_mqc
)
ch_vcf = VARIANTS_IVAR.out.vcf
ch_tbi = VARIANTS_IVAR.out.tbi
ch_ivar_counts_multiqc = VARIANTS_IVAR.out.multiqc_tsv
ch_bcftools_stats_multiqc = VARIANTS_IVAR.out.stats
ch_snpeff_multiqc = VARIANTS_IVAR.out.snpeff_csv
ch_snpsift_txt = VARIANTS_IVAR.out.snpsift_txt
ch_versions = ch_versions.mix(VARIANTS_IVAR.out.versions)
}
//
// SUBWORKFLOW: Call variants with BCFTools
//
if (!params.skip_variants && variant_caller == 'bcftools') {
VARIANTS_BCFTOOLS (
ch_bam,
PREPARE_GENOME.out.fasta,
(params.protocol == 'amplicon' || !params.skip_asciigenome || !params.skip_markduplicates) ? PREPARE_GENOME.out.chrom_sizes : [],
params.gff ? PREPARE_GENOME.out.gff : [],
(params.protocol == 'amplicon' && params.primer_bed) ? PREPARE_GENOME.out.primer_bed : [],
PREPARE_GENOME.out.snpeff_db,
PREPARE_GENOME.out.snpeff_config
)
ch_vcf = VARIANTS_BCFTOOLS.out.vcf
ch_tbi = VARIANTS_BCFTOOLS.out.tbi
ch_bcftools_stats_multiqc = VARIANTS_BCFTOOLS.out.stats
ch_snpeff_multiqc = VARIANTS_BCFTOOLS.out.snpeff_csv
ch_snpsift_txt = VARIANTS_BCFTOOLS.out.snpsift_txt
ch_versions = ch_versions.mix(VARIANTS_BCFTOOLS.out.versions)
}
//
// SUBWORKFLOW: Determine variants with Freyja
//
if (!params.skip_variants && !params.skip_freyja) {
BAM_VARIANT_DEMIX_BOOT_FREYJA(
ch_bam,
PREPARE_GENOME.out.fasta,
params.freyja_repeats,
params.freyja_db_name,
params.freyja_barcodes,
params.freyja_lineages,
)
ch_versions= ch_versions.mix(BAM_VARIANT_DEMIX_BOOT_FREYJA.out.versions)
}
//
// SUBWORKFLOW: Call consensus with iVar and downstream QC
//
ch_quast_multiqc = Channel.empty()
ch_pangolin_multiqc = Channel.empty()
ch_nextclade_report = Channel.empty()
if (!params.skip_consensus && params.consensus_caller == 'ivar') {
CONSENSUS_IVAR (
ch_bam,
PREPARE_GENOME.out.fasta,
params.gff ? PREPARE_GENOME.out.gff : [],
PREPARE_GENOME.out.nextclade_db
)
ch_quast_multiqc = CONSENSUS_IVAR.out.quast_tsv
ch_pangolin_multiqc = CONSENSUS_IVAR.out.pangolin_report
ch_nextclade_report = CONSENSUS_IVAR.out.nextclade_report
ch_versions = ch_versions.mix(CONSENSUS_IVAR.out.versions)
}
//
// SUBWORKFLOW: Call consensus with BCFTools
//
if (!params.skip_consensus && params.consensus_caller == 'bcftools' && variant_caller) {
CONSENSUS_BCFTOOLS (
ch_bam,
ch_vcf,
ch_tbi,
PREPARE_GENOME.out.fasta,
params.gff ? PREPARE_GENOME.out.gff : [],
PREPARE_GENOME.out.nextclade_db
)
ch_quast_multiqc = CONSENSUS_BCFTOOLS.out.quast_tsv
ch_pangolin_multiqc = CONSENSUS_BCFTOOLS.out.pangolin_report
ch_nextclade_report = CONSENSUS_BCFTOOLS.out.nextclade_report
ch_versions = ch_versions.mix(CONSENSUS_BCFTOOLS.out.versions)
}
//
// MODULE: Get Nextclade clade information for MultiQC report
//
ch_nextclade_multiqc = Channel.empty()
if (!params.skip_nextclade) {
ch_nextclade_report
.map { meta, csv ->
def clade = WorkflowCommons.getNextcladeFieldMapFromCsv(csv)['clade']
return [ "$meta.id\t$clade" ]
}
.collect()
.map {
tsv_data ->
def header = ['Sample', 'clade']
WorkflowCommons.multiqcTsvFromList(tsv_data, header)
}
.set { ch_nextclade_multiqc }
}
//
// SUBWORKFLOW: Create variants long table report
//
if (!params.skip_variants && !params.skip_variants_long_table && params.gff && !params.skip_snpeff) {
VARIANTS_LONG_TABLE (
ch_vcf,
ch_tbi,
ch_snpsift_txt,
ch_pangolin_multiqc
)
ch_versions = ch_versions.mix(VARIANTS_LONG_TABLE.out.versions)
}
//
// MODULE: Primer trimming with Cutadapt
//
ch_cutadapt_multiqc = Channel.empty()
if (params.protocol == 'amplicon' && !params.skip_assembly && !params.skip_cutadapt) {
CUTADAPT (
ch_assembly_fastq,
PREPARE_GENOME.out.primer_fasta
)
ch_assembly_fastq = CUTADAPT.out.reads
ch_cutadapt_multiqc = CUTADAPT.out.log
ch_versions = ch_versions.mix(CUTADAPT.out.versions.first().ifEmpty(null))
if (!params.skip_fastqc) {
FASTQC (
CUTADAPT.out.reads
)
ch_versions = ch_versions.mix(FASTQC.out.versions.first().ifEmpty(null))
}
}
//
// SUBWORKFLOW: Run SPAdes assembly and downstream analysis
//
ch_spades_quast_multiqc = Channel.empty()
if (!params.skip_assembly && 'spades' in assemblers) {
ASSEMBLY_SPADES (
ch_assembly_fastq.map { meta, fastq -> [ meta, fastq, [], [] ] },
params.spades_mode,
ch_spades_hmm,
PREPARE_GENOME.out.fasta,
params.gff ? PREPARE_GENOME.out.gff : [],
PREPARE_GENOME.out.blast_db,
ch_blast_outfmt6_header
)
ch_spades_quast_multiqc = ASSEMBLY_SPADES.out.quast_tsv
ch_versions = ch_versions.mix(ASSEMBLY_SPADES.out.versions)
}
//
// SUBWORKFLOW: Run Unicycler assembly and downstream analysis
//
ch_unicycler_quast_multiqc = Channel.empty()
if (!params.skip_assembly && 'unicycler' in assemblers) {
ASSEMBLY_UNICYCLER (
ch_assembly_fastq.map { meta, fastq -> [ meta, fastq, [] ] },
PREPARE_GENOME.out.fasta,
params.gff ? PREPARE_GENOME.out.gff : [],
PREPARE_GENOME.out.blast_db,
ch_blast_outfmt6_header
)
ch_unicycler_quast_multiqc = ASSEMBLY_UNICYCLER.out.quast_tsv
ch_versions = ch_versions.mix(ASSEMBLY_UNICYCLER.out.versions)
}
//
// SUBWORKFLOW: Run minia assembly and downstream analysis
//
ch_minia_quast_multiqc = Channel.empty()
if (!params.skip_assembly && 'minia' in assemblers) {
ASSEMBLY_MINIA (
ch_assembly_fastq,
PREPARE_GENOME.out.fasta,
params.gff ? PREPARE_GENOME.out.gff : [],
PREPARE_GENOME.out.blast_db,
ch_blast_outfmt6_header
)
ch_minia_quast_multiqc = ASSEMBLY_MINIA.out.quast_tsv
ch_versions = ch_versions.mix(ASSEMBLY_MINIA.out.versions)
}
//
// MODULE: Pipeline reporting
//
CUSTOM_DUMPSOFTWAREVERSIONS (
ch_versions.unique().collectFile(name: 'collated_versions.yml')
)
//
// MODULE: MultiQC
//
if (!params.skip_multiqc) {
workflow_summary = WorkflowCommons.paramsSummaryMultiqc(workflow, summary_params)
ch_workflow_summary = Channel.value(workflow_summary)
MULTIQC (
ch_multiqc_config,
ch_multiqc_custom_config,
CUSTOM_DUMPSOFTWAREVERSIONS.out.mqc_yml.collect(),
ch_workflow_summary.collectFile(name: 'workflow_summary_mqc.yaml'),
ch_fail_reads_multiqc.collectFile(name: 'fail_mapped_reads_mqc.tsv').ifEmpty([]),
ch_fail_mapping_multiqc.collectFile(name: 'fail_mapped_samples_mqc.tsv').ifEmpty([]),
ch_amplicon_heatmap_multiqc.ifEmpty([]),
FASTQ_TRIM_FASTP_FASTQC.out.fastqc_raw_zip.collect{it[1]}.ifEmpty([]),
FASTQ_TRIM_FASTP_FASTQC.out.trim_json.collect{it[1]}.ifEmpty([]),
ch_kraken2_multiqc.collect{it[1]}.ifEmpty([]),
ch_bowtie2_flagstat_multiqc.collect{it[1]}.ifEmpty([]),
ch_bowtie2_multiqc.collect{it[1]}.ifEmpty([]),
ch_ivar_trim_flagstat_multiqc.collect{it[1]}.ifEmpty([]),
ch_markduplicates_flagstat_multiqc.collect{it[1]}.ifEmpty([]),
ch_mosdepth_multiqc.collect{it[1]}.ifEmpty([]),
ch_ivar_counts_multiqc.collect{it[1]}.ifEmpty([]),
ch_bcftools_stats_multiqc.collect{it[1]}.ifEmpty([]),
ch_snpeff_multiqc.collect{it[1]}.ifEmpty([]),
ch_quast_multiqc.collect().ifEmpty([]),
ch_pangolin_multiqc.collect{it[1]}.ifEmpty([]),
ch_nextclade_multiqc.collectFile(name: 'nextclade_clade_mqc.tsv').ifEmpty([]),
ch_cutadapt_multiqc.collect{it[1]}.ifEmpty([]),
ch_spades_quast_multiqc.collect().ifEmpty([]),
ch_unicycler_quast_multiqc.collect().ifEmpty([]),
ch_minia_quast_multiqc.collect().ifEmpty([])
)
multiqc_report = MULTIQC.out.report.toList()
}
}
/*
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
COMPLETION EMAIL AND SUMMARY
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
*/
workflow.onComplete {
if (params.email || params.email_on_fail) {
NfcoreTemplate.email(workflow, params, summary_params, projectDir, log, multiqc_report, fail_mapped_reads)
}
NfcoreTemplate.summary(workflow, params, log, fail_mapped_reads, pass_mapped_reads)
}
/*
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
THE END
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
*/