-
Notifications
You must be signed in to change notification settings - Fork 10
/
Copy pathconfigure.ac
2958 lines (2491 loc) · 113 KB
/
configure.ac
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# configure.ac -*- Autoconf -*-
#==============================================================================
# Copyright (C)2003-2011 by Eric Sunshine <sunshine@sunshineco.com>
#
# Autoconf input script for Crystal Space. Process this file with
# CS/bin/autogen.sh to produce a configure script.
#==============================================================================
AC_PREREQ([2.56])
#------------------------------------------------------------------------------
# cs_version_number
# Keep this value synchronized with CS/include/csver.h.template,
# CS/docs/texinfo/version.txi, and CS/mk/autoconf/crystal.m4.
#------------------------------------------------------------------------------
m4_define([cs_version_number], [2.1])
#==============================================================================
# INITIALIZATION
#==============================================================================
AC_INIT([crystalspace], [cs_version_number],
[crystal-main@lists.sourceforge.net])
CS_PACKAGEINFO([Crystal Space],
[Copyright (C)1998-2011 Jorrit Tyberghein and others],
[http://www.crystalspace3d.org/])
AC_CONFIG_SRCDIR([libs/Jamfile])
AC_CONFIG_AUX_DIR([mk/autoconf])
AC_CANONICAL_HOST
CS_PATH_INIT
#------------------------------------------------------------------------------
# Check for compilers and linker.
#------------------------------------------------------------------------------
CS_CHECK_MNO_CYGWIN
CS_PROG_CC
CS_PROG_CXX
CS_PROG_LINK
AC_PROG_CPP
AC_PROG_CXXCPP
CS_EMIT_BUILD_PROPERTY([CMD.C++CPP], [$CXXCPP])
AS_IF([test $ac_compiler_gnu = yes],
[CS_HEADER_PROPERTY([CS_COMPILER_GCC])])
CS_HEADER_PROPERTY([CS_COMPILER_NAME],
[AS_ESCAPE(["])$cs_compiler_name_cxx[]AS_ESCAPE(["])])
#------------------------------------------------------------------------------
# Check for common tools.
#------------------------------------------------------------------------------
CS_CHECK_COMMON_TOOLS_LINK
CS_CHECK_COMMON_TOOLS_BASIC
CS_CHECK_COMMON_TOOLS_DOC_TEXINFO
CS_CHECK_COMMON_TOOLS_DOC_DOXYGEN
CS_CHECK_PROGS([FLEX], [flex])
CS_EMIT_BUILD_PROPERTY([CMD.FLEX], [$FLEX])
CS_CHECK_PROGS([BISON], [bison])
AS_IF([test -n "$BISON"],
[CS_CHECK_PROG_VERSION([bison], [$BISON --version], [1.35], [9.9],
[CS_EMIT_BUILD_PROPERTY([CMD.BISON], [$BISON])])])
CS_CHECK_TOOLS([HHC], [hhc])
CS_EMIT_BUILD_PROPERTY([CMD.HHC], [$HHC])
CS_CHECK_PROGS([SWIG], [swig])
AS_IF([test -n "$SWIG"],
[CS_CHECK_PROG_VERSION([swig], [$SWIG -version 2>&1], [1.3.22],
[9.9|.9],
[CS_EMIT_BUILD_PROPERTY([CMD.SWIG], [$SWIG])
CS_EMIT_BUILD_PROPERTY([CMD.SWIG.VERSION], [$cs_prog_swig_version])])])
CS_CHECK_COMMON_TOOLS_ICONS
# Note that CS comes with a copy of relaytool that, compared to the
# current (as of 2007-09-18) version from apbuild-2.0.5, has some
# additions and small fixes applied. Thus, prefer the version that
# ships with CS.
CS_CHECK_COMMON_TOOLS_RELAYTOOL([${srcdir}/bin])
#------------------------------------------------------------------------------
# Check for subversion and, if available, whether the source directory is an
# SVN checkout.
#------------------------------------------------------------------------------
CS_CHECK_TOOLS([SUBVERSION], [svn])
AS_IF([test -n "$SUBVERSION"],
[AC_CACHE_CHECK([whether ${srcdir} is an SVN checkout], [cs_cv_source_is_svn],
[AS_IF([AC_TRY_COMMAND([$SUBVERSION info ${srcdir} > /dev/null])],
[cs_cv_source_is_svn=yes], [cs_cv_source_is_svn=no])])],
[cs_cv_source_is_svn=no])
CS_EMIT_BUILD_PROPERTY([SOURCE_IS_SVN], [$cs_cv_source_is_svn])
#------------------------------------------------------------------------------
# In order to avoid alienating users by forcing them to install and use Jam,
# config.status is instructed (see far below) to build Jam on the user's behalf
# from local sources, and to place the executable in the root of the build
# directory. When checking for Jam, in addition to PATH, we also look in root
# of the build directory since we might already have built Jam on a previous
# configure run.
#
# IMPLEMENTATION NOTES
#
# The Crystal Space build system supports Jam versions starting with 2.4.
# Earlier versions are rejected. Examples of rejected versions include Apple's
# highly modified Jam (based upon 2.2.1), and ftjam (based upon
# 2.3.2). BoostJam reports its version number as 3.1.9 (or greater), though it
# is actually based upon Jam 2.4. Since we accept 2.4, and since 3.1.9 passes
# the "jam -v >= 2.4" assertion, this version anomaly is not a problem.
#
# We also check for 'make', since it is used to build Jam locally, when needed.
#------------------------------------------------------------------------------
m4_define([cs_jam_local_exe], [jam$EXEEXT])
CS_PATH_PROGS([JAM], [jam], [], [$PATH$PATH_SEPARATOR.])
AS_IF([test -n "$JAM"],
[CS_CHECK_PROG_VERSION([jam], ["$JAM" -v 2>&1], [2.4], [9.9|.9],
[cs_prog_jam_okay=yes], [cs_prog_jam_okay=no])],
[cs_prog_jam_okay=no])
AS_IF([test $cs_prog_jam_okay != yes],
[JAM=./cs_jam_local_exe CS_NEED_LOCAL_JAM=yes])
CS_EMIT_BUILD_PROPERTY([JAM], [$JAM])
CS_CHECK_PROGS([MAKE], [gnumake gmake make])
#------------------------------------------------------------------------------
# The cs-win32libs package is a convenience archive made available to Windows
# users of Crystal Space. It contains common libraries, headers, and tools
# (such as zlib, libjpeg, cal3d, etc.) usable by MSVC, Mingw/MSYS, and Cygwin
# users. It saves users the bother of having to install these packages
# manually one at a time.
#------------------------------------------------------------------------------
CS_NOTABLE([cs-winlibs], [], [windows], [$cs_cv_cslibs],
[CS_CHECK_CSWIN32LIBS])
#------------------------------------------------------------------------------
# Use the CPPFLAGS, CXXFLAGS, CFLAGS, and LDFLAGS passed to configure, as well
# as any additional flags provided by cs-win32libs.
#------------------------------------------------------------------------------
CS_EMIT_BUILD_PROPERTY([COMPILER.CFLAGS], [$CPPFLAGS $CFLAGS], [+])
CS_EMIT_BUILD_PROPERTY([COMPILER.C++FLAGS], [$CPPFLAGS $CXXFLAGS], [+])
CS_EMIT_BUILD_PROPERTY([COMPILER.LFLAGS], [$LDFLAGS], [+])
#------------------------------------------------------------------------------
# Check for typical required libraries (libc, libm, libmx, libdl, libnsl).
#------------------------------------------------------------------------------
AC_LANG_PUSH([C++])
AC_CHECK_HEADERS([cmath], [CS_HEADER_PROPERTY([CS_HAVE_CMATH_H])])
AC_CHECK_HEADERS([math.h], [CS_HEADER_PROPERTY([CS_HAVE_MATH_H])])
AC_CHECK_HEADERS([ieeefp.h], [CS_HEADER_PROPERTY([CS_HAVE_IEEEFP_H])])
AC_LANG_POP([C++])
CS_CHECK_COMMON_LIBS
AS_IF([test $ac_cv_lib_dl_dlopen = yes],
[AC_CHECK_LIB([dl], [dladdr], [CS_HEADER_PROPERTY([CS_HAVE_DLADDR])])])
AS_IF([test $ac_cv_lib_m_cosf != no || test $ac_cv_lib_mx_cosf != no],
[CS_HEADER_PROPERTY([CS_HAVE_MATH_H_FLOAT_FUNCS])])
#------------------------------------------------------------------------------
# Check for pthread. Also check if pthread implementation supports the
# recursive mutex extension and `atfork' functionality.
#------------------------------------------------------------------------------
CS_CHECK_PTHREAD([cygwin*])
CS_EMIT_BUILD_RESULT([cs_cv_sys_pthread], [PTHREAD])
AS_IF([test $cs_cv_sys_pthread_mutex_recursive != no],
[CS_HEADER_PROPERTY([CS_PTHREAD_MUTEX_RECURSIVE],
[$cs_cv_sys_pthread_mutex_recursive])])
CS_CHECK_PTHREAD_ATFORK([cs_cv_sys_pthread_atfork])
CS_EMIT_BUILD_PROPERTY([PTHREAD.ATFORK.AVAILABLE], [$cs_cv_sys_pthread_atfork])
CS_CHECK_PTHREAD_SETNAME_NP([cs_cv_sys_pthread_setname_np])
AS_IF([test cs_cv_sys_pthread_setname_np = yes],
[CS_HEADER_PROPERTY([CS_HAVE_PTHREAD_SETNAME_NP])])
#------------------------------------------------------------------------------
# Determine whether to link base g++ libraries statically
#------------------------------------------------------------------------------
AC_MSG_CHECKING([whether to link base g++ libraries statically])
AC_ARG_ENABLE([static-baselibs], [AC_HELP_STRING([--enable-static-baselibs],
[Link statically against libgcc and libstdc++. Use with caution; enabling
this option may cause issues when dynamically linking against other C++
modules. (default NO)])],
[], [enable_static_baselibs=no])
AC_MSG_RESULT([$enable_static_baselibs])
AS_IF([test $enable_static_baselibs = yes],
[CS_EMIT_BUILD_FLAGS([for -static-libgcc],
[cs_cv_prog_link_static_libgcc], [CS_CREATE_TUPLE([-static-libgcc])],
[C], [COMPILER.LFLAGS], [+])
libstdcxx=`$CXX -print-file-name=libstdc++.a`
CS_CHECK_BUILD_FLAGS([for -static-libstdc++],
[cs_cv_prog_link_static_libstdcxx], [CS_CREATE_TUPLE([-static-libstdc++])],
[C++], [],
[cs_cv_prog_link_static_libstdcxx=$libstdcxx])
CS_EMIT_BUILD_PROPERTY([COMPILER.LFLAGS], [$cs_cv_prog_link_static_libstdcxx], [+])])
#------------------------------------------------------------------------------
# Check if RTLD_NOW dlopen() flag is available; some installations (OpenBSD,
# for example) provide only RTLD_LAZY.
#------------------------------------------------------------------------------
AC_DEFUN([CS_CHECK_RTLD],
[AC_REQUIRE([CS_CHECK_COMMON_LIBS])
CS_CHECK_BUILD([for RTLD_NOW], [cs_cv_sys_rtld_now],
[AC_LANG_PROGRAM([[#include <dlfcn.h>]], [dlopen(0, RTLD_NOW)])],
[], [], [CS_HEADER_PROPERTY([CS_HAVE_RTLD_NOW])], [], [],
[], [], [$cs_cv_libdl_libs])])
CS_CHECK_RTLD
#------------------------------------------------------------------------------
# Determine host platform. Recognized platforms: Unix, Windows, Mac OS X.
# Recognized families: Unix, Windows.
#------------------------------------------------------------------------------
CS_CHECK_HOST
case $cs_host_target in
macosx)
CS_HEADER_PROPERTY([CS_PLATFORM_MACOSX])
# Assume that CoreAudio is always available on Mac OS X.
CS_EMIT_BUILD_PROPERTY([COREAUDIO.AVAILABLE], [yes])
CS_EMIT_BUILD_PROPERTY([COREAUDIO.LFLAGS],
[-framework CoreAudio -framework AudioToolbox])
;;
esac
case $cs_host_family in
windows)
CS_HEADER_PROPERTY([CS_PLATFORM_WIN32])
;;
unix)
CS_HEADER_PROPERTY([CS_PLATFORM_UNIX])
;;
esac
CS_HEADER_PROPERTY([CS_PLATFORM_NAME],
[AS_ESCAPE(["])$cs_host_os_normalized[]AS_ESCAPE(["])])
#------------------------------------------------------------------------------
# Check if Perl SDK is installed and which compiler and linker flags are
# required to embed Perl. Also determine if the glue file can be created with
# ExtUtils::Embed or if it must be created manually.
#------------------------------------------------------------------------------
CS_CHECK_PROGS([PERL], [perl5 perl])
CS_EMIT_BUILD_PROPERTY([PERL5], [$PERL])
CS_EMIT_BUILD_PROPERTY([PERL], [$PERL])
CS_EMIT_BUILD_PROPERTY([CMD.PERL5], [$PERL])
# csperl5 is experimental/testing so default is NO for now.
AC_ARG_WITH([perl], [AC_HELP_STRING([--with-perl],
[use Perl5 scripting interface (default NO)])])
AS_IF([test -z "$with_perl"], [with_perl=no])
AS_IF([test -n "$PERL" && test "$with_perl" != no],
[AC_CACHE_CHECK([for perl ExtUtils::Embed module], [cs_cv_perl_mod_embed],
[AS_IF([AC_RUN_LOG([$PERL -MExtUtils::Embed -e 0 1>&2])],
[cs_cv_perl_mod_embed=yes], [cs_cv_perl_mod_embed=no])])
AS_IF([test $cs_cv_perl_mod_embed = yes],
[CS_EMIT_BUILD_PROPERTY([PERL5.EXTUTILS.EMBED.AVAILABLE], [yes])
AC_CACHE_CHECK([for perl DynaLoader module],
[cs_cv_perl_mod_dynaloader],
[AS_IF([AC_RUN_LOG([$PERL -MDynaLoader -e 0 1>&2])],
[cs_cv_perl_mod_dynaloader=yes],
[cs_cv_perl_mod_dynaloader=no])])
AS_IF([test $cs_cv_perl_mod_dynaloader = yes],
[CS_EMIT_BUILD_PROPERTY([PERL5.DYNALOADER.AVAILABLE], [yes])])],
[# ExtUtils::Embed absent.
AC_MSG_NOTICE([Recommend you install a recent release of Perl 5.])
AC_MSG_NOTICE([http://www.perl.org/])
AC_CACHE_CHECK([for perl Config module], [cs_cv_perl_mod_config],
[AS_IF([AC_RUN_LOG([$PERL -MConfig -e 0 1>&2])],
[cs_cv_perl_mod_config=yes], [cs_cv_perl_mod_config=no])])])
AS_VAR_SET_IF([cs_cv_perl_cflags], [],
[AS_IF([test $cs_cv_perl_mod_embed = yes],
[cs_cv_perl_cflags=`AC_RUN_LOG(
[$PERL -MExtUtils::Embed -e ccopts])`
cs_cv_perl_lflags=`AC_RUN_LOG(
[$PERL -MExtUtils::Embed -e ldopts])`
cs_cv_perl_ext=`AC_RUN_LOG([$PERL -MConfig -e \
'$e = $Config{"dlext"} || $Config{"so"} || ""; print "$e"'])`],
[AS_IF([test $cs_cv_perl_mod_config = yes],
[cs_perl_core=`AC_RUN_LOG(
[$PERL -MConfig -e 'print $Config{archlib}'])`
cs_perl_core="${cs_perl_core}/CORE"
cs_cv_perl_cflags=`AC_RUN_LOG(
[$PERL -MConfig -e 'print $Config{ccflags}'])`
cs_cv_perl_cflags="${cs_cv_perl_cflags} -I${cs_perl_core}"
cs_cv_perl_lflags=`AC_RUN_LOG([$PERL -MConfig -e \
'print $Config{ldflags}, " ", $Config{libs}'])`
cs_cv_perl_lflags="${cs_cv_perl_lflags} -L${cs_perl_core}"
cs_cv_perl_ext=`AC_RUN_LOG([$PERL -MConfig -e \
'$e = $Config{"dlext"}||$Config{"so"}||""; print "$e"'])`],
[cs_perl_core=`AC_RUN_LOG([$PERL -V:archlib | \
$PERL -e '<STDIN> =~ m/\x27(.*)\x27/; print $1'])`
cs_perl_core="${cs_perl_core}/CORE"
cs_cv_perl_cflags=`AC_RUN_LOG([$PERL -V:ccflags | \
$PERL -e '<STDIN> =~ m/\x27(.*)\x27/; print $1'])`
cs_cv_perl_cflags="${cs_cv_perl_cflags} -I${cs_perl_core}"
cs_cv_perl_lflags=`AC_RUN_LOG([$PERL -V:ldflags | \
$PERL -e '<STDIN> =~ m/\x27(.*)\x27/; print $1'])`
cs_perl_lflags_tmp=`AC_RUN_LOG([$PERL -V:libs | \
$PERL -e '<STDIN> =~ m/\x27(.*)\x27/; print $1'])`
cs_cv_perl_lflags="${cs_cv_perl_lflags} ${cs_perl_lflags_tmp}
-L${cs_perl_core}"
cs_cv_perl_ext=`AC_RUN_LOG([$PERL -V:dlext | \
$PERL -e '<STDIN> =~ m/\x27(.*)\x27/; print $1'])`])])
cs_cv_perl_cflags=CS_PATH_NORMALIZE([$cs_cv_perl_cflags])
cs_cv_perl_lflags=CS_PATH_NORMALIZE([$cs_cv_perl_lflags])])
AS_IF([test -n "$cs_cv_perl_cflags$cs_cv_perl_lflags"],
[CS_CHECK_BUILD([if Perl SDK is usable], [cs_cv_perl],
[AC_LANG_PROGRAM(
[[#include <EXTERN.h>
#include <perl.h>]],
[perl_run(0);])],
[CS_CREATE_TUPLE([$cs_cv_perl_cflags],[],[$cs_cv_perl_lflags])])
AS_IF([test $cs_cv_perl = yes],
[CS_EMIT_BUILD_RESULT([cs_cv_perl], [PERL5])
CS_EMIT_BUILD_PROPERTY([PERL5.MODULE_EXT],[.$cs_cv_perl_ext])])])])
CS_NOTABLE([perl], [bindings], [], [$cs_cv_perl])
#------------------------------------------------------------------------------
# Check if Python SDK is installed and which compiler and linker flags are
# required to embed Python.
#------------------------------------------------------------------------------
CS_NOTABLE([python], [bindings], [], [$cs_cv_python],
[CS_CHECK_PYTHON([emit], [], [Python scripting interface])])
#------------------------------------------------------------------------------
# Check if Java SDK is installed and which compiler and linker flags are
# needed. Also check if Ant build tool, which is commonly used to build Java
# projects, is available.
#------------------------------------------------------------------------------
CS_NOTABLE([java], [bindings], [], [$cs_cv_java],
[CS_CHECK_JAVA([emit])])
#------------------------------------------------------------------------------
# Check if STL is available. Although STL is not used heavily in Crystal Space,
# a few plugin modules take advantage of it, so they need to know if it is
# available.
#------------------------------------------------------------------------------
CS_CHECK_STL([CS_EMIT_BUILD_RESULT([cs_cv_libstl], [STL])])
#------------------------------------------------------------------------------
# Check how to enable and disable compilation warnings, and how to promote
# diagnostics from warning to error status.
#------------------------------------------------------------------------------
CS_COMPILER_WARNINGS([C++], [cs_cv_prog_cxx_enable_warnings],
[CS_EMIT_BUILD_PROPERTY([COMPILER.CFLAGS],
[$cs_cv_prog_cxx_enable_warnings], [+])])
CS_COMPILER_ERRORS([C++], [cs_cv_prog_cxx_enable_errors])
CS_COMPILER_IGNORE_UNUSED([C++], [cs_cv_prog_cxx_ignore_unused],
[CS_EMIT_BUILD_PROPERTY([COMPILER.C++FLAGS.WARNING.NO_UNUSED],
[$cs_cv_prog_cxx_ignore_unused])])
CS_COMPILER_IGNORE_UNINITIALIZED([C++], [cs_cv_prog_cxx_ignore_uninitialized],
[CS_EMIT_BUILD_PROPERTY([COMPILER.C++FLAGS.WARNING.NO_UNINITIALIZED],
[$cs_cv_prog_cxx_ignore_uninitialized])])
CS_COMPILER_IGNORE_PRAGMAS([C++], [cs_cv_prog_cxx_ignore_unknown_pragmas],
[CS_EMIT_BUILD_PROPERTY([COMPILER.CFLAGS],
[$cs_cv_prog_cxx_ignore_unknown_pragmas], [+])])
# On MacOS/X, use of `long double' in csutil/formatter.h causes complaints.
CS_COMPILER_IGNORE_LONG_DOUBLE([C++], [cs_cv_prog_cxx_ignore_long_double],
[CS_EMIT_BUILD_PROPERTY([COMPILER.CFLAGS.MANDATORY],
[$cs_cv_prog_cxx_ignore_long_double], [+])])
CS_COMPILER_IGNORE_NON_VIRTUAL_DTOR([C++],
[cs_cv_prog_cxx_ignore_non_virtual_dtor],
[CS_EMIT_BUILD_PROPERTY([COMPILER.C++FLAGS.WARNING.NO_NON_VIRTUAL_DTOR],
[$cs_cv_prog_cxx_ignore_non_virtual_dtor])])
CS_COMPILER_IGNORE_CONST_STRINGS([C++],
[cs_cv_prog_cxx_ignore_const_strings],
[CS_EMIT_BUILD_PROPERTY([COMPILER.C++FLAGS.WARNING.NO_CONST_STRINGS],
[$cs_cv_prog_cxx_ignore_const_strings])])
#------------------------------------------------------------------------------
# Check for option to disable strict-aliasing (enabled by gcc on higher
# optimization levels). This is needed for some code we don't have
# control over (e.g. SWIG-generated code) that breaks strict-aliasing rules.
#------------------------------------------------------------------------------
CS_CHECK_BUILD_FLAGS([for flag to disable strict-aliasing],
[cs_cv_prog_cxx_no_strict_aliasing],
[CS_CREATE_TUPLE([-fno-strict-aliasing])], [C++],
[CS_EMIT_BUILD_PROPERTY([COMPILER.C++FLAGS.STRICTALIASING.DISABLE],
[$cs_cv_prog_cxx_no_strict_aliasing], [+])])
#------------------------------------------------------------------------------
# Check if C++ exceptions can be enabled and disabled.
#------------------------------------------------------------------------------
CS_EMIT_BUILD_FLAGS([how to enable C++ exceptions],
[cs_cv_prog_cxx_enable_exceptions],
[CS_CREATE_TUPLE([-fexceptions -fno-omit-frame-pointer]) \
CS_CREATE_TUPLE([-fexceptions])],
[C++], [COMPILER.C++FLAGS.EXCEPTIONS.ENABLE])
CS_EMIT_BUILD_FLAGS([how to disable C++ exceptions],
[cs_cv_prog_cxx_disable_exceptions], [CS_CREATE_TUPLE([-fno-exceptions])],
[C++], [COMPILER.C++FLAGS.EXCEPTIONS.DISABLE], [],
[CS_EMIT_BUILD_PROPERTY([COMPILER.C++FLAGS],
[$cs_cv_prog_cxx_disable_exceptions], [+])])
#------------------------------------------------------------------------------
# Check how to make compiler comply strongly with the official C++ language
# specification. Crystal Space itself can not abide 100% by the standard (for
# instance, we employ `long long', which is not part of the present
# specification), however, some external projects do so (by using gcc's -ansi
# and -pedantic options, for instance). Because such projects may utilize
# Crystal Space, we must ensure that our public headers likewise comply with
# the official specification.
#------------------------------------------------------------------------------
CS_EMIT_BUILD_FLAGS([how to enforce C++ standards conformance],
[cs_cv_prog_cxx_enable_pedantic], [CS_CREATE_TUPLE([-ansi -pedantic])],
[C++], [COMPILER.C++FLAGS.PEDANTIC.ENABLE])
#------------------------------------------------------------------------------
# Check if the linker recognizes "-force_cpusubtype_ALL". This is required on
# MacOS/X since the Crystal Space's PowerPC implementation of csQsqrt() uses
# the `frsqrte' instruction which is only valid when the -force_cpusubtype_ALL
# flag is present. This flag is marked "mandatory" because it is required even
# for external projects if they use csQsqrt().
#------------------------------------------------------------------------------
AC_DEFUN([CS_CHECK_FORCE_CPUSUBTYPE_ALL],
[CS_CHECK_BUILD_FLAGS([if -force_cpusubtype_ALL is needed],
[cs_cv_prog_cxx_force_cpusubtype_all],
[CS_CREATE_TUPLE([], [-force_cpusubtype_ALL])])])
CS_CHECK_FORCE_CPUSUBTYPE_ALL
CS_EMIT_BUILD_PROPERTY([COMPILER.CFLAGS.MANDATORY],
[$cs_cv_prog_cxx_force_cpusubtype_all], [+])
#------------------------------------------------------------------------------
# Check if the MacOS/X compiler recognizes "-fno-common". This flag is needed
# when building plugin modules (and the libraries which are linked into
# plugins) prior to Apple's introduction of the two-level namespace symbol
# scheme in order to ensure that each plugin module gets its own copy of
# uninitialized global variables.
#------------------------------------------------------------------------------
AC_DEFUN([CS_CHECK_NO_COMMON],
[AC_REQUIRE([AC_CANONICAL_HOST])
case $host_os in
darwin*)
CS_EMIT_BUILD_FLAGS([if -fno-common is needed],
[cs_cv_prog_cxx_no_common],
[CS_CREATE_TUPLE([], [-fno-common])], [C++],
[COMPILER.CFLAGS.MANDATORY], [+])
;;
esac])
CS_CHECK_NO_COMMON
#------------------------------------------------------------------------------
# Check if Mingw and Cygwin compilers recognize -fvtable-thunks. As of gcc
# 3.x, this option is no longer supported. Unfortunately, rather than
# returning an error code (as it does with other unrecognized options), the
# compiler merely prints a warning message when -fvtable-thunks is used, thus
# we use -Werror to turn the warning into an error.
#------------------------------------------------------------------------------
AC_DEFUN([CS_CHECK_VTABLE_THUNKS],
[AC_REQUIRE([AC_CANONICAL_HOST])
case $host_os in
mingw*|cygwin*)
CS_CHECK_BUILD_FLAGS([if -fvtable-thunks is needed],
[cs_cv_prog_cxx_vtable_thunks],
[CS_CREATE_TUPLE([-fvtable-thunks])], [C++],
[CS_EMIT_BUILD_PROPERTY([COMPILER.C++FLAGS.MANDATORY],
[$cs_cv_prog_cxx_vtable_thunks], [+])],
[], [$cs_cv_prog_cxx_enable_errors], [], [],
[no longer supported])
;;
esac])
CS_CHECK_VTABLE_THUNKS
#------------------------------------------------------------------------------
# Check for option to enable OpenMP support.
#------------------------------------------------------------------------------
CS_CHECK_BUILD_FLAGS([for flag to enable OpenMP],
[cs_cv_prog_cxx_openmp],
[CS_CREATE_TUPLE([-fopenmp])], [C++],
[CS_EMIT_BUILD_PROPERTY([COMPILER.C++FLAGS.OPENMP],
[$cs_cv_prog_cxx_openmp], [+])
# At least on gcc the flag needed for linking is -fopenmp as well.
CS_EMIT_BUILD_PROPERTY([COMPILER.LFLAGS.OPENMP],
[$cs_cv_prog_cxx_openmp], [+])])
#------------------------------------------------------------------------------
# Check how to ask the linker to promote warnings to errors.
#------------------------------------------------------------------------------
CS_CHECK_BUILD_FLAGS([how to treat linker warnings as errors],
[cs_cv_prog_link_enable_errors], [CS_CREATE_TUPLE([-Wl,--fatal-warnings])],
[C++])
#------------------------------------------------------------------------------
# Check how to ask the linker to export all dynamic symbols in debug mode to
# allow the backtrace() callstack creation code to obtain symbols in all cases.
#------------------------------------------------------------------------------
CS_CHECK_BUILD_FLAGS([how to export all dynamic symbols],
[cs_cv_prog_link_export_dynamic], [CS_CREATE_TUPLE([-Wl,-E])],
[C++], [CS_EMIT_BUILD_PROPERTY([COMPILER.LFLAGS.debug],
[$cs_cv_prog_link_export_dynamic], [+])],
[], [], [$cs_cv_prog_link_enable_errors])
#------------------------------------------------------------------------------
# Check if linker recognizes --kill-at which is needed to make csjava.dll
# usable by JNI on Windows. Without this, JNI is unable to find the exported
# JNI glue functions in csjava.dll.
#------------------------------------------------------------------------------
CS_CHECK_BUILD([if --kill-at is accepted], [cs_cv_prog_link_kill_at], [],
[CS_CREATE_TUPLE([],[-Wl,--kill-at])], [C++],
[CS_EMIT_BUILD_PROPERTY([CSJAVA.LFLAGS], [-Wl,--kill-at])])
#------------------------------------------------------------------------------
# Check if linker recognizes "-z defs" which is useful on some platforms that
# allow undefined symbols at link time. This can detect possible build issues
# (e.g. not linking against some library, a missing function) that could cause
# problems on stricter platforms.
#------------------------------------------------------------------------------
CS_EMIT_BUILD_FLAGS([if reporting missing symbols is supported],
[cs_cv_prog_link_z_defs], [CS_CREATE_TUPLE([],[-Wl,-z,defs])],
[C++], [COMPILER.LFLAGS.PRIVATE], [+])
CS_EMIT_BUILD_FLAGS([if missing symbols can be reported as warnings],
[cs_cv_prog_link_warn_unresolved_symbols],
[CS_CREATE_TUPLE([],[-Wl,--warn-unresolved-symbols])],
[C++], [COMPILER.LFLAGS.PRIVATE], [+])
#------------------------------------------------------------------------------
# Check if C++ function inlining can be enabled and disabled. Apparently, with
# some versions of GNU build tools on Windows, the Crystal Space Python plugin
# fails to link and emits the error message "Error: 0-bit reloc in dll". In
# particular, this occurs with optimizations (such as -O3) enabled. We can
# avoid the error by disabling function inlining.
#------------------------------------------------------------------------------
CS_EMIT_BUILD_FLAGS([how to disable function inlining],
[cs_cv_prog_cxx_disable_inlining],
[CS_CREATE_TUPLE([-fno-inline-functions])],
[C++], [COMPILER.C++FLAGS.INLINING.DISABLE])
#------------------------------------------------------------------------------
# Check how to declare symbol visibility.
#------------------------------------------------------------------------------
CS_VISIBILITY_FLAG_INLINES_HIDDEN(
[CS_EMIT_BUILD_PROPERTY([COMPILER.C++FLAGS],
[$cs_prog_cxx_visibility_inlines_hidden], [+])])
CS_VISIBILITY_FLAG_HIDDEN([C], [],
[CS_EMIT_BUILD_PROPERTY([COMPILER.CFLAGS],
[$cs_cv_prog_c_visibility_hidden], [+])])
CS_VISIBILITY_FLAG_DEFAULT([C], [],
[CS_EMIT_BUILD_PROPERTY([COMPILER.CFLAGS.VISIBILITY_DEFAULT],
[$cs_cv_prog_c_visibility_default])])
CS_VISIBILITY_DECLARE_HIDDEN([C++], [],
[CS_HEADER_PROPERTY([CS_VISIBILITY_HIDDEN],
[$cs_cv_prog_cxx_declare_visibility_hidden])])
CS_VISIBILITY_DECLARE_DEFAULT([C++], [],
[CS_HEADER_PROPERTY([CS_VISIBILITY_DEFAULT],
[$cs_cv_prog_cxx_declare_visibility_default])])
#------------------------------------------------------------------------------
# Check for compiler- and CPU-specific code generation flags. These flags are
# mutually exclusive. Exclusivity is enforced by the CS_CHECK_CODE_GEN_FLAG()
# macro. Note that use of these flags typically means that the resulting
# binary will not be backward compatible. For instance, if Pentium-specific
# instructions are used, the program will not work with earlier processors,
# such as the Intel 486. Because these options are potentially dangerous,
# their use it controlled by the user via --enable-cpu-specific-optimizations
# which accepts "no" (same as "disable"), "minimum" (the default), and
# "maximum". The "minimum" option selects optimizations which are likely to be
# supported by reasonably modern hardware, thus making the resulting
# executables fairly portable.
#
# CS_CHECK_CODE_GEN_FLAG(CPU-PATTERN, FLAGS, [LANGUAGE])
# If compiler- and CPU-specific optimization flags have not already been
# determined, and if the canonical host CPU matches CPU-PATTERN, try
# using the provided compiler FLAGS with the compiler represented by
# LANGUAGE (typically either "C" or "C++"). If language is omitted, C++
# is used. If the compiler accepts the flags, assign them to the shell
# variable cs_cv_prog_cxx_code_gen.
#------------------------------------------------------------------------------
AC_DEFUN([CS_CHECK_CODE_GEN_FLAG],
[AC_REQUIRE([AC_CANONICAL_HOST])
AS_IF([test "$cs_cv_prog_cxx_code_gen" = no],
[case $host_cpu in
$1) CS_BUILD_IFELSE([],
[CS_CREATE_TUPLE([$2])], m4_default([$3],[C++]),
[cs_cv_prog_cxx_code_gen=$cs_build_cflags], [])
;;
esac])])
AC_MSG_CHECKING([whether to use CPU-specific optimizations])
AC_ARG_ENABLE([cpu-specific-optimizations],
[AC_HELP_STRING([--enable-cpu-specific-optimizations=level],
[enable CPU-specific optimizations; recognized levels are `no',
`minimum' or `min', `maximum' or `max', `native' (default MINIMUM);
the `minimum' option selects optimizations which are likely to be
supported by reasonably modern hardware, thus making the resulting
executables fairly portable; use the `maximum' option with caution
since code for one processor will not work with earlier processors
(for example, Intel 686-specific code will not work with a 586). The
`native' option select optimizations specific for the compiling machine
(thus giving a fairly unportable executable).])],
[case $enable_cpu_specific_optimizations in
yes|min) enable_cpu_specific_optimizations=minimum ;;
max) enable_cpu_specific_optimizations=maximum ;;
esac],
[enable_cpu_specific_optimizations=minimum])
AC_MSG_RESULT([$enable_cpu_specific_optimizations])
case $enable_cpu_specific_optimizations in
no|minimum|maximum|native) ;;
*) CS_MSG_ERROR([unrecognized option; use `no', `minimum', `maximum' or `native'])
;;
esac
AS_IF([test $enable_cpu_specific_optimizations != no],
[AC_CACHE_CHECK([for code generation flags], [cs_cv_prog_cxx_code_gen],
[cs_cv_prog_cxx_code_gen=no
AS_IF([test $enable_cpu_specific_optimizations = native],
[CS_CHECK_CODE_GEN_FLAG([*], [-march=native -mtune=native])])
AS_IF([test $enable_cpu_specific_optimizations = maximum \
|| test $enable_cpu_specific_optimizations = native],
[CS_CHECK_CODE_GEN_FLAG([*686], [-march=pentium3 -mtune=generic])
CS_CHECK_CODE_GEN_FLAG([*686], [-march=pentium3 -mtune=pentium3])
CS_CHECK_CODE_GEN_FLAG([*686], [-march=pentium3])])
AS_IF([test $host_vendor = apple],
[# Work around issue on intel macs, where "-fpmath=sse" is on by
# default, but this breaks compilation when combined with
# the "-march=i586" selected below. Furthermore, -march=i686 was
# reported to not work, but -march=prescott so, so try to use
# that as the "minimum" optimization on x86 Apples, followed by
# -march=i686.
CS_CHECK_CODE_GEN_FLAG([[*[3-9]86]], [-march=prescott])
CS_CHECK_CODE_GEN_FLAG([[*[3-9]86]], [-march=i686])])
CS_CHECK_CODE_GEN_FLAG([x86_64], [-mtune=generic])
CS_CHECK_CODE_GEN_FLAG([x86_64], [-march=k8])
CS_CHECK_CODE_GEN_FLAG([x86_64], [-mtune=k8])
CS_CHECK_CODE_GEN_FLAG([*686], [-march=i686 -mtune=generic])
CS_CHECK_CODE_GEN_FLAG([*686], [-march=i686])
CS_CHECK_CODE_GEN_FLAG([*686], [-mcpu=pentiumpro -march=i686])
CS_CHECK_CODE_GEN_FLAG([*686], [-mcpu=pentiumpro])
CS_CHECK_CODE_GEN_FLAG([*686], [-mpentiumpro -march=i686])
CS_CHECK_CODE_GEN_FLAG([*686], [-mpentiumpro])
CS_CHECK_CODE_GEN_FLAG([[*[5-6]86]], [-march=i586 -mtune=generic])
CS_CHECK_CODE_GEN_FLAG([[*[5-6]86]], [-march=i586])
CS_CHECK_CODE_GEN_FLAG([[*[5-6]86]], [-mcpu=pentium -march=i586])
CS_CHECK_CODE_GEN_FLAG([[*[5-6]86]], [-mcpu=pentium])
CS_CHECK_CODE_GEN_FLAG([[*[5-6]86]], [-mpentium -march=i586])
CS_CHECK_CODE_GEN_FLAG([[*[5-6]86]], [-mpentium])
CS_CHECK_CODE_GEN_FLAG([[*[3-9]86]], [-march=i486])
CS_CHECK_CODE_GEN_FLAG([[*[3-9]86]], [-mcpu=i486 -march=i486])
CS_CHECK_CODE_GEN_FLAG([[*[3-9]86]], [-mcpu=i486])
CS_CHECK_CODE_GEN_FLAG([[*[3-9]86]], [-m486])
CS_CHECK_CODE_GEN_FLAG([alpha], [-mieee])])
AS_IF([test "$cs_cv_prog_cxx_code_gen" != no],
[CS_EMIT_BUILD_PROPERTY(
[COMPILER.CFLAGS], [$cs_cv_prog_cxx_code_gen], [+])])])
#------------------------------------------------------------------------------
# Check for SIMD flags. These checks are performed after CS_CHECK_HOST() and
# the CPU optimization flags detection since these may alter the build
# environment in a way which affects the SIMD flags tests. For instance,
# they might be impacted on Mac OS X by a universal binary build, or only the
# "-march" parameter chosen by the optimization flags detection may enable
# support for specific SIMD instructions.
#------------------------------------------------------------------------------
CS_CHECK_BUILD_FLAGS([for -mmmx flag], [cs_cv_prog_cc_mmmx],
[CS_CREATE_TUPLE([-mmmx])], [],
[CS_EMIT_BUILD_PROPERTY([COMPILER.CFLAGS.MMX], [$cs_cv_prog_cc_mmmx],
[append])], [], [$cs_cv_prog_cxx_code_gen])
CS_CHECK_BUILD_FLAGS([for -mfpmath=sse flag], [cs_cv_prog_cc_mfpmath_sse],
[CS_CREATE_TUPLE([-mfpmath=sse])], [],
[CS_EMIT_BUILD_PROPERTY([COMPILER.CFLAGS], [$cs_cv_prog_cc_mfpmath_sse],
[append])], [],
[$cs_cv_prog_cxx_code_gen $cs_cv_prog_cxx_enable_errors])
AS_IF([test -n "$cs_cv_prog_cc_mmmx"],
[CS_CHECK_BUILD([for mmintrin.h],
[cs_cv_header_mmintrin_h],
[AC_LANG_PROGRAM([[#include <mmintrin.h>]], [])],
[CS_CREATE_TUPLE([$cs_cv_prog_cc_mmmx])],
[C++],
[CS_HEADER_PROPERTY([CS_SUPPORTS_MMX])
CS_EMIT_BUILD_PROPERTY([CS_SUPPORTS_MMX], [yes])])])
#------------------------------------------------------------------------------
# Check for compiler optimization flags.
#------------------------------------------------------------------------------
AC_DEFUN([CS_CHECK_OPTIMIZE_FLAGS],
[AC_REQUIRE([AC_PROG_CC])
AC_REQUIRE([AC_PROG_CXX])
cs_optimize_flags=''
CS_EMIT_BUILD_FLAGS([how to enable optimizations],
[cs_cv_prog_cxx_optimize],
[CS_CREATE_TUPLE([-O3]) CS_CREATE_TUPLE([-O2]) CS_CREATE_TUPLE([-O])],
[C++], [COMPILER.CFLAGS.optimize], [+],
[cs_optimize_flags="$cs_optimize_flags $cs_cv_prog_cxx_optimize"])
CS_EMIT_BUILD_FLAGS([if -fomit-frame-pointer is accepted],
[cs_cv_prog_cxx_omit_frame_pointer],
[CS_CREATE_TUPLE([-fomit-frame-pointer])],
[C++], [COMPILER.CFLAGS.optimize], [+],
[cs_optimize_flags="$cs_optimize_flags \
$cs_cv_prog_cxx_omit_frame_pointer"])
CS_EMIT_BUILD_FLAGS([if -ffast-math is accepted],
[cs_cv_prog_cxx_fast_math],
[CS_CREATE_TUPLE([-ffast-math])], [C++],
[COMPILER.CFLAGS.optimize], [+],
[cs_optimize_flags="$cs_optimize_flags $cs_cv_prog_cxx_fast_math"])])
CS_CHECK_OPTIMIZE_FLAGS
#------------------------------------------------------------------------------
# Determine build mode; either "optimize", "debug", or "profile".
#------------------------------------------------------------------------------
AC_ARG_ENABLE([optimize], [AC_HELP_STRING([--enable-optimize],
[build with optimizations enabled (default YES);
same as --enable-mode=optimize])],
[test "$enableval" = "yes" && cs_build_mode=optimize])
AC_ARG_ENABLE([debug], [AC_HELP_STRING([--enable-debug],
[build with debugging information (default NO);
same as --enable-mode=debug])],
[test "$enableval" = "yes" && cs_build_mode=debug])
AC_ARG_ENABLE([profile], [AC_HELP_STRING([--enable-profile],
[build with profiling information (default NO);
same as --enable-mode=profile])],
[test "$enableval" = "yes" && cs_build_mode=profile])
AC_ARG_ENABLE([mode], [AC_HELP_STRING([--enable-mode=mode],
[set build mode; recognized modes are `optimize', `debug', `profile'
(default OPTIMIZE)])],
[case $enableval in
optimize|debug|profile) cs_build_mode=$enableval ;;
*) CS_MSG_ERROR([m4_text_wrap(
[unrecognized mode --enable-mode=$enableval;
use `optimize', `debug', or `profile'], [ ], [[]], [60])]) ;;
esac])
AC_MSG_CHECKING([build mode])
AS_VAR_SET_IF([cs_build_mode], [], [cs_build_mode=optimize])
AC_MSG_RESULT([$cs_build_mode])
CS_EMIT_BUILD_PROPERTY([MODE], [$cs_build_mode])
#------------------------------------------------------------------------------
# Check whether to enable LTO (link-time optimization).
#------------------------------------------------------------------------------
CS_CHECK_ENABLE_LTO
#------------------------------------------------------------------------------
# Check for compiler debug flags.
#------------------------------------------------------------------------------
CS_CHECK_BINUTILS_2_17
AC_MSG_CHECKING([whether to split debug information])
AC_ARG_ENABLE([separate-debug-info],
[AC_HELP_STRING([--enable-separate-debug-info],
[split debug information into separate files. (default YES if
binutils >= 2.17 and build mode not 'profile',
otherwise default NO)])])
AS_IF([test -z "$enable_separate_debug_info"],
[AS_IF([test "$cs_build_mode$" = "profile"],
[enable_separate_debug_info=no],
[AS_IF([test -z `uname | grep -i CYGWIN`],
[enable_separate_debug_info=$cs_cv_binutils_2_17],
[enable_separate_debug_info=$cs_cv_binutils_true_2_17])])])
AC_MSG_RESULT([$enable_separate_debug_info])
CS_EMIT_BUILD_PROPERTY([LINK.DEBUG.INFO.SEPARATE],
[$enable_separate_debug_info])
CS_EMIT_BUILD_FLAGS([how to enable debug mode debugging symbols],
[cs_cv_prog_cxx_debug_symbols_extra],
[CS_CREATE_TUPLE([-g3]) CS_CREATE_TUPLE([-g2]) CS_CREATE_TUPLE([-g])],
[C++], [COMPILER.CFLAGS.debug], [+],
[CS_EMIT_BUILD_PROPERTY([COMPILER.LFLAGS.debug],
[$cs_cv_prog_cxx_debug_symbols_extra], [+])])
AC_MSG_CHECKING([whether to enable debug information in optimize mode])
AC_ARG_ENABLE([optimize-mode-debug-info],
[AC_HELP_STRING([--enable-optimize-mode-debug-info],
[whether to enable debug information even in optimize builds.
(default YES if separate debug information is enabled,
otherwise default NO)])],
[enable_optimize_mode_debug_info=$enableval])
AS_IF([test -z "$enable_optimize_mode_debug_info"],
[enable_optimize_mode_debug_info=$enable_separate_debug_info])
AC_MSG_RESULT([$enable_optimize_mode_debug_info])
AS_IF([test "$enable_optimize_mode_debug_info" != "no"],
[CS_EMIT_BUILD_FLAGS([how to enable optimize mode debugging symbols],
[cs_cv_prog_cxx_debug_symbols_normal],
[CS_CREATE_TUPLE([-g2]) CS_CREATE_TUPLE([-g])],
[C++], [COMPILER.CFLAGS.optimize], [+],
[CS_EMIT_BUILD_PROPERTY([COMPILER.LFLAGS.optimize],
[$cs_cv_prog_cxx_debug_symbols_normal], [+])])])
#------------------------------------------------------------------------------
# Check if compiler complains about adding /usr/local/include to the header
# search path. If not, add it to the header search path since not all
# compilers search there by default. Some compiler, on the other hand,
# complain if it is already in the built-in search path, and we would like to
# avoid the complaint, if possible.
#
# Furthermore, add a -L entry to LDFLAGS for /usr/local/lib if present.
# Finally, add /usr/local/lib to LD_LIBRARY_PATH if present since not all
# platforms do so by default. This will allow some tests to succeed which would
# otherwise fail. An example is the sizeof(wchar_t) check on Solaris, which
# attempts to run a test program. Without augmenting LD_LIBRARY_PATH, the test
# program would fail to run, citing inability to locate libstdc++.so.
#------------------------------------------------------------------------------
AS_IF([test -d /usr/local/include],
[CS_CHECK_BUILD_FLAGS([if -I/usr/local/include is usable],
[cs_cv_prog_cpp_local_include],
[CS_CREATE_TUPLE([-I/usr/local/include])], [C++], [], [],
[$cs_cv_prog_cxx_enable_warnings $cs_cv_prog_cxx_enable_errors])],
[cs_cv_prog_cpp_local_include=''])
AS_IF([test -n "$cs_cv_prog_cpp_local_include"],
[CS_EMIT_BUILD_PROPERTY([COMPILER.CFLAGS],
[$cs_cv_prog_cpp_local_include], [+])
CPPFLAGS="$CPPFLAGS $cs_cv_prog_cpp_local_include"])
AS_IF([test -d /usr/local/lib],
[CS_EMIT_BUILD_PROPERTY([COMPILER.LFLAGS], [-L/usr/local/lib], [+])
LDFLAGS="$LDFLAGS -L/usr/local/lib"
LD_LIBRARY_PATH="$LD_LIBRARY_PATH$PATH_SEPARATOR/usr/local/lib"
export LD_LIBRARY_PATH])
#------------------------------------------------------------------------------
# Check if va_copy() or __va_copy() is available.
#------------------------------------------------------------------------------
# CS_CHECK_VA_COPY(FUNCTION)
AC_DEFUN([CS_CHECK_VA_COPY],
[CS_CHECK_BUILD([for $1], [cs_cv_func_$1],
[AC_LANG_PROGRAM(
[[#include <stdio.h>
#include <stdarg.h>]],
[va_list ap1; va_list ap2; $1(ap1,ap2)])],
[], [], [CS_HEADER_PROPERTY(AS_TR_CPP([CS_HAVE_$1]))], [], [],
[$cs_cv_prog_cxx_enable_pedantic])])
CS_CHECK_VA_COPY([va_copy])
CS_CHECK_VA_COPY([__va_copy])
#------------------------------------------------------------------------------
# Check for X-Windows and several extensions. This check can identify both
# new-style modular X.Org installations and old-style monolithic installations,
# such as XFree86.
#------------------------------------------------------------------------------
AC_DEFUN([CS_X_CHECK_PREPARE],
[AC_REQUIRE([AC_CANONICAL_HOST])
AC_REQUIRE([CS_CHECK_HOST])
# Explicitly disable X checking on Windows to avoid discovering XFree86 in
# case Cygwin is installed. Doing so allows us to avoid Mesa's OpenGL
# headers during the OpenGL check, and prefer Microsoft's OpenGL headers.
# The Mesa OpenGL headers cause link errors because they do not employ
# __stdcall.
case $host_os in
mingw*|cygwin*) with_x=no ;;
esac
# Explicitly disable X checking on MacOS/X in case the optional XFree86 is
# installed since we want to avoid an undesirable dependency upon XFree86
# in the CS executables and plugins. If the user is actually
# cross-building for Darwin on MacOS/X, then the --with-x option will
# override this test (by setting cs_host_macosx to "no").
AS_IF([test x$cs_host_macosx = xyes], [with_x=no])])
CS_X_CHECK_PREPARE
# Compatiblity: use --with-x param for individual X lib checks
AS_IF([test -z "$with_x11"], [with_x11=$with_x])
# Newer X.org versions ship with pkgconfig packages, which will be consulted
# by CS_CHECK_LIB_WITH().
CS_CHECK_LIB_WITH([x11],
[AC_LANG_PROGRAM(
[[#include <X11/Xlib.h>]],
[XOpenDisplay (0)])])
AS_IF([test $cs_cv_libx11 = yes],
[# Probably newer style modular X.org installation.
AS_IF([test -z "$with_xext"], [with_xext=$with_x])
CS_CHECK_LIB_WITH([xext],
[AC_LANG_PROGRAM(
[[#include <X11/Xlib.h>
#include <X11/extensions/XShm.h>]],
[XShmCreateImage(0, 0, 0, 0, 0, 0, 0, 0)])], [], [], [],
[$cs_cv_libx11_cflags],
[$cs_cv_libx11_lflags],
[$cs_cv_libx11_libs])
no_x=no
X_CFLAGS="$cs_cv_libxext_cflags $cs_cv_libx11_cflags"
X_LFLAGS="$cs_cv_libxext_lflags $cs_cv_libx11_lflags"
X_LIBS="$cs_cv_libxext_libs $cs_cv_libx11_libs"
],
[# Probably an older style monolithic X11 installation.
# Use old Autoconf built-in X11 detection.
AC_PATH_X
AC_PATH_XTRA
X_LFLAGS="$X_PRE_LIBS $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"])
CS_NOTABLE([x11], [rendering], [unix], [test "yes" != "$no_x"])
AS_IF([test "$no_x" != yes],
[# We must be especially careful to instruct CS_EMIT_BUILD_PROPERTY() to
# emit the following properties even if their values are empty. This is
# necessary because of the way that Jam performs "product-wise" variable
# expansion. For example, if X is "x" and Y is undefined, Jam will expand
# "$(X) $(Y)" to "", whereas every other tool in the world will expand it
# to "x ". Since the emitted X11.CFLAGS, X11.LFLAGS, XFREE86VM.CFLAGS, and
# XFREE86VM.LFLAGS properties reference the other variables by name, we
# must ensure that those other variables are defined (even if only with an
# empty string).
CS_EMIT_BUILD_PROPERTY([X11.AVAILABLE], [yes])
CS_EMIT_BUILD_PROPERTY([X11.CFLAGS], [$X_CFLAGS])
CS_EMIT_BUILD_PROPERTY([X11.LFLAGS], [$X_LIBS $X_LFLAGS])