-
Notifications
You must be signed in to change notification settings - Fork 2
/
Copy pathnutrients_plankton_bacteria_detritus.jl
319 lines (258 loc) · 13.8 KB
/
nutrients_plankton_bacteria_detritus.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
using Oceananigans
using Oceananigans.Units: day
using Oceananigans.Grids: znode, Center, AbstractTopology, Flat, Bounded
using Oceananigans.BoundaryConditions: ImpenetrableBoundaryCondition, fill_halo_regions!
using Oceananigans.Fields: ZeroField, ZFaceField
using Oceananigans.Biogeochemistry: AbstractBiogeochemistry
import Oceananigans.Biogeochemistry: required_biogeochemical_tracers, biogeochemical_drift_velocity
const c = Center()
struct NutrientsPlanktonBacteriaDetritus{FT, W} <: AbstractBiogeochemistry
maximum_plankton_growth_rate :: FT
maximum_bacteria_growth_rate :: FT
maximum_grazing_rate :: FT
bacteria_yield :: FT
zooplankton_yield :: FT
linear_remineralization_rate :: FT
linear_mortality_rate :: FT
quadratic_mortality_rate :: FT
quadratic_mortality_rate_Z :: FT
nutrient_half_saturation :: FT
detritus_half_saturation :: FT
grazing_half_saturation :: FT
PAR_half_saturation :: FT
PAR_attenuation_scale :: FT
detritus_vertical_velocity :: W
end
"""
NutrientsPlanktonBacteriaDetritus(; grid,
maximum_plankton_growth_rate = 1/day,
maximum_bacteria_growth_rate = 1/day
maximum_grazing_rate = 3/day
bacteria_yield = 0.2
zooplankton_yield = 0.3
linear_remineralization_rate = 0.03/day,
linear_mortality_rate = 0.01/day,
quadratic_mortality_rate = 0.1/day,
quadratic_mortality_rate_Z = 1/day,
nutrient_half_saturation = 0.1,
detritus_half_saturation = 0.1,
grazing_half_saturation = 3.0,
PAR_half_saturation = 10.0,
PAR_attenuation_scale = 25.0,
detritus_vertical_velocity = -10/day)
Return a six-tracer biogeochemistry model for the interaction of nutrients (N), phytoplankton (P),
zooplankton(Z), bacteria (B), dissolved detritus (D1), and particulate detritus (D2).
Keyword Arguments
=================
* `grid` (required): An Oceananigans' grid.
* `maximum_plankton_growth_rate`: (s⁻¹) Growth rate of plankton `P` unlimited by the
availability of nutrients and light. Default: 1/day.
* `maximum_bacteria_growth_rate`: (s⁻¹) Growth rate of plankton `B` unlimited by the
availability of nutrients and light. Default = 0.5/day.
* `maximum_grazing_rate`: (s⁻¹) Maximum grazing rate of phytoplankton by zooplankton.
* `bacteria_yield`: Determines fractional nutrient production by bacteria production
relative to consumption of detritus such that ``∂_t N / ∂_t D = 1 - y``,
where `y = bacteria_yield`. Default: 0.2.
* `linear_remineralization_rate`: (s⁻¹) Remineralization rate constant of detritus 'D',
assuming linear remineralization of 'D', while
implicitly modeling bacteria 'B'. Default = 0.3/day.
* `linear_mortality_rate`: (s⁻¹) Linear term of the mortality rate of both plankton and bacteria.
* `quadratic_mortality_rate`: (s⁻¹) Quadratic term of the mortality rate of both plankton and bacteria.
* `nutrient_half_saturation`: (mmol m⁻³) Half-saturation of nutrients for plankton production.
* `detritus_half_saturation`: (mmol m⁻³) Half-saturation of nutrients for bacteria production.
Default = 10.0 mmol m⁻³.
* `phytoplankton_half_saturation`: (mmol m⁻³) Half-saturation of phytoplankton for zooplankton production.
* `zooplankton_assimilation`: Fractional assimilation efficiency for zooplankton.
* `PAR_half_saturation`: (W m⁻²) Half-saturation of photosynthetically available radiation (PAR)
for plankton production.
* `PAR_attenuation_scale`: (m) Depth scale over which photosynthetically available radiation (PAR)
attenuates exponentially.
* `detritus_sinking_speed`: (m s⁻¹) Sinking velocity of particulate detritus.
Tracer names
============
* `N`: nutrients
* `P`: phytoplankton
* `Z`: zooplankton
* `B`: bacteria
* `D`: detritus
Biogeochemical functions
========================
* transitions for `N`, `P`, `Z`, `B`, `D`
* `biogeochemical_drift_velocity` for `D2`, modeling the sinking of detritus at
a constant `detritus_sinking_speed`.
"""
function NutrientsPlanktonBacteriaDetritus(grid;
maximum_plankton_growth_rate = 1/day, # Add reference for each parameter
maximum_bacteria_growth_rate = 1/day,
maximum_grazing_rate = 3/day,
bacteria_yield = 0.2,
zooplankton_yield = 0.3,
linear_remineralization_rate = 0.03/day,
linear_mortality_rate = 0.01/day, # m³/mmol/day
quadratic_mortality_rate = 0.1/day, # m³/mmol/day
quadratic_mortality_rate_Z = 1/day, # m³/mmol/day (zooplankton quadratic mortality)
nutrient_half_saturation = 0.1, # mmol m⁻³
detritus_half_saturation = 0.1, # mmol m⁻³
grazing_half_saturation = 3.0, # mmol m⁻³
PAR_half_saturation = 10.0, # W m⁻²
PAR_attenuation_scale = 25.0, # m
detritus_vertical_velocity = -10/day) # m s⁻¹
if detritus_vertical_velocity isa Number
w₀ = detritus_vertical_velocity
no_penetration = ImpenetrableBoundaryCondition()
bcs = FieldBoundaryConditions(grid, (Center, Center, Face),
top=no_penetration, bottom=no_penetration)
detritus_vertical_velocity = ZFaceField(grid, boundary_conditions = bcs)
set!(detritus_vertical_velocity, w₀)
fill_halo_regions!(detritus_vertical_velocity)
end
FT = eltype(grid)
return NutrientsPlanktonBacteriaDetritus(convert(FT, maximum_plankton_growth_rate),
convert(FT, maximum_bacteria_growth_rate),
convert(FT, maximum_grazing_rate),
convert(FT, bacteria_yield),
convert(FT, zooplankton_yield),
convert(FT, linear_remineralization_rate),
convert(FT, linear_mortality_rate),
convert(FT, quadratic_mortality_rate),
convert(FT, quadratic_mortality_rate_Z),
convert(FT, nutrient_half_saturation),
convert(FT, detritus_half_saturation),
convert(FT, grazing_half_saturation),
convert(FT, PAR_half_saturation),
convert(FT, PAR_attenuation_scale),
detritus_vertical_velocity)
end
const NPZBD = NutrientsPlanktonBacteriaDetritus
@inline required_biogeochemical_tracers(::NPZBD) = (:N, :P, :Z, :B, :D)
@inline function biogeochemical_drift_velocity(bgc::NPZBD, ::Val{:D})
u = ZeroField()
v = ZeroField()
w = bgc.detritus_vertical_velocity
return (; u, v, w)
end
# For implicit time stepping, consider:
#
# ∂t P ≈ (P⁺ - P⁻) / Δt = - m * P⁻
# -> P⁺ = P⁻ - Δt * m * P⁻
#
# (P⁺ - P⁻) / Δt = - m * P⁺
# -> P⁺ = P⁻ / (1 + Δt * m)
#
# A depth-dependent temperature curve from Zakem (2018)
# Temp = 12 .*exp.(z./ 150) .+ 12 .*exp.(z ./ 500) .+ 2
# Temperature modification to metabolic rates, following the Arrhenius equation
# @inline temp_fun(Temp) = 0.8 .* exp.(-4000 .*(1 ./ (Temp .+ 273.15) .- 1 ./ 293.15))
@inline bacteria_production(μᵇ, kᴰ, y, D, B) = y * μᵇ * D / (D + kᴰ) * B
@inline phytoplankton_production(μᵖ, kᴺ, kᴵ, I, N, P) = (μᵖ * min(N / (N + kᴺ) , I / (I + kᴵ)) * P)
@inline zooplankton_graze_phytoplankton(gₘ, kᵍ, γ, P, Z) = γ * gₘ * P / (P + kᵍ) * Z
@inline zooplankton_graze_bacteria(gₘ, kᵍ, γ, B, Z) = γ * gₘ * B / (B + kᵍ) * Z
@inline bacteria_mortality(mlin,mq, B) = mlin * B + mq * B^2
@inline phytoplankton_mortality(mlin,mq, P) = mlin * P + mq * P^2
@inline zooplankton_mortality(mlin,mq_Z, Z) = mlin * Z + mq_Z * Z^2
@inline detritus_remineralization(r, D) = r * D
@inline function (bgc::NutrientsPlanktonBacteriaDetritus)(i, j, k, grid, ::Val{:N}, clock, fields)
μᵖ = bgc.maximum_plankton_growth_rate
μᵇ = bgc.maximum_bacteria_growth_rate
r = bgc.linear_remineralization_rate
gₘ = bgc.maximum_grazing_rate
kᴰ = bgc.detritus_half_saturation
kᴺ = bgc.nutrient_half_saturation
kᵍ = bgc.grazing_half_saturation
kᴵ = bgc.PAR_half_saturation
λ = bgc.PAR_attenuation_scale
y = bgc.bacteria_yield
γ = bgc.zooplankton_yield
# Available photosynthetic radiation
z = znode(i, j, k, grid, c, c, c)
# TODO: design a user interface for prescribing incoming shortwave
I = 700 * exp(z / λ)
P = @inbounds fields.P[i, j, k]
Z = @inbounds fields.Z[i, j, k]
D = @inbounds fields.D[i, j, k]
B = @inbounds fields.B[i, j, k]
N = @inbounds fields.N[i, j, k]
if sum(B) > 0
return (- phytoplankton_production(μᵖ, kᴺ, kᴵ, I, N, P)
+ bacteria_production(μᵇ, kᴰ, y, D, B) * (1 / y - 1)
+ zooplankton_graze_phytoplankton(gₘ, kᵍ, γ, P, Z) * (1 / γ - 1)
+ zooplankton_graze_bacteria(gₘ, kᵍ, γ, B, Z) * (1 / γ - 1))
elseif sum(B) == 0
return (- phytoplankton_production(μᵖ, kᴺ, kᴵ, I, N, P)
+ detritus_remineralization(r, D)
+ zooplankton_graze_phytoplankton(gₘ, kᵍ, γ, P, Z) * (1 / γ - 1))
end
end
@inline function (bgc::NutrientsPlanktonBacteriaDetritus)(i, j, k, grid, ::Val{:P}, clock, fields)
μᵖ = bgc.maximum_plankton_growth_rate
gₘ = bgc.maximum_grazing_rate
kᴺ = bgc.nutrient_half_saturation
kᴵ = bgc.PAR_half_saturation
kᵍ = bgc.grazing_half_saturation
λ = bgc.PAR_attenuation_scale
mlin = bgc.linear_mortality_rate
mq = bgc.quadratic_mortality_rate
γ = bgc.zooplankton_yield
# Available photosynthetic radiation
z = znode(i, j, k, grid, c, c, c)
# TODO: design a user interface for prescribing incoming shortwave
I = 700 * exp(z / λ)
P = @inbounds fields.P[i, j, k]
Z = @inbounds fields.Z[i, j, k]
N = @inbounds fields.N[i, j, k]
return (phytoplankton_production(μᵖ, kᴺ, kᴵ, I, N, P)
- phytoplankton_mortality(mlin, mq, P)
- zooplankton_graze_phytoplankton(gₘ, kᵍ, γ, P, Z) / γ)
end
@inline function (bgc::NutrientsPlanktonBacteriaDetritus)(i, j, k, grid, ::Val{:Z}, clock, fields)
gₘ = bgc.maximum_grazing_rate
kᵍ = bgc.grazing_half_saturation
mlin = bgc.linear_mortality_rate
mq_Z = bgc.quadratic_mortality_rate_Z
γ = bgc.zooplankton_yield
P = @inbounds fields.P[i, j, k]
B = @inbounds fields.B[i, j, k]
Z = @inbounds fields.Z[i, j, k]
return (zooplankton_graze_phytoplankton(gₘ, kᵍ, γ, P, Z)
+ zooplankton_graze_bacteria(gₘ, kᵍ, γ, B, Z)
- zooplankton_mortality(mlin, mq_Z, Z))
end
@inline function (bgc::NutrientsPlanktonBacteriaDetritus)(i, j, k, grid, ::Val{:B}, clock, fields)
μᵇ = bgc.maximum_bacteria_growth_rate
gₘ = bgc.maximum_grazing_rate
kᴰ = bgc.detritus_half_saturation
kᵍ = bgc.grazing_half_saturation
mlin = bgc.linear_mortality_rate
mq = bgc.quadratic_mortality_rate
y = bgc.bacteria_yield
γ = bgc.zooplankton_yield
D = @inbounds fields.D[i, j, k]
B = @inbounds fields.B[i, j, k]
Z = @inbounds fields.Z[i, j, k]
return (bacteria_production(μᵇ, kᴰ, y, D, B)
- bacteria_mortality(mlin, mq, B)
- zooplankton_graze_bacteria(gₘ, kᵍ, γ, B, Z) / γ)
end
@inline function (bgc::NutrientsPlanktonBacteriaDetritus)(i, j, k, grid, ::Val{:D}, clock, fields)
μᵇ = bgc.maximum_bacteria_growth_rate
kᴰ = bgc.detritus_half_saturation
r = bgc.linear_remineralization_rate
y = bgc.bacteria_yield
mlin = bgc.linear_mortality_rate
mq = bgc.quadratic_mortality_rate
mq_Z = bgc.quadratic_mortality_rate_Z
P = @inbounds fields.P[i, j, k]
Z = @inbounds fields.Z[i, j, k]
D = @inbounds fields.D[i, j, k]
B = @inbounds fields.B[i, j, k]
if sum(B) > 0
return (bacteria_mortality(mlin, mq, B)
+ phytoplankton_mortality(mlin, mq, P)
+ zooplankton_mortality(mlin, mq_Z, Z)
- bacteria_production(μᵇ, kᴰ, y, D, B) / y)
elseif sum(B) == 0
return (phytoplankton_mortality(mlin, mq, P)
+ zooplankton_mortality(mlin, mq_Z, Z)
- detritus_remineralization(r, D))
end
end