CMakeLists.txt

cmake_minimum_required(VERSION 3.12)
project(nova-renderer)

############################################################
# Fix build type because of possible capitalization issues #
############################################################
if(NOT NOVA_PACKAGE AND CMAKE_BUILD_TYPE)
    string(TOLOWER ${CMAKE_BUILD_TYPE} TMP_BUILD_TYPE)
    set(BUILD_TYPE_FIXED_BY_NOVA FALSE)
    if("${TMP_BUILD_TYPE}" STREQUAL "debug" AND NOT "${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
        set(ORIGINAL_BUILD_TYPE ${CMAKE_BUILD_TYPE})
        set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Specifies the build type on single-configuration generators. (Fixed to Debug from '${TMP_BUILD_TYPE}' by nova-renderer)" FORCE)
        set(BUILD_TYPE_FIXED_BY_NOVA TRUE)
        add_compile_definitions(TRACY_ENABLE)
    elseif(NOT "${CMAKE_BUILD_TYPE}" STREQUAL "Release" AND NOT "${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
        set(ORIGINAL_BUILD_TYPE ${CMAKE_BUILD_TYPE})
        set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Specifies the build type on single-configuration generators. (Fixed to Release from '${TMP_BUILD_TYPE}' by nova-renderer)" FORCE)
        set(BUILD_TYPE_FIXED_BY_NOVA TRUE)
    endif()

    if(BUILD_TYPE_FIXED_BY_NOVA)
        message(WARNING "CMAKE_BUILD_TYPE build type has been fixed to ${CMAKE_BUILD_TYPE} from ${ORIGINAL_BUILD_TYPE}")
    endif()
elseif(NOT CMAKE_BUILD_TYPE AND NOT MSVC)
    set(CMAKE_BUILD_TYPE "Release")
endif()

#############################
# Options for nova's builds #
#############################
option(NOVA_TEST "Enable tests." OFF)
option(NOVA_ENABLE_EXPERIMENTAL "Enable experimental features, may be in code as well as in the CMake files" OFF)
option(NOVA_TREAT_WARNINGS_AS_ERRORS "Add -Werror flag or /WX for MSVC" OFF)
option(NOVA_PACKAGE "Build only the library, nothing else." OFF)

option(NOVA_FORCE_DEBUGGING "Force compiling all the debugging and validation code" OFF)

if(NOVA_ENABLE_EXPERIMENTAL)
    set(CMAKE_LINK_WHAT_YOU_USE TRUE) # Warn about unsued linked libraries
endif()

#########################################################
# Enable tests if not in submodule and debug or if MSVC #
#########################################################
if(NOT NOVA_PACKAGE)
    message(STATUS "Enabling nova tests by default because Nova is not a package")
    set(NOVA_TEST ON)
endif()

############################
# Initialize cmake options #
############################
set(3RD_PARTY_DIR ${CMAKE_CURRENT_LIST_DIR}/external)
set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/tools/cmake" "${3RD_PARTY_DIR}")
set(CMAKE_CXX_STANDARD 20)
set(CMAKE_C_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS ON)
if(NOT NOVA_PACKAGE)
    set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
    set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
endif()

#################################
# Setup our own cmake additions #
#################################
include(ClangFormat)
include(ClangTidy)
include(RemovePermissive)
include(CompilerOptionsUtils)
include(CheckCXXCompilerFlag)
include(CheckIncludeFileCXX)

set(BUILD_TESTING OFF CACHE BOOL "NO TESTING" FORCE)

#################################
# Setup 3rd party dependencies. #
#################################
include(external)

########################
# Add Nova source code #
########################
set(NOVA_SOURCE
        external/tracy/TracyClient.cpp

        include/nova_renderer/util/platform.hpp
        include/nova_renderer/util/result.hpp
        include/nova_renderer/util/utils.hpp
        include/nova_renderer/util/container_accessor.hpp
        include/nova_renderer/util/bytes.hpp

        include/nova_renderer/nova_renderer.hpp
        include/nova_renderer/nova_settings.hpp
        include/nova_renderer/renderables.hpp
        include/nova_renderer/renderdoc_app.h
        include/nova_renderer/renderpack_data.hpp
        include/nova_renderer/window.hpp
        include/nova_renderer/constants.hpp
        include/nova_renderer/frame_context.hpp
        include/nova_renderer/renderpack_data_conversions.hpp

        include/nova_renderer/filesystem/filesystem_helpers.hpp
        include/nova_renderer/filesystem/folder_accessor.hpp
        include/nova_renderer/filesystem/virtual_filesystem.hpp

        include/nova_renderer/loading/renderpack_loading.hpp
        include/nova_renderer/loading/shader_includer.hpp

        include/nova_renderer/rhi/forward_decls.hpp
        include/nova_renderer/rhi/command_list.hpp
        include/nova_renderer/rhi/swapchain.hpp
        include/nova_renderer/rhi/rhi_enums.hpp
        include/nova_renderer/rhi/rhi_types.hpp
        include/nova_renderer/rhi/resource_binder.hpp
        include/nova_renderer/rhi/pipeline_create_info.hpp
        include/nova_renderer/rhi/render_device.hpp

        include/nova_renderer/procedural_mesh.hpp
        include/nova_renderer/rendergraph.hpp
        include/nova_renderer/ui_renderer.hpp
        include/nova_renderer/resource_loader.hpp
        include/nova_renderer/camera.hpp
        include/nova_renderer/per_frame_device_array.hpp
        include/nova_renderer/material.hpp

        src/nova_renderer.cpp

        src/rhi/rhi_types.cpp
        src/rhi/render_device.cpp
        src/rhi/swapchain.cpp

        src/rhi/vulkan/vulkan_command_list.cpp
        src/rhi/vulkan/vulkan_command_list.hpp
        src/rhi/vulkan/vulkan_render_device.cpp
        src/rhi/vulkan/vulkan_render_device.hpp
        src/rhi/vulkan/vk_structs.hpp
        src/rhi/vulkan/vulkan_utils.hpp
        src/rhi/vulkan/vulkan_utils.cpp
        src/rhi/vulkan/vulkan_swapchain.cpp
        src/rhi/vulkan/vulkan_swapchain.hpp
        src/rhi/vulkan/vulkan_resource_binder.hpp
        src/rhi/vulkan/vulkan_resource_binder.cpp

        src/settings/nova_settings.cpp
		
        src/render_objects/procedural_mesh.cpp
        src/render_objects/uniform_structs.hpp
        src/render_objects/renderables.cpp

        src/renderer/rendergraph.cpp
        src/renderer/ui/ui_renderer.cpp
        src/renderer/builtin/backbuffer_output_pass.hpp
        src/renderer/builtin/backbuffer_output_pass.cpp
        src/renderer/resource_loader.cpp
        src/renderer/camera.cpp
        src/renderer/visibility_cache.hpp
        src/renderer/visibility_cache.cpp
        src/renderer/material_data_buffer.cpp
        src/renderer/material_data_buffer.hpp
        src/renderer/material.cpp
        src/renderer/pipeline_reflection.hpp
        src/renderer/pipeline_reflection.cpp

        src/util/utils.cpp
        src/util/result.cpp
        src/util/bytes.cpp

        src/loading/json_utils.hpp
        src/loading/renderpack/renderpack_loading.cpp
        src/loading/renderpack/shader_includer.cpp
        src/loading/renderpack/renderpack_data.cpp
        src/loading/renderpack/renderpack_validator.cpp
        src/loading/renderpack/renderpack_validator.hpp
        src/loading/renderpack/render_graph_builder.cpp
        src/loading/renderpack/render_graph_builder.hpp
        src/loading/renderpack/renderpack_data_conversions.cpp

        src/debugging/renderdoc.cpp
        src/debugging/renderdoc.hpp

        src/logging/console_log_stream.hpp
        src/logging/console_log_stream.cpp
        
        src/windowing/window.cpp

        src/render/backend/vulkan_render_backend.hpp
        src/render/backend/vulkan_render_backend.cpp
        )
        
####################
# Add Nova headers #
####################
set(NOVA_HEADERS
        include/nova_renderer/util/platform.hpp
        include/nova_renderer/nova_renderer.hpp
        include/nova_renderer/renderpack_data.hpp
        include/nova_renderer/nova_settings.hpp
        include/nova_renderer/rhi/render_device.hpp
        include/nova_renderer/window.hpp
        include/nova_renderer/util/utils.hpp
        include/nova_renderer/renderables.hpp
        include/nova_renderer/renderdoc_app.h
        include/nova_renderer/util/result.hpp
        )

##################################
# Select platform dependent code #
##################################
set(WINDOWS_NOVA_SOURCE
        include/nova_renderer/util/windows.hpp
        src/util/windows_utils.cpp
        src/util/windows_utils.hpp
        )

if(WIN32)
    set(NOVA_SOURCE ${NOVA_SOURCE} ${WINDOWS_NOVA_SOURCE})
else()
   message(ERROR "Only Windows is supported")
endif()

##########################################
# Set platform dependent compile options #
##########################################
if(MSVC)
    add_definitions(/D_CRT_SECURE_NO_WARNINGS=1)
endif()

if(NOVA_TREAT_WARNINGS_AS_ERRORS)
    if(MSVC)
        add_compile_options(/WX)
    else()
        # TODO: Consider removing the -Wno-error's when we are in a more complete state
        add_compile_options(-Werror -Wno-error=unused-variable -Wno-error=unused-but-set-variable
                -Wno-error=unused-parameter)
    endif()
endif()

##########################################
# Setup required options for backtracing #
##########################################
if(CMAKE_BUILD_TYPE MATCHES DEBUG)
    add_compile_options_if_supported(-g -rdynamic)
    message(STATUS "Enabling symbol output")
endif()

#################
# Organize code #
#################
# For now just put everthing in a single nova source group
# because there are several sub groups that would be extremely small
source_group("nova" FILES ${NOVA_NO_COMPILE} ${3RD_PARTY_SOURCE} ${NOVA_SOURCE} ${NOVA_HEADERS})

##########################
# Setup the nova library #
##########################
add_library(nova-renderer STATIC
        ${NOVA_HEADERS}
        ${NOVA_SOURCE}
        ${3RD_PARTY_SOURCE}
        )
nova_format(nova-renderer "${OTHER_NOVA_SOURCE}")
set_target_properties(nova-renderer PROPERTIES POSITION_INDEPENDENT_CODE TRUE)
target_compile_definitions(nova-renderer PUBLIC DUMP_NOVA_CALLS)
target_include_directories(nova-renderer PRIVATE ${CMAKE_CURRENT_LIST_DIR}/include)

if(NOVA_FORCE_DEBUGGING) 
    target_compile_definitions(nova-renderer PUBLIC NOVA_DEBUG)
else()
    target_compile_definitions(nova-renderer PUBLIC $<$<CONFIG:Debug>:NOVA_DEBUG>)
endif()

if(NOVA_DEBUG) 
    target_compile_definitions(nova-renderer PUBLIC RX_DEBUG)
endif()

target_link_directories(nova-renderer PUBLIC $ENV{VULKAN_SDK}/Lib)

target_include_directories(nova-renderer PRIVATE ${STB_INCLUDE_DIRS})
target_include_directories(nova-renderer PRIVATE ${Vulkan_INCLUDE_DIR})

#########################
# Set libraries to link #
#########################
set(COMMON_LINK_LIBS
        ${CMAKE_DL_LIBS}
        glfw
        glm
        nlohmann_json 
        nlohmann_json::nlohmann_json
        spdlog::spdlog 
        spdlog::spdlog_header_only
        vk-bootstrap
        vma::vma)
        
set(COMMON_LINK_LIBS ${COMMON_LINK_LIBS} vulkan-1)

############################
# Platform dependent fixes #
############################
find_package(WindowsSDK)
get_windowssdk_include_dirs(${WINDOWSSDK_LATEST_DIR} WinSDK_DIRS)

# MSVC 15.9 broke the Windows SDK by implementing two phase lookup. "/Zc:twoPhase-" disables it.
add_compile_options_if_supported(/Zc:twoPhase- /permissive /bigobj )

set_target_properties(nova-renderer PROPERTIES PREFIX "")
target_include_directories(nova-renderer PRIVATE ${WinSDK_DIRS})
target_compile_definitions(nova-renderer PUBLIC _SILENCE_CXX17_ITERATOR_BASE_CLASS_DEPRECATION_WARNING NOMINMAX)
target_compile_definitions(nova-renderer PRIVATE NOVA_EXPORT)

# Visual Studio is stupid. Is it really that hard to use filesystem directories to organize code like literally
# everyone else?
foreach(source IN LISTS NOVA_SOURCE)
    get_filename_component(source_path "${source}" PATH)
    string(REPLACE "/" "\\" source_path_msvc "${source_path}")
    source_group("${source_path_msvc}" FILES "${source}")
endforeach()

###############################
# Link all required libraries #
###############################
target_link_libraries(nova-renderer PUBLIC ${COMMON_LINK_LIBS})