forked from pik33/ultibo-retro-sid
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathunit6502.pas
executable file
·1354 lines (1061 loc) · 31.3 KB
/
unit6502.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
unit Unit6502;
{$mode objfpc}{$H+}
{$MACRO ON}
interface
uses Classes, SysUtils;
//var ram:array[-2..65537] of byte;
var instructions:integer=0; //keep track of total instructions executed
clockticks6502:integer=0;
clockgoal6502:integer=0;
jsrcnt:integer=0;
function read6502(address:integer):byte;
procedure write6502(address:integer; value:byte);
procedure reset6502;
procedure nmi6502;
procedure irq6502;
procedure exec6502(tickcount:integer);
procedure fast6502(tickcount:integer);
procedure step6502;
procedure jsr6502(aa:word; addr:integer);
implementation
uses retromalina;
// **********************************************************
// * 65032 CPU emulator core *
// * Pascal code by pik33 (pik33@o2.pl) *
// * based on Fake6502 C code *
// **********************************************************
// * Original Fake6502 LICENSE: *
// * (c)2011 Mike Chambers (miker00lz@gmail.com) *
// * This source code is released into the *
// * public domain, but if you use it please do give *
// * credit. I put a lot of effort into writing this! *
// **********************************************************
procedure imp; forward;
procedure indx; forward;
procedure zp; forward;
procedure imm; forward;
procedure acc; forward;
procedure abso; forward;
procedure rel; forward;
procedure indy; forward;
procedure absy; forward;
procedure absx; forward;
procedure ind; forward;
procedure zpx; forward;
procedure zpy; forward;
//65c02
procedure izp; forward; //ok
procedure iax; forward; //ok
procedure brk; forward;
procedure ora; forward;
procedure nop; forward;
procedure ana; forward;
procedure slo; forward;
procedure asl; forward;
procedure bpl; forward;
procedure php; forward;
procedure clc; forward;
procedure jsr; forward;
procedure rla; forward;
procedure bit; forward;
procedure rol; forward;
procedure bmi; forward;
procedure plp; forward;
procedure sec; forward;
procedure rti; forward;
procedure eor; forward;
procedure sre; forward;
procedure lsr; forward;
procedure pha; forward;
procedure bvc; forward;
procedure cli; forward;
procedure jmp; forward;
procedure rts; forward;
procedure adc; forward;
procedure bvs; forward;
procedure rra; forward;
procedure ror; forward;
procedure pla; forward;
procedure sei; forward;
procedure sta; forward;
procedure sax; forward;
procedure stx; forward;
procedure sty; forward;
procedure dey; forward;
procedure txa; forward;
procedure bcc; forward;
procedure tya; forward;
procedure txs; forward;
procedure ldy; forward;
procedure lda; forward;
procedure ldx; forward;
procedure lax; forward;
procedure tay; forward;
procedure tax; forward;
procedure bcs; forward;
procedure clv; forward;
procedure tsx; forward;
procedure cpy; forward;
procedure cmp; forward;
procedure dcp; forward;
procedure dea; forward;
procedure iny; forward;
procedure dex; forward;
procedure bne; forward;
procedure cld; forward;
procedure cpx; forward;
procedure isb; forward;
procedure inx; forward;
procedure beq; forward;
procedure sbc; forward;
procedure ina; forward;
procedure sed; forward;
// 65c02
procedure bra; forward; //ok
procedure phx; forward; //ok
procedure phy; forward; //ok
procedure plx; forward; //ok
procedure ply; forward; //ok
procedure stz; forward; //ok
procedure trb; forward; //ok
procedure tsb; forward; //ok
//65032
procedure ldc; forward;
procedure stc; forward;
procedure ldd; forward;
procedure std; forward;
procedure phc; forward; //ok
procedure phd; forward; //ok
procedure pld; forward; //ok
procedure plc; forward; //ok
type
Taddr=procedure;
TOpcode=procedure;
var addrtable:array[0..255] of TAddr=(
// | 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 | A | B | C | D | E | F |
{ 0 } @imp, @indx, @abso, @indx, @zp, @zp, @zp, @zp, @imp, @imm, @acc, @imm, @abso, @abso, @abso, @abso, { 0 }
{ 1 } @rel, @indy, @izp, @indy, @zp, @zpx, @zpx, @zpx, @imp, @absy, @acc, @absy, @abso, @absx, @absx, @absx, { 1 }
{ 2 } @abso, @indx, @abso, @indx, @zp, @zp, @zp, @zp, @imp, @imm, @acc, @imm, @abso, @abso, @abso, @abso, { 2 }
{ 3 } @rel, @indy, @izp, @indy, @zpx, @zpx, @zpx, @zpx, @imp, @absy, @acc, @absy, @absx, @absx, @absx, @absx, { 3 }
{ 4 } @imp, @indx, @abso, @indx, @imp, @zp, @zp, @zp, @imp, @imm, @acc, @imm, @abso, @abso, @abso, @abso, { 4 }
{ 5 } @rel, @indy, @izp, @indy, @zpx, @zpx, @zpx, @zpx, @imp, @absy, @imp, @absy, @absx, @absx, @absx, @absx, { 5 }
{ 6 } @imp, @indx, @abso, @indx, @zp, @zp, @zp, @zp, @imp, @imm, @acc, @imm, @ind, @abso, @abso, @abso, { 6 }
{ 7 } @rel, @indy, @izp, @indy, @zpx, @zpx, @zpx, @zpx, @imp, @absy, @imp, @absy, @iax, @absx, @absx, @absx, { 7 }
{ 8 } @imm, @indx, @imp, @indx, @zp, @zp, @zp, @zp, @imp, @imm, @imp, @imm, @abso, @abso, @abso, @abso, { 8 }
{ 9 } @rel, @indy, @izp, @indy, @zpx, @zpx, @zpy, @zpy, @imp, @absy, @imp, @absy, @abso, @absx, @absx, @absy, { 9 }
{ A } @imm, @indx, @imm, @indx, @zp, @zp, @zp, @zp, @imp, @imm, @imp, @imm, @abso, @abso, @abso, @abso, { A }
{ B } @rel, @indy, @izp, @indy, @zpx, @zpx, @zpy, @zpy, @imp, @absy, @imp, @absy, @absx, @absx, @absy, @absy, { B }
{ C } @imm, @indx, @imp, @indx, @zp, @zp, @zp, @zp, @imp, @imm, @imp, @imm, @abso, @abso, @abso, @abso, { C }
{ D } @rel, @indy, @izp, @indy, @zpx, @zpx, @zpx, @zpx, @imp, @absy, @imp, @absy, @absx, @absx, @absx, @absx, { D }
{ E } @imm, @indx, @imp, @indx, @zp, @zp, @zp, @zp, @imp, @imm, @imp, @imm, @abso, @abso, @abso, @abso, { E }
{ F } @rel, @indy, @izp, @indy, @zpx, @zpx, @zpx, @zpx, @imp, @absy, @imp, @absy, @absx, @absx, @absx, @absx { F }
);
var optable:array[0..255] of TOpcode=(
// | 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 | A | B | C | D | E | F |
{ 0 } @brk, @ora, @ldc, @slo, @tsb, @ora, @asl, @slo, @php, @ora, @asl, @nop, @tsb, @ora, @asl, @slo, { 0 }
{ 1 } @bpl, @ora, @ora, @slo, @trb, @ora, @asl, @slo, @clc, @ora, @ina, @slo, @trb, @ora, @asl, @slo, { 1 }
{ 2 } @jsr, @ana, @ldd, @rla, @bit, @ana, @rol, @rla, @plp, @ana, @rol, @nop, @bit, @ana, @rol, @rla, { 2 }
{ 3 } @bmi, @ana, @ana, @rla, @bit, @ana, @rol, @rla, @sec, @ana, @dea, @rla, @bit, @ana, @rol, @rla, { 3 }
{ 4 } @rti, @eor, @stc, @sre, @pld, @eor, @lsr, @sre, @pha, @eor, @lsr, @nop, @jmp, @eor, @lsr, @sre, { 4 }
{ 5 } @bvc, @eor, @eor, @sre, @nop, @eor, @lsr, @sre, @cli, @eor, @phy, @sre, @nop, @eor, @lsr, @sre, { 5 }
{ 6 } @rts, @adc, @std, @rra, @stz, @adc, @ror, @rra, @pla, @adc, @ror, @nop, @jmp, @adc, @ror, @rra, { 6 }
{ 7 } @bvs, @adc, @adc, @rra, @stz, @adc, @ror, @rra, @sei, @adc, @ply, @rra, @jmp, @adc, @ror, @rra, { 7 }
{ 8 } @bra, @sta, @plc, @sax, @sty, @sta, @stx, @sax, @dey, @bit, @txa, @nop, @sty, @sta, @stx, @sax, { 8 }
{ 9 } @bcc, @sta, @sta, @nop, @sty, @sta, @stx, @sax, @tya, @sta, @txs, @nop, @stz, @sta, @stz, @nop, { 9 }
{ A } @ldy, @lda, @ldx, @lax, @ldy, @lda, @ldx, @lax, @tay, @lda, @tax, @nop, @ldy, @lda, @ldx, @lax, { A }
{ B } @bcs, @lda, @lda, @lax, @ldy, @lda, @ldx, @lax, @clv, @lda, @tsx, @lax, @ldy, @lda, @ldx, @lax, { B }
{ C } @cpy, @cmp, @phc, @dcp, @cpy, @cmp, @dea, @dcp, @iny, @cmp, @dex, @nop, @cpy, @cmp, @dea, @dcp, { C }
{ D } @bne, @cmp, @cmp, @dcp, @nop, @cmp, @dea, @dcp, @cld, @cmp, @phx, @dcp, @nop, @cmp, @dea, @dcp, { D }
{ E } @cpx, @sbc, @phd, @isb, @cpx, @sbc, @ina, @isb, @inx, @sbc, @nop, @sbc, @cpx, @sbc, @ina, @isb, { E }
{ F } @beq, @sbc, @sbc, @isb, @nop, @sbc, @ina, @isb, @sed, @sbc, @plx, @isb, @nop, @sbc, @ina, @isb { F }
);
var ticktable:array[0..255] of byte = (
{ | 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 | A | B | C | D | E | F | }
{ 0 } 7, 6, 7, 8, 5, 3, 5, 5, 3, 2, 2, 2, 6, 4, 6, 6, { 0 }
{ 1 } 2, 5, 5, 8, 5, 4, 6, 6, 2, 4, 2, 7, 6, 4, 7, 7, { 1 }
{ 2 } 6, 6, 7, 8, 3, 3, 5, 5, 4, 2, 2, 2, 4, 4, 6, 6, { 2 }
{ 3 } 2, 5, 5, 8, 4, 4, 6, 6, 2, 4, 2, 7, 4, 4, 7, 7, { 3 }
{ 4 } 6, 6, 7, 8, 7, 3, 5, 5, 3, 2, 2, 2, 3, 4, 6, 6, { 4 }
{ 5 } 2, 5, 5, 8, 4, 4, 6, 6, 2, 4, 3, 7, 4, 4, 7, 7, { 5 }
{ 6 } 6, 6, 7, 8, 3, 3, 5, 5, 4, 2, 2, 2, 5, 4, 6, 6, { 6 }
{ 7 } 2, 5, 5, 8, 4, 4, 6, 6, 2, 4, 4, 7, 6, 4, 7, 7, { 7 }
{ 8 } 3, 6, 7, 6, 3, 3, 3, 3, 2, 2, 2, 2, 4, 4, 4, 4, { 8 }
{ 9 } 2, 6, 5, 6, 4, 4, 4, 4, 2, 5, 2, 5, 4, 5, 5, 5, { 9 }
{ A } 2, 6, 2, 6, 3, 3, 3, 3, 2, 2, 2, 2, 4, 4, 4, 4, { A }
{ B } 2, 5, 5, 5, 4, 4, 4, 4, 2, 4, 2, 4, 4, 4, 4, 4, { B }
{ C } 2, 6, 6, 8, 3, 3, 5, 5, 2, 2, 2, 2, 4, 4, 6, 6, { C }
{ D } 2, 5, 5, 8, 4, 4, 6, 6, 2, 4, 3, 7, 4, 4, 7, 7, { D }
{ E } 2, 6, 6, 8, 3, 3, 5, 5, 2, 2, 2, 2, 4, 4, 6, 6, { E }
{ F } 2, 5, 5, 8, 4, 4, 6, 6, 2, 4, 4, 7, 4, 4, 7, 7 { F }
);
{$define FLAG_CARRY:=$01}
{$define FLAG_ZERO:=$02}
{$define FLAG_INTERRUPT:=$04}
{$define FLAG_DECIMAL:=$08}
{$define FLAG_BREAK:=$10}
{$define FLAG_CONSTANT:=$20}
{$define FLAG_OVERFLOW:=$40}
{$define FLAG_SIGN:=$80}
{$define BASE_STACK:=$100}
//flag modifier macros
{$define setcarry:= status :=status or FLAG_CARRY}
{$define clearcarry:= status := status and not(FLAG_CARRY)}
{$define setzero:= status :=status or FLAG_ZERO}
{$define clearzero:= status:= status and not(FLAG_ZERO)}
{$define setinterrupt:= status :=status or FLAG_INTERRUPT}
{$define clearinterrupt:= status:= status and not(FLAG_INTERRUPT)}
{$define setdecimal:= status :=status or FLAG_DECIMAL}
{$define cleardecimal:= status := status and not(FLAG_DECIMAL)}
{$define setoverflow:= status :=status or FLAG_OVERFLOW}
{$define clearoverflow:= status := status and not(FLAG_OVERFLOW)}
{$define setsign:= status :=status or FLAG_SIGN}
{$define clearsign:= status := status and not(FLAG_SIGN)}
//6502 CPU registers
var pc:word;
var sp,a,x,y,status:byte;
//helper variables
var
oldpc,ea,reladdr,value,aresult:word;
opcode:byte;
penaltyop,penaltyaddr:byte;
csa,dsa,csi,dsi:integer;
// cs,ds:^integer;
function read6502(address:integer):byte;
begin
address:=address and $FFFF;
result:=peek(base+address); //ram[address and $FFFF];
end;
procedure write6502(address:integer; value:byte);
begin
address:=address and $FFFF;
poke(base+address,value); //ram[address and $FFFF]:=value;
end;
//a few general functions used by various other functions
procedure push32(pushval:cardinal);
begin
write6502(BASE_STACK+sp,(pushval shr 24) and $FF);
write6502(BASE_STACK+((sp-1) and $FF),(pushval shr 16) and $FF);
write6502(BASE_STACK+((sp-2) and $FF),(pushval shr 8) and $FF);
write6502(BASE_STACK+((sp-3) and $FF),pushval and $FF);
sp-=4;
end;
procedure push16(pushval:word);
begin
write6502(BASE_STACK+sp,(pushval shr 8) and $FF);
write6502(BASE_STACK+((sp-1) and $FF),pushval and $FF);
sp-=2;
end;
procedure push8(pushval:word);
begin
write6502(BASE_STACK+sp,pushval);
dec(sp);
end;
function pull32:cardinal;
var temp32:cardinal;
begin
temp32:=read6502(BASE_STACK + ((sp + 4) and $FF));
temp32:=(temp32 shl 8) + read6502(BASE_STACK + ((sp + 3) and $FF));
temp32:=(temp32 shl 8) + read6502(BASE_STACK + ((sp + 2) and $FF));
temp32:=(temp32 shl 8) + read6502(BASE_STACK + ((sp + 1) and $FF));
result:=temp32;
sp+=4;
end;
function pull16:word;
var temp16:word;
begin
temp16:=read6502(BASE_STACK + ((sp + 2) and $FF));
temp16:=(temp16 shl 8) + read6502(BASE_STACK + ((sp + 1) and $FF));
result:=temp16;
sp+=2;
end;
function pull8:byte;
begin
inc(sp);
result:=(read6502(BASE_STACK + sp));
end;
function getvalue:word;
var ea2:integer;
begin
ea2:=ea;
if (addrtable[opcode] = @acc) then
result:=a
else
result:=read6502(ea2);
end;
function getvalue16:word;
var ea2:integer;
begin
ea2:=ea;
result:=word(read6502(ea2)) or (word(read6502(ea2+1)) shl 8);
end;
function getvalue32:cardinal;
var ea2:integer;
begin
ea2:=ea;
result:=cardinal(read6502(ea2))
or (cardinal(read6502(ea2+1)) shl 8)
or (cardinal(read6502(ea2+2)) shl 16)
or (cardinal(read6502(ea2+3)) shl 24);
end;
procedure putvalue(saveval:word);
var ea2:integer;
begin
ea2:=ea;
if (addrtable[opcode] = @acc) then a := byte(saveval and $00FF) else write6502(ea2, (saveval and $00FF));
end;
procedure putvalue32(saveval:cardinal);
var ea2:integer;
begin
ea2:=ea;
write6502(ea2, (saveval and $000000FF));
write6502(ea2+1, ((saveval shl 8) and $000000FF));
write6502(ea2+2, ((saveval shl 16) and $000000FF));
write6502(ea2+3, ((saveval shl 24) and $000000FF));
end;
procedure reset6502;
begin
pc := word(read6502($FFFC)) or (word(read6502($FFFD) shl 8));
a := 0;
x := 0;
y := 0;
sp := $FD;
//ds:=@dsa;
//cs:=@csa;
//:=0; ds^:=0; csi:=0; dsi:=0;
status:=status or FLAG_CONSTANT;
clockgoal6502:=0;
instructions:=0;
clockticks6502:=0;
end;
procedure nmi6502;
begin
push16(pc);
push8(status);
status :=status or FLAG_INTERRUPT;
pc := word(read6502($FFFA)) or (word(read6502($FFFB)) << 8);
//cs:=@csi;
//ds:=@dsi;
end;
procedure irq6502;
begin
push16(pc);
push8(status);
status :=status or FLAG_INTERRUPT;
pc := word(read6502($FFFE)) or (word(read6502($FFFF)) << 8);
//cs:=@csi;
//ds:=@dsi;
end;
procedure exec6502(tickcount:integer);
begin
clockgoal6502 += tickcount;
while (clockticks6502 < clockgoal6502) do
begin
opcode := read6502(pc);
pc+=1;
// status := status or FLAG_CONSTANT;
penaltyop := 0;
penaltyaddr := 0;
addrtable[opcode];
optable[opcode];
clockticks6502 += ticktable[opcode];
if (penaltyop<>0) and (penaltyaddr<>0) then clockticks6502+=1;
instructions+=1;
end;
end;
procedure fast6502(tickcount:integer);
begin
clockgoal6502 += tickcount;
while (clockticks6502 < clockgoal6502) do
begin
opcode := read6502(pc);
pc+=1;
addrtable[opcode];
optable[opcode];
clockticks6502 += 1;
instructions+=1;
end;
end;
procedure step6502;
begin
opcode := read6502(pc);
pc+=1;
status :=status or FLAG_CONSTANT;
penaltyop := 0;
penaltyaddr := 0;
addrtable[opcode];
optable[opcode];
clockticks6502 += ticktable[opcode];
if (penaltyop<>0) and (penaltyaddr<>0) then clockticks6502+=1;
clockgoal6502 := clockticks6502;
instructions+=1;
end;
procedure jsr6502(aa:word; addr:integer);
var depth:integer;
begin
inc(jsrcnt) ;
//box(100,100,500,20,33);
//outtextxy(100,100,'entered jsr at '+inttohex(addr,4),44);
pc:=addr;
sp := $FD;
depth:=0;
if aa<256 then begin a:=aa; x:=0; y:=0; status:=0; end;
instructions:=0;
repeat
opcode := read6502(pc);
if opcode=$20 then inc(depth);
if opcode=$60 then dec(depth);
begin
pc+=1;
addrtable[opcode];
optable[opcode];
instructions+=1;
end;
until (depth<0) or (instructions>3000);
// box(100,200,500,20,33);
//outtextxy(100,200,'exited jsr after '+inttostr(instructions)+' jsr count '+inttostr(jsrcnt),44);
end;
//addressing mode functions, calculates effective addresses
procedure imp; //implied
begin
end;
procedure acc; //accumulator
begin
end;
procedure imm; //immediate
begin
ea := pc;
inc(pc);
end;
procedure zp; //zero-page
begin
ea := word(read6502(pc));
inc(pc);
end;
procedure zpx; //zero-page,X
begin
ea := ((read6502(pc)+x) and $FF); //zero-page wraparound
inc(pc)
end;
procedure zpy; //zero-page,Y
begin
ea := ((read6502(pc)+y) and $FF); //zero-page wraparound
inc(pc)
end;
procedure rel; //relative for branch ops (8-bit immediate value, sign-extended)
begin
reladdr := word(read6502(pc));
inc(pc);
if (reladdr and $80)<>0 then reladdr:=reladdr or $FF00;
end;
procedure abso; //absolute
begin
ea := word(read6502(pc)) or (word(read6502(pc+1)) shl 8);
pc += 2;
end;
procedure absx; //absolute,X
var startpage:word;
begin
ea := word(read6502(pc)) or (word(read6502(pc+1)) shl 8);
startpage := ea and $FF00;
ea += x;
if (startpage <> (ea and $FF00)) then penaltyaddr := 1; //one cycle penalty for page-crossing on some opcodes
pc += 2;
end;
procedure absy; //absolute,Y
var startpage:word;
begin
ea := word(read6502(pc)) or (word(read6502(pc+1)) shl 8);
startpage := ea and $FF00;
ea += y;
if (startpage <> (ea and $FF00)) then penaltyaddr := 1; //one cycle penalty for page-crossing on some opcodes
pc += 2;
end;
procedure ind; //indirect
var eahelp, eahelp2:word;
begin
eahelp := word(read6502(pc)) or (word(read6502(pc+1)) shl 8);
eahelp2 := (eahelp and $FF00) or ((eahelp + 1) and $00FF); //replicate 6502 page-boundary wraparound bug
ea := word(read6502(eahelp)) or (word(read6502(eahelp2)) shl 8);
pc += 2;
end;
procedure izp; // (indirect,zp)
var eahelp:word;
begin
eahelp := word(read6502(pc)) and $FF; //zero-page wraparound for table pointer
inc(pc);
ea := word(read6502(eahelp and $00FF)) or (word(read6502((eahelp+1) and $00FF)) shl 8);
end;
procedure indx; // (indirect,zp,X)
var eahelp:word;
begin
eahelp := (word(read6502(pc) + x) and $FF); //zero-page wraparound for table pointer
inc(pc);
ea := word(read6502(eahelp and $00FF)) or (word(read6502((eahelp+1) and $00FF)) shl 8);
end;
procedure iax; // (indirect,X)
var eahelp:word;
begin
eahelp := word(read6502(pc))+(word(read6502(pc+1) shl 8)+ y); //zero-page wraparound for table pointer
pc+=2;
ea := word(read6502(eahelp and $00FF)) or (word(read6502((eahelp+1) and $00FF)) shl 8);
end;
procedure indy; // (indirect),zp,Y
var eahelp, eahelp2, startpage: word;
begin
eahelp := word(read6502(pc));
inc(pc);
eahelp2 := (eahelp and $FF00) or ((eahelp + 1) and $00FF); //zero-page wraparound
ea := word(read6502(eahelp)) or (word(read6502(eahelp2)) shl 8);
startpage := ea and $FF00;
ea += y;
if (startpage <> (ea and $FF00)) then penaltyaddr := 1; //one cycle penalty for page-crossing on some opcodes
end;
// addr modes end
//instruction handler functions
procedure adc;
begin
penaltyop := 1;
value := getvalue;
aresult := word(value)+a+(status and FLAG_CARRY);
if (aresult and $FF00) <>0 then setcarry else clearcarry;
if (aresult and $00FF)<>0 then clearzero else setzero;
if ((aresult xor a) and (aresult xor value) and $0080)<>0 then
setoverflow
else
clearoverflow;
if (aresult and $0080)<>0 then setsign else clearsign;
if (status and FLAG_DECIMAL)<>0 then
begin
inc(clockticks6502);
clearcarry;
if ((a and $0F) > $09) then a += $06;
if ((a and $F0) > $90) then
begin
a += $60;
setcarry;
end;
end;
a:=byte(aresult and $00FF);
end;
procedure ana;
begin
penaltyop := 1;
value := getvalue;
aresult := a and value;
if (aresult and $00FF)<>0 then clearzero else setzero;
if (aresult and $0080)<>0 then setsign else clearsign;
a:=byte(aresult and $00FF);
end;
procedure asl;
begin
value := getvalue;
aresult := value shl 1;
if (aresult and $FF00) <>0 then setcarry else clearcarry;
if (aresult and $00FF)<>0 then clearzero else setzero;
if (aresult and $0080)<>0 then setsign else clearsign;
putvalue(aresult);
end;
procedure bcc;
begin
if ((status and FLAG_CARRY) = 0) then
begin
oldpc := pc;
pc += reladdr;
if ((oldpc and $FF00) <> (pc and $FF00)) then clockticks6502 += 2 //check if jump crossed a page boundary
else clockticks6502+=1;
end;
end;
procedure bcs;
begin
if ((status and FLAG_CARRY) = FLAG_CARRY) then
begin
oldpc := pc;
pc += reladdr;
if ((oldpc and $FF00) <> (pc and $FF00)) then clockticks6502 += 2 //check if jump crossed a page boundary
else clockticks6502+=1;
end;
end;
procedure beq;
begin
if ((status and FLAG_ZERO) = FLAG_ZERO) then
begin
oldpc := pc;
pc += reladdr;
if ((oldpc and $FF00) <> (pc and $FF00)) then clockticks6502 += 2 //check if jump crossed a page boundary
else clockticks6502+=1;
end;
end;
procedure bit;
begin
value := getvalue;;
aresult := a and value;
if (aresult and $00FF)<>0 then clearzero else setzero;
status := (status and $3F) or (value and $C0);
end;
procedure bmi;
begin
if ((status and FLAG_SIGN) = FLAG_SIGN) then
begin
oldpc := pc;
pc += reladdr;
if ((oldpc and $FF00) <> (pc and $FF00)) then clockticks6502 += 2 //check if jump crossed a page boundary
else clockticks6502+=1;
end;
end;
procedure bne;
begin
if ((status and FLAG_ZERO) = 0) then
begin
oldpc := pc;
pc += reladdr;
if ((oldpc and $FF00) <> (pc and $FF00)) then clockticks6502 += 2 //check if jump crossed a page boundary
else clockticks6502+=1;
end;
end;
procedure bpl;
begin
if ((status and FLAG_SIGN) = 0) then
begin
oldpc := pc;
pc += reladdr;
if ((oldpc and $FF00) <> (pc and $FF00)) then clockticks6502 += 2 //check if jump crossed a page boundary
else clockticks6502+=1;
end;
end;
procedure bra;
begin
oldpc := pc;
pc += reladdr;
if ((oldpc and $FF00) <> (pc and $FF00)) then clockticks6502 += 2 //check if jump crossed a page boundary
else clockticks6502+=1;
end;
procedure brk;
begin
pc+=1;
push16(pc); //push next instruction address onto stack
push8(status or FLAG_BREAK); //push CPU status to stack
setinterrupt; //set interrupt flag
pc := word(read6502($FFFE)) or (word(read6502($FFFF)) shl 8);
end;
procedure bvc;
begin
if ((status and FLAG_OVERFLOW) = 0) then
begin
oldpc := pc;
pc += reladdr;
if ((oldpc and $FF00) <> (pc and $FF00)) then clockticks6502 += 2 //check if jump crossed a page boundary
else clockticks6502+=1;
end;
end;
procedure bvs;
begin
if ((status and FLAG_OVERFLOW) = FLAG_OVERFLOW) then
begin
oldpc := pc;
pc += reladdr;
if ((oldpc and $FF00) <> (pc and $FF00)) then clockticks6502 += 2 //check if jump crossed a page boundary
else clockticks6502+=1;
end;
end;
procedure clc;
begin
clearcarry;
end;
procedure cld;
begin
cleardecimal;
end;
procedure cli;
begin
clearinterrupt;
end;
procedure clv;
begin
clearoverflow;
end;
procedure cmp;
begin
penaltyop := 1;
value := byte(getvalue);
aresult := word(a) - value;
if (a >= (value and $00FF)) then setcarry else clearcarry;
if (a = (byte(value and $00FF))) then setzero else clearzero;
if (aresult and $0080)<>0 then setsign else clearsign;
end;
procedure cpx;
begin
value := getvalue;;
aresult := word(x) - value;
if (x >= (value and $00FF)) then setcarry else clearcarry;
if (x = (byte(value and $00FF))) then setzero else clearzero;
if (aresult and $0080)<>0 then setsign else clearsign;
end;
procedure cpy;
begin
value := getvalue;;
aresult := word(y) - value;
if (y >= (value and $00FF)) then setcarry else clearcarry;
if (y = (value and $00FF)) then setzero else clearzero;
if (aresult and $0080)<>0 then setsign else clearsign;
end;
procedure dea;
begin
value := getvalue;;
aresult := value - 1;
if (aresult and $0080)<>0 then setsign else clearsign;
if (aresult and $00FF)<>0 then clearzero else setzero;
putvalue(aresult);
end;
procedure dex;
begin
x-=1;
if (x and $0080)<>0 then setsign else clearsign;
if (x and $00FF)<>0 then clearzero else setzero;
end;
procedure dey;
begin
y-=1;
if (y and $0080)<>0 then setsign else clearsign;
if (y and $00FF)<>0 then clearzero else setzero;
end;
procedure eor;
begin
penaltyop := 1;
value := getvalue;
aresult := a xor value;
if (aresult and $0080)<>0 then setsign else clearsign;
if (aresult and $00FF)<>0 then clearzero else setzero;
a:=byte(aresult and $00FF);
end;
procedure ina;
begin
value := getvalue;
aresult := value + 1;
if (aresult and $0080)<>0 then setsign else clearsign;
if (aresult and $00FF)<>0 then clearzero else setzero;
putvalue(aresult);
end;
procedure inx;
begin
x+=1;
if (x and $0080)<>0 then setsign else clearsign;
if (x and $00FF)<>0 then clearzero else setzero;
end;
procedure iny;
begin
y+=1;
if (y and $0080)<>0 then setsign else clearsign;
if (y and $00FF)<>0 then clearzero else setzero;
end;
procedure jmp;
begin
pc := ea;
end;
procedure jsr;
begin
push16(pc - 1);
pc := ea;
end;
procedure lda;
begin
penaltyop := 1;
value := getvalue;
a := (value and $00FF);
if (a and $0080)<>0 then setsign else clearsign;
if (a and $00FF)<>0 then clearzero else setzero;
end;
procedure ldc;
begin
//:=getvalue32 shl 8;
end;
procedure ldd;
begin
//ds^:=getvalue32 shl 8;
end;
procedure ldx;
begin
penaltyop := 1;
value := getvalue;
x := (value and $00FF);
if (x and $0080)<>0 then setsign else clearsign;
if (x and $00FF)<>0 then clearzero else setzero;
end;
procedure ldy;
begin
penaltyop := 1;
value := getvalue;;
y := (value and $00FF);
if (y and $0080)<>0 then setsign else clearsign;
if (y and $00FF)<>0 then clearzero else setzero;
end;
procedure lsr;
begin
value := getvalue and $FF;
aresult := value shr 1;
if (value and 1)=1 then setcarry else clearcarry;
if (aresult and $0080)<>0 then setsign else clearsign;
if (aresult and $00FF)<>0 then clearzero else setzero;
putvalue(aresult);
end;
procedure nop;
begin