build.gradle

group 'io.github.vantiv'
version JAR_VERSION

apply plugin : 'eclipse'
apply plugin : 'java'
apply plugin : 'maven-publish'
apply plugin : 'jacoco'


repositories {
    maven { url 'http://repo1.maven.org/maven2' }
    jcenter { url 'http://jcenter.bintray.com/' }

}


configurations {
    generateJAXB.extendsFrom mainRuntime
}

jacocoTestReport {
    executionData(fileTree(dir:"${buildDir}/jacoco/", include:"*.exec"))
    reports {
        xml.enabled true
        html.enabled true
    }
}


sourceSets {
    main{
        java{
            srcDirs += "$buildDir/generated"
        }
    }
}


dependencies {
    implementation  group:'com.jcraft', name:'jsch', version:'0.1.54'
    implementation  group:'commons-io', name:'commons-io', version:'2.5'
    implementation  group:'org.apache.httpcomponents', name:'httpclient', version:'4.5.2'
    //implementation group: 'org.apache.httpcomponents.client5', name: 'httpclient5', version: '5.2.1'
    testImplementation  group: 'junit', name: 'junit', version: '4.12'
    implementation  group: 'org.jacoco', name: 'org.jacoco.agent', version: '0.8.1'
    generateJAXB group:'com.sun.xml.bind', name:'jaxb-core', version:'2.2.7'
    generateJAXB group:'com.sun.xml.bind', name:'jaxb-impl', version:'2.2.5-5'
    generateJAXB group:'com.sun.xml.bind', name:'jaxb-xjc', version:'2.2.5'
    testImplementation group: 'org.mockito', name: 'mockito-core', version: '4.11.0'
}


sourceCompatibility=1.7

clean {
    delete 'build'
}

jar{
    manifest {
        attributes("Implementation-Title":"Payfac Merchant Provisioner SDK For Java 1.5 and greater", "Implementation-Version":"${JAR_VERSION}","Implementation-Vendor":"worldpay","Main-Class":"com.cnp.sdk.Setup")
    }

    getDestinationDirectory().set(file("${buildDir}/lib"))

    getArchiveFileName().set("${JAR_NAME}-${JAR_VERSION}.jar")
}


javadoc{
    destinationDir = file("$buildDir/${RELEASE_ARTIFACTS_DIR}/doc")
}



task generateJaxbClasses() {
    compileJava.dependsOn it
    eclipseClasspath.dependsOn it

    ext.bindingsFile = "src/main/xsd/bindings.xml"
    ext.generatedDir = "${buildDir}/generated"

    inputs.file bindingsFile
    outputs.dir generatedDir

    doFirst {
        mkdir generatedDir
    }

    doLast {
        ant.taskdef(name: "xjc", classname:"com.sun.tools.xjc.XJCTask", classpath:configurations.generateJAXB.asPath)
        ant.xjc(destdir:"${generatedDir}", package: "io.github.vantiv.mp.sdk", binding:bindingsFile, extension:'true'){
            schema(dir:"src/main/xsd/", includes:"merchant-onboard-api-v${SCHEMA_VERSION}.xsd")
        }
    }
}


task sourceJar(type:Jar) {
    dependsOn generateJaxbClasses
    getDestinationDirectory().set(file("${buildDir}/libs"))
    getArchiveClassifier().set('sources')
    from "src/main/java"
    from generateJaxbClasses.generatedDir
}



task copyJarsToKit(type:Copy, dependsOn:[check,jar,sourceJar]){
    from "${buildDir}/libs/${JAR_NAME}-${JAR_VERSION}.jar"
    from "LICENSE"
    from "${buildDir}/libs/${JAR_NAME}-${JAR_VERSION}-sources.jar"
    from "${buildDir}/${JAR_NAME}-${JAR_VERSION}.pom"
    into "$buildDir/${RELEASE_ARTIFACTS_DIR}"
}

task copyLibsToKit(type:Copy, dependsOn:check){
    from configurations.runtimeClasspath.asFileTree.matching{
        include '**/commons-io*'
        include '**/commons-codec*'
        include '**/httpclient*'
        include '**/jsch*'
        include '**/*jacoco*'
    }

    into "$buildDir/${RELEASE_ARTIFACTS_DIR}/dependencies"
}

task tarKit(type:Tar, dependsOn:[copyJarsToKit, copyLibsToKit]){
    compression = Compression.GZIP
    getDestinationDirectory().set(file("$buildDir/${DIST_DIR}"))
    getArchiveFileName().set("${JAR_NAME}-${JAR_VERSION}.tar.gz")
    from "$buildDir/${RELEASE_ARTIFACTS_DIR}"
}

task zipKit(type:Zip, dependsOn:[copyJarsToKit, copyLibsToKit]){
    getDestinationDirectory().set(file("$buildDir/${DIST_DIR}"))
    getArchiveFileName().set("${JAR_NAME}-${JAR_VERSION}.zip")
    from "$buildDir/${RELEASE_ARTIFACTS_DIR}"
}

task kit(dependsOn:[tarKit, zipKit]){
    if (JavaVersion.current().isJava8Compatible()) {
        allprojects {
            tasks.withType(Javadoc) {
                options.addStringOption('Xdoclint:none', '-quiet')
            }
        }
    }
    dependsOn javadoc
}


publishing {
    publications {
        maven(MavenPublication) {
            from components.java
            pom {
                name = 'mp-sdk-for-java'
                description = 'Vantiv eCommerce Java SDK is a Java implementation of the Vantiv Payfac XML API'
                url = 'https://github.com/Vantiv/payfac-mp-sdk-java'
                groupId = 'io.github.vantiv'
                artifactId = "${JAR_NAME}"
                version = "${JAR_VERSION}"

                licenses {
                    license {
                        name = 'License'
                        url = 'https://github.com/Vantiv/payfac-mp-sdk-java/blob/14.x/LICENSE'
                    }
                }
                developers{
                    developer{
                        id = 'vantivSDKSupport'
                        name = 'VantivSDKSupport'
                        email = 'sdksupport@worldpay.com'
                    }
                }
                scm {
                    connection = 'scm:git:github.com/Vantiv/payfac-mp-sdk-for-java.git'
                    developerConnection = 'scm:git:ssh://github.com/Vantiv/payfac-mp-sdk-for-java.git'
                    url = 'https://github.com/Vantiv/payfac-mp-sdk-java.git'
                }
            }
        }
    }
}

tasks.register("copyPomToRoot") {
    def publication = publishing.publications.maven
    def generatePom = tasks.named("generatePomFileFor${publication.name.capitalize()}Publication")
    dependsOn(generatePom)
    def output = rootProject.file("${publication.artifactId}-${publication.version}.pom")
    outputs.file(output)
    doLast { output.bytes = generatePom.get().destination.bytes }
}