-
Notifications
You must be signed in to change notification settings - Fork 13
/
Copy pathXMLGraph.m
1640 lines (1103 loc) · 28.7 KB
/
XMLGraph.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ::Package:: *)
(* Autogenerated Package *)
BeginPackage["XMLGraph`"];
(* ::Text:: *)
(*
XMLGraph is an object that is stored as XMLGraph[data] where data is an Association or other object that supports key access mechanisms that stores the core XMLGraph data.
Keys *must* include \[OpenCurlyDoubleQuote]Graph\[CloseCurlyDoubleQuote], \[OpenCurlyDoubleQuote]Data\[CloseCurlyDoubleQuote], \[OpenCurlyDoubleQuote]Version\[CloseCurlyDoubleQuote].
Data -- data for each node
Graph -- structural representation of the XML
Version -- version of the object API
Each node in Graph will have an entry in Data. Structural lookups happen on the Graph. Data lookups happen on the data.
*)
XMLGraph::usage=
"A Graph-based representation of XML data";
BeginPackage["`Package`"];
(* ::Subsubsection::Closed:: *)
(*Node Stuff*)
$NodeDefaults::usage="Defaults for created nodes";
Node::usage="Head for a node";
CreateNode::usage=
"Creates a node/set of nodes";
InsertNodes::usage=
"Adds nodes to the graph";
DeleteNodes::usage=
"Deletes nodes from the graph";
ModifyNodes::usage=
"Modifies a node or set of nodes on the graph";
RootNode::usage=
"Gets the XML root element";
NodeList::usage=
"Lists the nodes on the Graph";
NodeData::usage=
"Gets a set of nodes off the graph";
NodeAttributes::usage=
"Pulls node attributes off the graph";
SelectNodes::usage=
"Selects nodes by some criterion";
NodeChildren::usage="";
NodeParents::usage="";
(* ::Subsubsection::Closed:: *)
(*Object Stuff*)
ConstructXMLGraph::usage="";
XMLGraphQ::usage="Tests whether an XMLGraph structure is a valid XML graph";
MutableXMLGraph::usage="Creates a mutable XMLGraph";
MutableXMLGraphQ::usage="Tests whether a graph is mutable or not";
(* ::Subsubsection::Closed:: *)
(*Conversions*)
FromXMLAssociation::usage="";
ToXMLAssociation::usage="";
FromXMLObject::usage="";
ToXMLObject::usage="";
(* ::Subsubsection::Closed:: *)
(*Graph Operations*)
XMLSubgraph::usage="Extracts a subgraph starting from a head node";
FormattedXMLGraph::usage="Returns the Graph with nice formatting";
XMLGraphSort::usage="Sorts the XMLGraph by distance from the \"Root\" node";
XMLGraphBFS::usage="Applies BreadthFirstScan to the Graph";
XMLGraphDFS::usage="Applies DepthFirstScan to the Graph";
EndPackage[];
BeginPackage["`CSSSelectors`"];
ParseCSSSelector::usage="";
CSSSelector::usage="";
CSSCombinator::usage="";
CompileCSSSelector::usage="";
CSSSelect::usage="";
EndPackage[];
Begin["`Private`"];
(* ::Subsection:: *)
(*Object API*)
XMLGraph//Clear
(* ::Subsubsection::Closed:: *)
(*XMLGraphQ*)
(* ::Subsubsubsection::Closed:: *)
(*XMLGraphQ*)
XMLGraphQ[a:Except[_XMLGraph]]:=
Quiet[TrueQ@KeyExistsQ[a, "Version"]]&&
AllTrue[{"Graph", "Data"}, KeyExistsQ[a, #]&];
HoldPattern[XMLGraphQ[XMLGraph[a_]?(System`Private`HoldNotValidQ)]]:=
XMLGraphQ@a
XMLGraphQ[_XMLGraph?(System`Private`HoldValidQ)]:=
True;
XMLGraphQ[___]:=False
(* ::Subsubsubsection::Closed:: *)
(*MutableXMLGraphQ*)
HoldPattern[MutableXMLGraphQ[XMLGraph[a_]]]:=
MutableXMLGraphQ@a;
MutableXMLGraphQ[a:Except[_XMLGraph]]:=
TrueQ@a["Mutable"]
(* ::Subsubsection::Closed:: *)
(*Constructor*)
(* ::Subsubsubsection::Closed:: *)
(*XMLGraph*)
HoldPattern[XMLGraph[a_]?(System`Private`HoldNotValidQ)]:=
With[{res=ConstructXMLGraph[a]},
res/;XMLGraphQ[res]
];
(* ::Subsubsubsection::Closed:: *)
(*ConstructXMLGraph*)
$XMLGraphDefaults=
<|
"Version"->1,
"Graph"->VertexAdd[Graph[{}], "Root"],
"Data"-><||>
|>;
ConstructXMLGraph//Clear;
validateGraphData[a_]:=
Module[{g=a["Graph"], d=a["Data"]},
Replace[EdgeList[g, "Root"\[DirectedEdge]_],
el:{"Root"\[DirectedEdge]n_}:>
Set[a["Graph"],
EdgeAdd[EdgeDelete[g, el], "Root"\[UndirectedEdge]n]
]
];
If[Length@d>0&&!AssociationQ[d[[1, "Meta"]]],
a["Data"]=
MapAt[Association, d, {All, "Meta"}];
]
];
validateGraphData~SetAttributes~HoldFirst
ConstructXMLGraph[a_Association]:=
If[Length@a>0&&AssociationQ@a[[1]]&&
AllTrue[{"Type", "Meta", "Children"}, KeyExistsQ[a[[1]], #]&],
FromXMLAssociation@a,
Module[
{
assoc=
Join[
$XMLGraphDefaults,
KeyTake[a, {"Version", "Graph", "Data"}]
]
},
validateGraphData[assoc];
With[{d=assoc},
System`Private`HoldSetValid@XMLGraph[d]
]
]
];
ConstructXMLGraph[xml:_XMLElement|(XMLObject[_][_, _, _])|_String]:=
FromXMLObject[xml];
ConstructXMLGraph[e_]:=
With[{a=Association@e},
If[AssociationQ@a,
XMLGraph@a,
If[Quiet@Check[BooleanQ@KeyExistsQ[e, "Version"], False],
KeyValueMap[
If[!KeyExistsQ[e, #],
e[#]=#2
]&,
$XMLGraphDefaults
];
If[!XMLGraphQ[e],
$Failed,
validateGraphData[e];
System`Private`HoldSetValid@XMLGraph[e]
],
$Failed
]
]
]
(* ::Subsubsubsection::Closed:: *)
(*MutableXMLGraph*)
MutableXMLGraph[x_XMLGraph?XMLGraphQ]:=
If[MutableXMLGraphQ[x],
x,
Quiet@
Check[
Get["HashTableInterface`"],
Get["https://github.com/b3m2a1/mathematica-tools/raw/master/HashTableInterface.m"]
];
Module[{b=HashTableInterface`HashTable[x["Backend"]]},
b["Mutable"]=True;
XMLGraph[b]
]
]
(* ::Subsubsection::Closed:: *)
(*Accessor API*)
(* ::Subsubsubsection::Closed:: *)
(*Backend*)
HoldPattern@XMLGraph[a_]["Backend"]:=
a
(* ::Subsubsubsection::Closed:: *)
(*Graph*)
HoldPattern@XMLGraph[a_]["Graph"]:=
a["Graph"]
(* ::Subsubsubsection::Closed:: *)
(*Data*)
HoldPattern@XMLGraph[a_]["Data"]:=
a["Data"]
(* ::Subsubsection::Closed:: *)
(*Format*)
Format[x_XMLGraph?XMLGraphQ]:=
RawBoxes@
With[
{
g=Length@x["Nodes"]-1,
r=Replace[x["Root"], s:Except[None]:>x["Data"][s, "Type"]],
be=x["Backend"]
},
BoxForm`ArrangeSummaryBox[
XMLGraph,
Unevaluated[XMLGraph@@{be}],
None,
{
BoxForm`MakeSummaryItem[{"Root: ", r}, StandardForm],
BoxForm`MakeSummaryItem[{"Nodes: ", g}, StandardForm]
},
{},
StandardForm
]
]
(* ::Subsubsection::Closed:: *)
(*Methods/Attributes*)
(* ::Subsubsubsection::Closed:: *)
(*Bind*)
$$objData=<|
"Methods"-><||>,
"Attributes"-><||>
|>;
bindMethod/:(bindMethod[graph_, name_[pat___]]:=def_):=
(
$$objData["Methods", name]=True;
XMLGraph/:graph?XMLGraphQ[name[pat]]:=def;
XMLGraph/:graph?XMLGraphQ[name][pat]:=def;
)
bindAttribute/:(bindAttribute[graph_, name_]:=def_):=
(
$$objData["Attributes", name]=True;
XMLGraph/:graph?XMLGraphQ[name]:=def;
)
(* ::Subsubsubsection::Closed:: *)
(*Insert*)
bindMethod[x_XMLGraph, "Insert"[n_]]:=
InsertNodes[x, n]
(* ::Subsubsubsection::Closed:: *)
(*Delete*)
bindMethod[x_XMLGraph, "Delete"[n_]]:=
DeleteNodes[x, n]
(* ::Subsubsubsection::Closed:: *)
(*Modify*)
bindMethod[x_XMLGraph, "ModifyNodes"[n_]]:=
ModifyNodes[x, n]
(* ::Subsubsubsection::Closed:: *)
(*FormattedGraph*)
bindMethod[x_XMLGraph, "FormattedGraph"[o___]]:=
FormattedXMLGraph[x, o];
(* ::Subsubsubsection::Closed:: *)
(*Nodes*)
bindAttribute[x_XMLGraph, "Nodes"]:=
NodeList[x]
(* ::Subsubsubsection::Closed:: *)
(*Root*)
bindAttribute[x_XMLGraph, "Root"]:=
RootNode[x]
(* ::Subsubsubsection::Closed:: *)
(*Select*)
bindMethod[x_XMLGraph, "Select"[fn_, n___]]:=
SelectNodes[x, fn, n]
(* ::Subsubsubsection::Closed:: *)
(*Locate*)
bindMethod[x_XMLGraph, "Locate"[id_]]:=
Append[SelectNodes[x, "id"->id, 1], None][[1]]
(* ::Subsubsubsection::Closed:: *)
(*BFS*)
bindMethod[x_XMLGraph, "BFS"[arg__]]:=
XMLGraphBFS[x, arg]
(* ::Subsubsubsection::Closed:: *)
(*DFS*)
bindMethod[x_XMLGraph, "DFS"[arg__]]:=
XMLGraphDFS[x, arg]
(* ::Subsubsubsection::Closed:: *)
(*Data*)
bindMethod[x_XMLGraph, "Data"[n_:All, p_:All]]:=
NodeData[x, n, p];
(* ::Subsubsubsection::Closed:: *)
(*Type*)
bindMethod[x_XMLGraph, "Type"[n_:All]]:=
NodeData[x, n, "Type"]
(* ::Subsubsubsection::Closed:: *)
(*Meta*)
bindMethod[x_XMLGraph, "Meta"[n_:All]]:=
NodeData[x, n, "Meta"]
(* ::Subsubsubsection::Closed:: *)
(*Attribute*)
bindMethod[x_XMLGraph, "Attribute"[n_:All, attr_]]:=
NodeAttributes[x, n, attr]
(* ::Subsubsubsection::Closed:: *)
(*Parent*)
bindMethod[x_XMLGraph, "Parent"[n_:All, depth_:1]]:=
NodeParents[x, n, depth]
(* ::Subsubsubsection::Closed:: *)
(*FullParents*)
bindMethod[x_XMLGraph, "FullParents"[n_:All, depth_:1]]:=
NodeParents[x, n, depth, True]
(* ::Subsubsubsection::Closed:: *)
(*Children*)
bindMethod[x_XMLGraph, "Children"[n_:All, depth_:1]]:=
NodeChildren[x, n, depth]
(* ::Subsubsubsection::Closed:: *)
(*FullChildren*)
bindMethod[x_XMLGraph, "FullChildren"[n_:All, depth_:1]]:=
NodeChildren[x, n, depth, True]
(* ::Subsubsubsection::Closed:: *)
(*Sort*)
bindMethod[x_XMLGraph, "Sort"[]]:=
XMLGraphSort[x]
(* ::Subsubsubsection::Closed:: *)
(*Subgraph*)
bindMethod[x_XMLGraph, "Subgraph"[k_]]:=
XMLSubgraph[x, k]
(* ::Subsubsubsection::Closed:: *)
(*XML*)
bindAttribute[x_XMLGraph, "XML"]:=
ToXMLObject[x]
(* ::Subsubsubsection::Closed:: *)
(*Association*)
bindAttribute[x_XMLGraph, "Association"]:=
ToXMLAssociation[x]
(* ::Subsubsubsection::Closed:: *)
(*Fallthrough*)
x_XMLGraph?XMLGraphQ[h_[s_String?($$objData["Attributes", #]&)]]:=
With[{g=x[h]},
g[s]/;XMLGraphQ[g]
]
x_XMLGraph?XMLGraphQ[h_[s_String?($$objData["Methods", #]&)[a___]]]:=
With[{g=x[h]},
g[s[a]]/;XMLGraphQ[g]
]
(* ::Subsection:: *)
(*Node API*)
(* ::Subsubsection::Closed:: *)
(*$NodeDefaults*)
$NodeDefaults=
<|
"Type"->"p",
"Meta"-><||>,
"Children"->{}
|>
(* ::Subsubsection::Closed:: *)
(*ValidateNode*)
(* ::Text:: *)
(*...I should probably write this...*)
(* ::Subsubsection::Closed:: *)
(*Node*)
With[
{
baseBoxes=
RawBoxes@
BoxForm`ArrangeSummaryBox[
Node,
Node[$$name],
None,
{$$name},
{},
StandardForm
]/.DynamicModuleBox[_, b_, ___]:>
RuleCondition[b/.PaneSelectorBox[s_, ___]:>Lookup[s, False], True]
},
Format[Node[name_String]]:=
baseBoxes/.{
$$name->name,
TagBox["$$name", "SummaryItem"]:>
RuleCondition[TagBox[ToString[name, InputForm], "SummaryItem"], True]
}
]
(* ::Subsubsection::Closed:: *)
(*CreateNode*)
(* ::Text:: *)
(*
CreateNode takes a parent node and a list of child-specs and creates an Association for the children out of it.
Returns {{childData}, {nodeSpecs...}} where each nodeSpec is an Association and the childData is data about the children of the parent node.
*)
(* ::Subsubsubsection::Closed:: *)
(*CreateNode*)
CreateNode[d_]:=
Reap[createNode[d]];
(* ::Subsubsubsection::Closed:: *)
(*createNode*)
createNode[parent_->XMLObject[_][_, el_, ___]]:=
createNode[
parent->el
]
createNode[parent_->XMLElement[d_, c_, b_]]:=
createNode[
parent->
<|"Type"->d, "Meta"->c, "Children"->b|>
];
createNode[parent_->kid_Association]:=
Module[
{
data=<|"Parent"->parent|>,
children
},
data["Type"]=Lookup[kid, "Type", $NodeDefaults["Type"]];
data["Name"]=StringSplit[CreateUUID[data["Type"]<>":"], "-", 2][[1]];
data["Meta"]=Lookup[kid, "Meta", $NodeDefaults["Meta"]];
data["Children"]=
createNode[
data["Name"]->
Flatten@List@Lookup[kid, "Children", $NodeDefaults["Children"]]
];
Sow[data];
Node[data["Name"]]
]
createNode[parent_->kids:l_List]:=
createNode/@Thread[parent->kids];
createNode[parent_->kid_]:=
kid
(* ::Subsubsection::Closed:: *)
(*InsertNodes*)
InsertNodes[
x_XMLGraph?XMLGraphQ,
nodes:{__Rule}
]:=
Module[
{
a=XMLGraph["Backend"],
data,
parents=Keys@nodes,
pos,
nodez=Values@nodes,
children,
others,
edges,
new
},
(* If no position is specifed insert at the end *)
parents=
If[!ListQ@#, {#, -1}, #]&/@parents;
{parents, pos}=Transpose@parents;
(* Create new nodes from rules *)
nodez=Flatten[{#}, 1]&/@nodez;
nodez=CreateNode/@Thread[parents->nodez];
new=Join@@nodez[[All, 2]];
(* Add constructed edges to the Graph *)
edges=
Map[#["Parent"]->#["Name"]&, new];
a["Graph"]=
EdgeAdd[a["Graph"],
UndirectedEdge@@@edges
];
(* Add data to Data association *)
data=a["Data"];
MapThread[
Function[
data[#, "Children"]=
FlattenAt[
Insert[data[#, "Children"], #3, #2],
#2
];
data[#, "Children"]
],
{
parents,
pos,
nodez[[All, 1]]
}
];
Map[Function[data[#["Name"]]=#], new];
(* Return new XMLGraph and added nodes *)
{If[MutableXMLGraphQ@x, x, XMLGraph@a], edges[[All, 2]]}
]
(* ::Subsubsection::Closed:: *)
(*DeleteNodes*)
DeleteNodes[
x_XMLGraph,
n:{__String}
]:=
Module[
{
a=x["Backend"],
g,
d,
vs
},
g=a["Graph"];
g=VertexDelete[g, n];
a["Graph"]=g;
d=a["Data"];
vs=Lookup[d, n];
a["Data"]=KeyDrop[d, n];
{If[MutableXMLGraphQ@x, x, XMLGraph@a], vs}
]
(* ::Subsubsection::Closed:: *)
(*ModifyNodes*)
ModifyNodes[
x_XMLGraph,
n:{__Rule}
]:=
Module[
{
a=x["Backend"],
g,
d,
vs=Keys@n,
ms=Association/@Values[n]
},
d=a["Data"];
MapThread[
Function[
d[#, "Type"]=
Lookup[#2, "Type", d[#, "Type"]];
d[#, "Meta"]=
Merge[{d[#, "Meta"], KeyDrop[#2, "Type"]}, Last];
],
{
vs,
ms
}
];
a["Data"]=d;
If[MutableXMLGraphQ@x, x, XMLGraph@a]
]
(* ::Subsubsection::Closed:: *)
(*RootNode*)
RootNode[x_XMLGraph]:=
If[Length@#>0,
#[[1, 2]],
None
]&@IncidenceList[x["Graph"], "Root"]
(* ::Subsubsection::Closed:: *)
(*NodeList*)
NodeList[x_XMLGraph]:=
Keys@x["Data"]
(* ::Subsubsection::Closed:: *)
(*SelectNodes*)
SelectNodes//Clear
SelectNodes[x_XMLGraph, test_String, n_:All]:=
CSSSelect[x, test, n]
SelectNodes[x_XMLGraph, prop_String->test_]:=
Keys@Select[x["Data"][[All, "Meta", prop]], #==test&];
SelectNodes[x_XMLGraph, test:Except[_String|_String->_]]:=
Keys@Select[x["Data"], test];
SelectNodes[x_XMLGraph, prop_String->test_, n_]:=
Keys@Select[x["Data"][[All, "Meta", prop]], #==test&, n];
SelectNodes[x_XMLGraph, test:Except[_String|_String->_], n_]:=
Keys@Select[x["Data"], test, n];
(* ::Subsubsection::Closed:: *)
(*NodeData*)
NodeData[x_XMLGraph, n:_String|{__String}|All, part:(_String|{__String}|All):All]:=
x["Data"][[n, part]];
NodeData[x_XMLGraph, i:_Integer|{__Integer}|_Span, parts:_String|{__String}|All:All]:=
NodeData[x, VertexList[x["Graph"]][[i]]];
NodeData[x_XMLGraph, {}, part:(_String|{__String}|All):All]:=
{}
(* ::Subsubsection::Closed:: *)
(*NodeAttributes*)
NodeAttributes[x_XMLGraph,
n:_String|{__String}|All,
part:(_String|{__String}|All):All]:=
x["Data"][[n, "Meta", part]];
NodeAttributes[x_XMLGraph, i:_Integer|{__Integer}|_Span, parts:_String|{__String}|All:All]:=
NodeAttributes[x, VertexList[x["Graph"]][[i]]];
NodeAttributes[x_XMLGraph, {}, part:(_String|{__String}|All):All]:=
{}
(* ::Subsubsection::Closed:: *)
(*NodeChildren*)
NodeChildren[x_XMLGraph, n_, depth_:1, full:True|False:False]:=
If[full, Rest[NestList][##]&, Nest][
NodeData[x, Cases[#, Node[s_]:>s, {0, 1}], "Children"]&,
Thread[Node[n]],
depth
]
(* ::Subsubsection::Closed:: *)
(*NodeParents*)
NodeParents[x_XMLGraph, n_, depth_:1, full:True|False:False]:=
If[full, Rest[NestList][##]&, Nest][
NodeData[x, #, "Parent"]&,
n,
depth
]
(* ::Subsection:: *)
(*CSS Selectors*)
(* ::Text:: *)
(*
I may want a DFS selection procedure over the Graph representation? This would make things like ~ more intuitive and linear time, but might also be a bit more of a pain.
*)
(* ::Subsubsection::Closed:: *)
(*Parse*)
cssSelectorPatterns=
{
"\*"->CSSSelector[All],
"."~~cls:Except[WhitespaceCharacter]..:>
CSSSelector["Class"][cls],
"#"~~id:Except[WhitespaceCharacter]..:>
CSSSelector["ID"][id],
(Whitespace|"")~~","~~(Whitespace|"")->CSSCombinator["Or"],
(Whitespace|"")~~"+"~~(Whitespace|"")->CSSCombinator["Next"],
(Whitespace|"")~~"~"~~(Whitespace|"")->CSSCombinator["Follows"],
(Whitespace|"")~~">"~~(Whitespace|"")->CSSCombinator["Child"],
(el:(LetterCharacter~~Except[WhitespaceCharacter|","|"+"|"~"|">"]...))~~
("["~~attr:Except[WhitespaceCharacter|"]"]..~~"]"):>
CSSCombinator["And"][
CSSSelector["Element"][el],
cssAttributeSelector[attr]
],
"["~~attr:Except[WhitespaceCharacter|"]"]..~~"]":>
cssAttributeSelector[attr],
el:(LetterCharacter~~Except[WhitespaceCharacter|","|"+"|"~"|">"]...):>
CSSSelector["Element"][el]
}
cssAttributeSelector[s_String]:=
Module[
{
split,
attr,
token,
val
},
split=StringSplit[StringTrim[s], "=", 2];
If[Length@split==2,
{attr, val}=split;
token=StringTake[s, {-1}];
attr=StringDrop[s, -1];
CSSSelector["Attribute"][token, attr, val],
CSSSelector["Attribute"][split[[1]]]
]
]
cssSelectorPostProcess=
{
" "->CSSCombinator["Descendant"]
};
normalizeWhiteSpace[s_String]:=
StringReplace[s, Whitespace->" "]
ParseCSSSelector[s_String]:=
Module[
{
split,
map,
i=1,
tag
},
split=List@@StringReplace[normalizeWhiteSpace@s, cssSelectorPatterns];
map=<||>;
split=
Flatten[
Replace[
StringReplace[
If[!StringQ@#, tag=ToString[i++];map[tag]=#;tag, #]&/@split,
cssSelectorPostProcess
],
map,
1
],
1,
StringExpression
];
Replace[{