forked from nez-peg/nez-grammar
-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathjava8.nez
863 lines (791 loc) · 40.5 KB
/
java8.nez
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
/**
* Java8 Grammar
*
* Based on grammar from Java8 langauge specification
*
* [1] https://docs.oracle.com/javase/specs/jls/se8/html/jls-2.html#jls-2.4
*
* Authors:
* Kimio Kuramitsu (https://github.com/kkuramitsu/)
* Kohei Moriya
*/
File = _ { $(PackageDeclaration)? $(ImportDeclaration)* $(TypeDeclaration)* #Source } _ EOT
/* Code Layout (Whitespace) */
_ = ( S / BLOCKCOMMENT / LINECOMMENT )*
__ = !S
S = [ \n\r\t\u000B\u000C]
BLOCKCOMMENT = '/*' ( !'*/' . )* '*/'
LINECOMMENT = '//' ( !'\n' . )*
EOL = '\r'? '\n'
/ !.
EOT = !.
/* Operators */
"++" = '++' _
"--" = '--' _
"&" = '&' ![&=] _
"*" = '*' !'=' _
"+" = '+' ![+=] _
"-" = '-' !( '-' / [=>] ) _
"~" = '~' _
"!" = '!' !'=' _
"{" = '{' _
"[" = '[' _
"]" = ']' _
"," = ',' _
"..." = '...' _
":" = ':' ![>:] _
"::" = '::' _
"/" = '/' !'=' _
"%" = '%' ![=>] _
"<<" = '<<' !'=' _
">>" = '>>' ![=>] _
">>>" = '>>>' !'=' _
"<=" = '<=' _
">=" = '>=' _
"<" = '<' ![=] _
">" = '>' ![=] _
"==" = '==' _
"!=" = '!=' _
"^" = '^' ![=] _
"|" = '|' ![|=] _
"&&" = '&&' _
"||" = '||' _
"?" = '?' _
";" = ';' _
"}" = '}' _
"*=" = '*=' _
"/=" = '/=' _
"%=" = '%=' _
"+=" = '+=' _
"-=" = '-=' _
"<<=" = '<<=' _
">>=" = '>>=' _
">>>=" = '>>>=' _
"&=" = '&=' _
"^=" = '^=' _
"|=" = '|=' _
"=" = '=' !'=' _
"." = '.' !'.' _
"(" = '(' _
")" = ')' _
"@" = '@' _
"->" = '->' _
// reserved keyword
"abstract" = 'abstract' !W _
"assert" = 'assert' !W _
"boolean" = 'boolean' !W _
"break" = 'break' !W _
"byte" = 'byte' !W _
"case" = 'case' !W _
"catch" = 'catch' !W _
"char" = 'char' !W _
"class" = 'class' !W _
"const" = 'const' !W _
"continue" = 'continue' !W _
"default" = 'default' !W _
"do" = 'do' !W _
"double" = 'double' !W _
"else" = 'else' !W _
"enum" = 'enum' !W _
"extends" = 'extends' !W _
"false" = 'false' !W _
"final" = 'final' !W _
"finally" = 'finally' !W _
"float" = 'float' !W _
"for" = 'for' !W _
"goto" = 'goto' !W _
"if" = 'if' !W _
"implements" = 'implements' !W _
"import" = 'import' !W _
"instanceof" = 'instanceof' !W _
"int" = 'int' !W _
"interface" = 'interface' !W _
"long" = 'long' !W _
"native" = 'native' !W _
"new" = 'new' !W _
"null" = 'null' !W _
"package" = 'package' !W _
"private" = 'private' !W _
"protected" = 'protected' !W _
"public" = 'public' !W _
"return" = 'return' !W _
"short" = 'short' !W _
"static" = 'static' !W _
"strictfp" = 'strictfp' !W _
"super" = 'super' !W _
"switch" = 'switch' !W _
"synchronized" = 'synchronized' !W _
"this" = 'this' !W _
"throw" = 'throw' !W _
"throws" = 'throws' !W _
"transient" = 'transient' !W _
"true" = 'true' !W _
"try" = 'try' !W _
"void" = 'void' !W _
"volatile" = 'volatile' !W _
"while" = 'while' !W _
KEYWORD = "abstract"
/ "assert"
/ "boolean"
/ "break"
/ "byte"
/ "case"
/ "catch"
/ "char"
/ "class"
/ "const"
/ "continue"
/ "default"
/ "double"
/ "do"
/ "else"
/ "enum"
/ "extends"
/ "false"
/ "final"
/ "finally"
/ "float"
/ "for"
/ "goto"
/ "if"
/ "implements"
/ "import"
/ "instanceof"
/ "interface"
/ "int"
/ "long"
/ "native"
/ "new"
/ "null"
/ "package"
/ "private"
/ "protected"
/ "public"
/ "return"
/ "short"
/ "static"
/ "strictfp"
/ "super"
/ "switch"
/ "synchronized"
/ "this"
/ "throws"
/ "throw"
/ "transient"
/ "true"
/ "try"
/ "void"
/ "volatile"
/ "while"
/* Annotation */
Annotations = { $(Annotation)+ #Modifiers }
Annotation = "@" { $(QualifiedName) "(" $(ElementValuePairList)? ")" #Annotation }
/ "@" { $(QualifiedName) "(" $(ElementValue) ")" #Annotation }
/ "@" { $(QualifiedName) #Annotation }
ElementValuePairList = { $(ElementValuePair) ( "," $(ElementValuePair) )* #CommaList }
ElementValuePair = { $(Identifier) "=" $(ElementValue) #KeyValue }
ElementValue = ElementValueArrayInitializer
/ ConditionalExpression
/ Annotation
ElementValueArrayInitializer = "{" { addElementValueList? #List } ","? "}"
addElementValueList = $(ElementValue) ( "," $(ElementValue) )*
/* Declaration */
// package
PackageDeclaration = { $(Annotations)? "package" $(QualifiedName) #JavaPackageDeclaration } ";"
// import
ImportDeclaration = { "import" ("static" #JavaStaticImport / #Import) $name(PackageName) } ";"
PackageName = QualifiedName {$ "." "*" #WildCardName }?
// type
TypeDeclaration = ClassDeclaration
/ InterfaceDeclaration
/ ";" { #Empty }
// class, enum
ClassDeclaration = { $anno(ClassModifiers)? "class" $name(Identifier) $_(TypeParameters)? $super(SuperClass)? $impl(SuperInterfaces)? $body(ClassBody) #ClassDecl }
/ { $anno(ClassModifiers)? "enum" $name(Identifier) $impl(SuperInterfaces)? $body(EnumBody) #EnumDecl }
ClassModifiers = { $(ClassModifier)+ #Modifiers }
ClassModifier = Annotation
/ "public" { #Public }
/ "protected" { #Protected }
/ "private" { #Private }
/ "abstract" { #Abstract }
/ "final" { #Final }
/ "static" { #Static }
/ "strictfp" { #Strictfp }
SuperClass = "extends" ClassOrInterfaceType
SuperInterfaces = "implements" ClassOrInterfaceTypes
ClassBody = "{" { $(ClassBodyDeclaration)* #Block } "}"
ClassBodyDeclaration = ClassMemberDeclaration
/ { $(Block) #JavaInstanceInisializer }
/ "static" { $(Block) #JavaStaticInitializer }
/ ConstructorDeclaration
ClassMemberDeclaration = FieldDeclaration
/ MethodDeclaration
/ ClassDeclaration
/ InterfaceDeclaration
/ ";" { #Empty }
EnumBody = "{" { addEnumeratorList? ","? ";" $({ $(ClassBodyDeclaration)+ #JavaEnumMemberList }) #List } "}"
/ "{" { addEnumeratorList? ","? ";"? #List } "}"
addEnumeratorList = $(Enumerator) ( "," $(Enumerator) )*
Enumerator = { $anno(Annotations)? $name(Identifier) $(ArgumentExpressionList) $(ClassBody)? #JavaEnumerator }
/ { $anno(Annotations)? $name(Identifier) $(ClassBody) #JavaEnumerator }
/ { $anno(Annotations)? $name(Identifier) #Enumerator }
// interface, annotation
InterfaceDeclaration = { $anno(InterfaceModifiers)? "interface" $name(Identifier) $_(TypeParameters)? $super(ExtendsInterfaces)? $body(InterfaceBody) #InterfaceDecl }
/ { $(InterfaceModifiers)? "@" "interface" $(Identifier) $(AnnotationTypeBody) #JavaAnnotationTypeDecl }
InterfaceModifiers = { $(InterfaceModifier)+ #Modifiers }
InterfaceModifier = Annotation
/ "public" { #Public }
/ "protected" { #Protected }
/ "private" { #Private }
/ "abstract" { #Abstract }
/ "static" { #Static }
/ "strictfp" { #Strictfp }
ExtendsInterfaces = "extends" ClassOrInterfaceTypes
InterfaceBody = "{" { $(InterfaceMemberDeclaration)* #Block } "}"
InterfaceMemberDeclaration = ConstantDeclaration
/ InterfaceMethodDeclaration
/ ClassDeclaration
/ InterfaceDeclaration
/ ";" { #Empty }
AnnotationTypeBody = "{" { $(AnnotationTypeMemberDeclaration)* #Block } "}"
AnnotationTypeMemberDeclaration = AnnotationTypeElementDeclaration
/ ConstantDeclaration
/ ClassDeclaration
/ InterfaceDeclaration
/ ";" { #Empty }
AnnotationTypeElementDeclaration = { $(AnnotationTypeElementModifiers)? $(Type) $(Identifier) "(" ")" $(AnnotationTypeElementDefaultValue)? ";" #JavaAnnotationTypeElement }
AnnotationTypeElementModifiers = { $(AnnotationTypeElementModifier)+ #Modifiers }
AnnotationTypeElementModifier = Annotation
/ "public" { #Public }
/ "abstract" { #Abstract }
AnnotationTypeElementDefaultValue = "default" ElementValue
// local variable
VariableDeclaration = { $anno(VariableModifiers)? $type(Type) addVariableDeclarations }
VariableModifiers = { $(VariableModifier)+ #Modifiers }
VariableModifier = Annotation
/ "final" { #Final }
addVariableDeclarations = $name(VarName) ( "=" $expr(Initializer) )? !',' #VarDecl
/ $list(InitDeclList) #MultiVarDecl
InitDecl = { $name(VarName) ( "=" $expr(Initializer) )? #VarDecl }
InitDeclList = { $(InitDecl) ( "," $(InitDecl) )* #List }
VarName = Identifier {$name "[" $param(ConstantExpression)? "]" #ArrayName }*
Initializer = Expression
/ ArrayInitializer
ArrayInitializer = { "{" ( $(Initializer) ( "," $(Initializer) )* )? ","? "}" #Array }
//field
FieldDeclaration = { $anno(FieldModifiers)? $type(Type) $list(InitDeclList) #FieldDecl } ";"
FieldModifiers = { $(FieldModifier)+ #Modifiers }
FieldModifier = Annotation
/ "public" { #Public }
/ "protected" { #Protected }
/ "private" { #Private }
/ "final" { #Final }
/ "static" { #Static }
/ "transient" { #Transient }
/ "volatile" { #Volatile }
//constant
ConstantDeclaration = { $anno(ConstantModifiers)? $type(Type) $list(InitDeclList) #JavaInterfaceConstantDecl } ";"
ConstantModifiers = { $(ConstantModifier)+ #Modifiers }
ConstantModifier = Annotation
/ "public" { #Public }
/ "final" { #Final }
/ "static" { #Static }
//method
MethodDeclaration = { $anno(MethodModifiers)? ( $(TypeParameters) $anno(Annotations)? )? $type(TypeOrVoid) $name(Identifier) "(" $param(MethodParamList) ")" $throws(Throws)? ($body(Block) / ";") #MethodDecl }
MethodModifiers = { $(MethodModifier)+ #Modifiers }
MethodModifier = Annotation
/ "public" { #Public }
/ "protected" { #Protected }
/ "private" { #Private }
/ "abstract" { #Abstract }
/ "final" { #Final }
/ "static" { #Static }
/ "synchronized" { #Synchronized }
/ "native" { #Native }
/ "strictfp" { #Strictfp }
InterfaceMethodDeclaration = { $anno(InterfaceMethodModifiers)? ( $(TypeParameters) $anno(Annotations)? )? $type(TypeOrVoid) $name(Identifier) "(" $param(MethodParamList) ")" $throws(Throws)? ($body(Block) / ";") #MethodDecl }
InterfaceMethodModifier = Annotation
/ "public" { #Public }
/ "abstract" { #Abstract }
/ "default" { #Default }
/ "static" { #Static }
/ "strictfp" { #Strictfp }
InterfaceMethodModifiers = { $(InterfaceMethodModifier)+ #Modifiers }
MethodParamList = { ( $(MethodParam) "," )* $(VarParam) #List }
/ { ( $(MethodParam) ( "," $(MethodParam) )* )? #List }
MethodParam = { $anno(VariableModifiers)? $type(Type) $name(VarName) #Param }
VarParam = { $anno(VariableModifiers)? $(Type) "..." $(VarName) #VarParam }
Throws = "throws" { $(ClassOrInterfaceTypes) #Throws }
//constructor
ConstructorDeclaration = { $anno(ConstructorModifiers)? $type(ReferenceType) "(" $param(MethodParamList) ")" $throws(Throws)? $body(ConstructorBody) #Constructor }
ConstructorModifiers = { $(ConstructorModifier)+ #Modifiers }
ConstructorModifier = Annotation
/ "public" { #Public }
/ "protected" { #Protected }
/ "private" { #Private }
ConstructorBody = "{" { $(ExplicitConstructorInvocation)? $(BlockStatement)* #Block } "}"
ExplicitConstructorInvocation = { $(TypeArguments)? $({ $(This) "(" addArgumentExpressionList? ")" #List }) #ExplicitConstructorInvocation } ";"
/ { $(TypeArguments)? $({ $(Super) "(" addArgumentExpressionList? ")" #List }) #ExplicitConstructorInvocation } ";"
/ { $(PostfixExpression) "." $(TypeArguments)? $(Super) $({ "(" addArgumentExpressionList? ")" #List }) #ExplicitConstructorInvocation } ";"
/* Types, Values, Variables */
Type = ReferenceType
/ PrimitiveType
PrimitiveType = { $anno(Annotations) $(UnannoPrimitiveType) #Annotated }
/ UnannoPrimitiveType
UnannoPrimitiveType = NumericType
/ BooleanType
NumericType = IntegralType
/ FloatingPointType
IntegralType = { "byte" #Name }
/ { "char" #Name }
/ { "short" #Name }
/ { "int" #Name }
/ { "long" #Name }
FloatingPointType = { "float" #Name }
/ { "double" #Name }
BooleanType = { "boolean" #Name }
ReferenceType = ArrayType
/ ClassOrInterfaceType
/ TypeVariable
ArrayType = (PrimitiveType / ClassOrInterfaceType / TypeVariable) {$base $(Annotations)? "[" "]" #ArrayType }+
ClassOrInterfaceType = ClassType
/ InterfaceType
ClassType = SimpleClassType {$prefix "." $name(SimpleClassType) #JavaQualifiedNamedType }*
SimpleClassType = { $anno(Annotations) $(UnannoSimpleClassType) #Annotated }
/ UnannoSimpleClassType
UnannoSimpleClassType = Identifier {$base $param(TypeArguments) #GenericType }?
InterfaceType = ClassType
TypeVariable = { $anno(Annotations) $(Identifier) #Annotated }
/ Identifier
TypeParameter = { $anno(Annotations) $(UnannoTypeParameter) #Annotated }
/ UnannoTypeParameter
UnannoTypeParameter = Identifier {$base "extends" $extends(ClassOrInterfaceType) ( "&" $(InterfaceType) )* #TypeBound }?
TypeParameters = { "<" $(TypeParameter) ( "," $(TypeParameter) )* ">" #TypeLists }
TypeArgument = ReferenceType
/ { $(Annotations)? "?" #TWildCard } {$ ("extends" #UpperBound / "super" #LowerBound) $(ReferenceType) }?
TypeArguments = { "<" ( $(TypeArgument) ( "," $(TypeArgument) )* )? ">" #TypeArguments }
Void = { "void" #VoidType }
TypeOrVoid = Type
/ Void
NonArrayType = ClassOrInterfaceType
/ PrimitiveType
ClassOrInterfaceTypes = { $(ClassOrInterfaceType) ( "," $(ClassOrInterfaceType) )* #List }
// Block, Statement
//===================
Block = "{" { $(BlockStatement)* #Block } "}"
BlockStatement = Statement
/ VariableDeclaration ";"
/ ClassDeclaration
Statement = Block
/ { "assert" $cond(Expression) ( ":" $msg(Expression) )? #Assert } ";"
/ { "if" "(" $cond(Expression) ")" $then(Statement) ( "else" $else(Statement) )? #If }
/ SwitchStatement
/ { "while" "(" $cond(Expression) ")" $body(Statement) #While }
/ { "do" $body(Statement) "while" "(" $cond(Expression) ")" #DoWhile } ";"
/ { "for" "(" $init(Expressions)? ";" $cond(Expression)? ";" $iter(Expressions)? ")" $body(Statement) #For }
/ { "for" "(" $init(VariableDeclaration) ";" $cond(Expression)? ";" $iter(Expressions)? ")" $body(Statement) #For }
/ { "for" "(" $anno(VariableModifiers)? $type(Type) $name(Identifier) ":" $iter(Expression) ")" $body(Statement) #ForEach }
/ { "continue" $label(Identifier)? `` #Continue } ";"
/ { "break" $label(Identifier)? `` #Break } ";"
/ { "return" $expr(Expression)? #Return } ";"
/ TryStatement
/ { "throw" $expr(Expression) #Throw } ";"
/ { "synchronized" "(" $cond(Expression) ")" $body(Block) #Synchronized }
/ { $label(Identifier) ":" #Label }
/ Expression ";"
/ ";" { #Empty }
// try-catch-finally
TryStatement = { "try" $(ResourceList) $try(Block) $catch({ $(Catch)* #List }) ( "finally" $finally(Block) )? #JavaTryWithResource }
/ { "try" $try(Block) $catch({ $(Catch)* #List }) "finally" $finally(Block) #Try }
/ { "try" $try(Block) $catch({ $(Catch)+ #List }) #Try }
ResourceList = "(" { $(Resource) ( ";" $(Resource) )* #JavaResourceList } ";"? ")"
Resource = { $anno(VariableModifiers)? $type(Type) $name(Identifier) "=" $expr(Expression) #VarDecl }
Catch = { "catch" "(" addCatchParameter ")" $body(Block) #Catch }
addCatchParameter = $anno(VariableModifiers)? $type(ClassOrInterfaceType) $name(Identifier)
/ $anno(VariableModifiers)? $type({ $(ClassOrInterfaceType) ( "|" $(ClassOrInterfaceType) )+ #JavaMultiExceptions }) $name(Identifier)
// switch
SwitchStatement = { "switch" "(" $cond(Expression) ")" $body(SwitchBlock) #Switch }
SwitchBlock = "{" { $(SwitchCondition)+ #Block } "}"
SwitchCondition = { "case" $cond(ConstantExpression) ":" $body(CaseBlock) #SwitchCase }
/ { "default" ":" $body(CaseBlock) #SwitchDefault }
CaseBlock = { $(BlockStatement)* #Block }
/* Expression */
Expression = LambdaExpression
/ AssignmentExpression
Expressions = { $(Expression) ( "," $(Expression) )* #List }
AssignmentExpression = { $left(UnaryExpression) addAssignmentOperator $right(Expression) }
/ ConditionalExpression
addAssignmentOperator = "=" #Assign
/ "*=" #AssignMul
/ "/=" #AssignDiv
/ "%=" #AssignMod
/ "+=" #AssignAdd
/ "-=" #AssignSub
/ "<<=" #AssignLeftShift
/ ">>=" #AssignRightShift
/ ">>>=" #AssignLogicalRightShift
/ "&=" #AssignBitwiseAnd
/ "^=" #AssignBitwiseXOr
/ "|=" #AssignBitwiseOr
ConstantExpression = ConditionalExpression
ConditionalExpression = LogicalOrExpression {$cond "?" $then(Expression) ":" $else(LogicalOrExpression) #Conditional }*
LogicalOrExpression = LogicalAndExpression {$left "||" $right(LogicalAndExpression) #Or }*
LogicalAndExpression = InclusiveOrExpression {$left "&&" $right(InclusiveOrExpression) #And }*
InclusiveOrExpression = ExclusiveOrExpression {$left "|" $right(ExclusiveOrExpression) #BitwiseOr }*
ExclusiveOrExpression = AndExpression {$left "^" $right(AndExpression) #BitwiseXor }*
AndExpression = EqualityExpression {$left "&" $right(EqualityExpression) #BitwiseAnd }*
EqualityExpression = RelationalExpression {$left ("==" #Equals / "!=" #NotEquals) $right(RelationalExpression) }*
RelationalExpression = ShiftExpression {$left addRelationalOperator }*
addRelationalOperator = "<=" $right(ShiftExpression) #LessThanEquals
/ ">=" $right(ShiftExpression) #GreaterThanEquals
/ "<" $right(ShiftExpression) #LessThan
/ ">" $right(ShiftExpression) #GreaterThan
/ "instanceof" $right(ReferenceType) #InstanceOf
ShiftExpression = AdditiveExpression {$left ("<<" #LeftShift / ">>" #RightShift / ">>>" #LogicalRightShift) $right(AdditiveExpression) }*
AdditiveExpression = MultiplicativeExpression {$left ("+" #Add / "-" #Sub) $right(MultiplicativeExpression) }*
MultiplicativeExpression = CastNewExpression {$left ("*" #Mul / "/" #Div / "%" #Mod) $right(CastNewExpression) }*
CastNewExpression = { "(" $type(Type) ")" $expr(CastNewExpression) #Cast }
/ UnaryExpression
UnaryExpression = PostfixExpression
/ { "++" $expr(UnaryExpression) #PreInc }
/ { "--" $expr(UnaryExpression) #PreDec }
/ { "+" $expr(CastNewExpression) #Plus }
/ { "-" $expr(CastNewExpression) #Minus }
/ { "~" $expr(CastNewExpression) #Compl }
/ { "!" $expr(CastNewExpression) #Not }
PostfixExpression = PrimaryExpression {$recv addMethodCall / addInstanceCreation / addIndex / addField / addMethodReference / addInc / addDec }*
addMethodCall = "." $(TypeArguments)? $name(Identifier) $param(ArgumentExpressionList) #MethodApply
addInstanceCreation = "." "new" $(TypeArguments)? $(Annotations)? $(ClassOrInterfaceType) $(ArgumentExpressionList) $(ClassBody)? #JavaInstanceCreation
ArgumentExpressionList = { "(" addArgumentExpressionList? ")" #List }
addArgumentExpressionList = $(Expression) ( "," $(Expression) )*
addIndex = "[" $param({ $(Expression) #List }) "]" #Indexer
addField = "." $name(Identifier) !'(' #Field
addMethodReference = "::" $(TypeArguments)? $(Identifier) #JavaMethodReference
addInc = "++" #Inc
addDec = "--" #Dec
PrimaryExpression = Constant
/ This
/ Super
/ "(" Expression ")"
/ ClassLiteral
/ { $(QualifiedName) "." "this" #JavaThis }
/ { $(QualifiedName) "." "super" #JavaSuper }
/ MethodInvocationExpression
/ InstanceCreationExpression
/ ArrayCreationExpression
/ MethodReference
/ Identifier
ClassLiteral = { $(TypeOrVoid) "." "class" #JavaClassLiteral }
This = "this" { #This }
Super = "super" { #Super }
MethodInvocationExpression = { $name(Identifier) $param(ArgumentExpressionList) #Apply }
InstanceCreationExpression = { "new" $({ $(TypeArguments) #JavaTypeArgs })? $(Annotations)? $type(ClassOrInterfaceType) $param(ArgumentExpressionList) $body(ClassBody)? #New }
ArrayCreationExpression = { "new" $(Annotations)? $type(NonArrayType {$base $(Annotations)? "[" $size(Expression) "]" #ArrayType }+ {$base $(Annotations)? "[" "]" #ArrayType }*) #NewArray }
/ { "new" $(Annotations)? $type(NonArrayType {$base $(Annotations)? "[" "]" #ArrayType }+) $(ArrayInitializer) #NewArray }
MethodReference = { $(ReferenceType) "::" $(TypeArguments)? $(Identifier / { "new" #Name }) #JavaMethodReference }
LambdaExpression = { $param(LambdaParameters) "->" $body(LambdaBody) #Lambda }
LambdaParameters = Identifier
/ "(" MethodParamList ")"
/ "(" InferredParamList ")"
InferredParamList = { $(Identifier) ( "," $(Identifier) )* #List }
LambdaBody = !'{' { $({ $expr(Expression) #Return }) #Block }
/ Block
/* Identifier */
Identifier = { NAME #Name } _
QualifiedName = Identifier {$ "." $(Identifier) #QualifiedName }*
W = [a-zA-Z0-9_$]
NAME = !DIGIT !KEYWORD W+
/* Literal, Constant */
Literal = FloatingPointLiteral
/ IntegerLiteral
/ BooleanLiteral
/ CharacterLiteral
/ StringLiteral
/ NullLiteral
Constant = Literal
NullLiteral = "null" { #Null }
BooleanLiteral = "true" { #True }
/ "false" { #False }
IntegerLiteral = { (DECIMAL / HEXADECIMAL / BINARY / OCTAL) (INT_SUFFIX #Long / #Integer) } _
DIGIT = [0-9]
DIGITS = DIGIT ( '_'* DIGIT )*
DECIMAL = '0' ![bBxX0-9_]
/ !'0' DIGITS
HEXDIGIT = [a-fA-F0-9]
HEXDIGITS = HEXDIGIT ( '_'* HEXDIGIT )*
HEXADECIMAL = '0' [xX] HEXDIGITS
BINARYDIGIT = [01]
BINARYDIGITS = BINARYDIGIT ( '_'* BINARYDIGIT )*
BINARY = '0' [bB] BINARYDIGITS
OCTALDIGIT = [0-7]
OCTAL = '0' ( '_'* OCTALDIGIT )*
INT_SUFFIX = [lL]
FloatingPointLiteral = { FLOAT (FLOAT_SUFFIX #Float / DOUBLE_SUFFIX? #Double) } _
/ { DIGITS (FLOAT_SUFFIX #Float / DOUBLE_SUFFIX #Double) } _
FLOAT_SUFFIX = [fF]
DOUBLE_SUFFIX = [dD]
FLOAT = FRACTION EXPONENT?
/ DIGITS EXPONENT
/ HEXFRACTION BINARYEXPONENT
EXPONENT = [eE] [+\-]? DIGITS
BINARYEXPONENT = [pP] [+\-]? DIGITS
FRACTION = '.' DIGITS
/ DIGITS '.' DIGITS?
HEXFRACTION = '0' [xX] '.' HEXDIGITS
/ HEXADECIMAL ( '.' HEXDIGITS? )?
StringLiteral = '"' { STRING_CONTENT* #String } '"' _
CharacterLiteral = '\'' { CHAR_CONTENT #Character } '\'' _
STRING_CONTENT = ESCAPE
/ ![\"\n\\] .
CHAR_CONTENT = ESCAPE
/ !['\n\\] .
ESCAPE = SIMPLE_ESCAPE
/ OCTAL_ESCAPE
/ HEX_ESCAPE
SIMPLE_ESCAPE = '\\' ['\"\\bfnrt]
OCTAL_ESCAPE = '\\' [0-3] OCTALDIGIT OCTALDIGIT
/ '\\' OCTALDIGIT OCTALDIGIT
/ '\\' OCTALDIGIT
HEX_ESCAPE = '\\' 'u'+ HEXDIGIT HEXDIGIT HEXDIGIT HEXDIGIT
/* Example */
// The traditional "Hello, world!" program can be written in Java
example TypeDeclaration&File '''
class HelloWorldApp {
public static void main(String[] args) {
System.out.println("Hello World!"); // Prints the string to the console.
}
}
'''
// Generics
example File '''
package java.util.List;
public interface List<E> {
void add(E x);
Iterator<E> iterator();
}
'''
// Annotation
example File '''
@Entity // Declares this an entity bean
@Table(name = "people") // Maps the bean to SQL table "people"
public class Person implements Serializable {
@Id // Map this to the primary key column.
@GeneratedValue(strategy = GenerationType.AUTO) // Database will generate new primary keys, not us.
private Integer id;
@Column(length = 32) // Truncate column values to 32 characters.
private String name;
}
'''
// Generic Method
example MethodDeclaration '''
public void doSomething(List<? extends MyClass> list) {
for(MyClass object : list) { // OK
// do something
}
}
'''
// Generic Method
example MethodDeclaration '''
public static <Type> Entry<Type, Type> twice(Type value) {
return new Entry<Type, Type>(value, value);
}
'''
// Generics in throws clause
example MethodDeclaration '''
public <T extends Throwable> void throwMeConditional(boolean conditional, T exception) throws T {
if(conditional) {
throw exception;
}
}
'''
/* Variable Declraration */
example VariableDeclaration '''
int a = 1
'''
example VariableDeclaration '''
int a = 1, b
'''
example VariableDeclaration '''
int[] anArray = {
1, 2,
3, 4
}
'''
example VariableDeclaration '''
String[][] names = {
{"Mr. ", "Mrs. ", "Ms. "},
{"Smith", "Jones"}
}
'''
/* Statement */
example Statement '''
if(c);
'''
example Statement '''
if(c) {
}
'''
/* Expression (standard) */
example Expression ~7d9419 '''
1+2*3
'''
example Expression ~bfe331 '''
1*2+3
'''
example Expression ~162311 '''
(1+2)*3
'''
example Expression ~cd4f5d '''
1+2-3*4%5
'''
example Expression '''
x = x + 1
'''
example Expression '''
x = x | 1
'''
example Expression '''
x = x & 1
'''
/* Expression (local) */
example Expression '''
() -> {
System.out.println("example");
}
'''
/* Identifier (standard) */
example Expression ~a47e9fd '''
x
'''
example Expression ~fdb051 '''
Apple
'''
/* Literal (standard) */
example Literal ~1e4f2d '''
true
'''
example Literal ~4eab66 '''
false
'''
example Literal ~ec2775 '''
'C'
'''
example Literal ~1951c6 '''
0
'''
example Literal ~aef181 '''
26
'''
example Literal ~c3b9d6 '''
0x1a
'''
example Literal ~146f59 '''
0b11010
'''
example Literal ~f74a78 '''
123.4
'''
example Literal ~94b99c '''
1.234e2
'''
example Literal ~c83c217 '''
123.4f
'''
example Literal ~02bf7f6 '''
"hello,world\n"
'''
/* Literal (standard) */
example Literal ~db9f5e3 '''
"S\u00ED Se\u00F1or"
'''
format #JavaPackageDeclaration[*] `package $[0];`
format #Import[*] `import $[0];`
format #JavaStaticImport[*] `import static $[0];`
format #WildCardName[*] `$[0].*`
format #Modifiers[*] `$[0 ` ` -1] `
format #Annotation[*] `@$[0]($[1])`
format #Annotation[*] `@$[0]`
format #CommaList[*] `$[0 `, ` -1]`
format #KeyValue[*] `$[0] = $[1]`
format #Final[*] `final`
format #VarDecl[*] `$[0]`
format #VarDecl[*] `$[0] = $[1]`
format #ArrayName[*] `$[0][]`
format #ArrayName[*] `$[0][$[1]]`
format #Array[*] `{$[0 `, ` -1]}`
format #Annotated[*] `$[0] $[1]`
format #VoidType[*] `void`
format #Tbyte[*] `byte`
format #Tshort[*] `short`
format #Tint[*] `int`
format #Tlong[*] `long`
format #Tfloat[*] `float`
format #Tdouble[*] `double`
format #Tarray[*] `$[0][]`
format #Tarray[*] `$[0] $[1] []`
format #TypeBound[*] `$[0] extends $[1] $[2 ` & ` -1]`
format #TypeArguments[*] `<$[0 `,` -1]>`
format #Comma[*] `$[0], $[1]`
format #Assign[*] `$[0] = $[1]`
format #AssignMul[*] `$[0] *= $[1]`
format #AssignDiv[*] `$[0] /= $[1]`
format #AssignMod[*] `$[0] %= $[1]`
format #AssignAdd[*] `$[0] += $[1]`
format #AssignSub[*] `$[0] -= $[1]`
format #AssignLeftShift[*] `$[0] <<= $[1]`
format #AssignRightShift[*] `$[0] >>= $[1]`
format #AssignLogicalRightShift[*] `$[0] >>>= $[1]`
format #AssignBitwiseAnd[*] `$[0] &= $[1]`
format #AssignBitwiseXOr[*] `$[0] ^= $[1]`
format #AssignBitwiseOr[*] `$[0] != $[1]`
format #Conditional[*] `$[0] ? $[1] : $[2]`
format #LogicalAnd[*] `$[0] && $[1]`
format #LogicalOr[*] `$[0] || $[1]`
format #BitwiseOr[*] `($[0] | $[1])`
format #BitwiseXor[*] `($[0] ^ $[1])`
format #BitwiseAnd[*] `($[0] & $[1])`
format #Equals[*] `$[0] == $[1]`
format #NotEquals[*] `$[0] != $[1]`
format #LessThanEquals[*] `$[0] <= $[1]`
format #LessThan[*] `$[0] < $[1]`
format #GreaterThanEquals[*] `$[0] >= $[1]`
format #GreaterThan[*] `$[0] > $[1]`
format #InstanceOf[*] `$[0] instanceof $[1]`
format #HashIn[*] `$[0] in $[1]`
format #LeftShift[*] `($[0] << $[1])`
format #RightShift[*] `($[0] >> $[1])`
format #LogicalRightShift[*] `($[0] >>> $[1])`
format #Add[*] `($[0] + $[1])`
format #Sub[*] `($[0] - $[1])`
format #Mul[*] `($[0] * $[1])`
format #Div[*] `($[0] / $[1])`
format #Mod[*] `($[0] % $[1])`
format #PreInc[*] `++$[0]`
format #PreDec[*] `--$[0]`
format #Plus[*] `+$[0]`
format #Minus[*] `-$[0]`
format #BitwiseNot[*] `~$[0]`
format #LogicalNot[*] `!$[0]`
format #SuffixInc[*] `$[0]++`
format #SuffixDec[*] `$[0]--`
format #This[*] `this`
format #Array[*] `[$[0 `,` -1]]`
format #Object[*] `{$[0 `,` -1]}`
format #Property[*] `$[0]: $[1]`
format #Field[*] `$[0].$[1]`
format #Indexer[*] `$[0][$[1]]`
format #List[*] `($[0 `, ` -1])`
format #Name[*] `${text}`
format #QualifiedName[*] `$[0].$[1]`
format #Null[*] `null`
format #True[*] `true`
format #False[*] `false`
format #Integer[*] `${text}`
format #Long[*] `${text}`
//format #OctalInteger[0] `${text}`
//format #HexInteger[0] `${text}`
format #Float[*] `${text}`
format #Double[*] `${text}`
format #String[*] `"${text}"`
format #Character[*] `'${text}'`
//format #RegExp[0] `${text}`