build.gradle

plugins {
    id 'nebula.lint' version '20.3.0'
    id 'jacoco-report-aggregation'
}

dependencies {
    subprojects.forEach {
        jacocoAggregation it
    }
}

allprojects {
    repositories {
        mavenCentral()
        maven { url "https://jitpack.io" }
    }

    apply plugin: 'maven-publish'
    apply plugin: 'java-library'
    apply plugin: 'jacoco'
    apply plugin: 'checkstyle'
    apply plugin: 'pmd'
    apply plugin: 'nebula.lint'
    apply plugin: 'jacoco-report-aggregation'

    group 'no.unit.nva'
    version '0.5.10'

    java {
        sourceCompatibility = JavaVersion.VERSION_21
        targetCompatibility = JavaVersion.VERSION_21
    }


    gradleLint.rules = ['unused-dependency']

    def junit5Version = '5.11.3'

    dependencies {
        implementation group: 'jakarta.xml.bind', name: 'jakarta.xml.bind-api', version: '4.0.2'
        testImplementation group: 'org.hamcrest', name: 'hamcrest', version: '3.0'
        testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-api', version: junit5Version
        testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-engine', version: junit5Version
        testRuntimeOnly group: 'org.junit.platform', name: 'junit-platform-launcher', version: '1.11.3'
    }

    test {
        useJUnitPlatform()
        failFast = true
        testLogging {
            events = ['skipped', 'passed', 'failed']
        }
        finalizedBy jacocoTestReport
    }

    jacocoTestReport {
        reports {
            xml.required = true
        }
    }

    pmd {
        ruleSetConfig = rootProject.resources.text.fromFile('config/pmd/ruleset.xml')
        ruleSets = []
        ignoreFailures = false
        toolVersion = "7.8.0"
    }

    tasks.withType(Pmd).configureEach {
        exclude '**/org/datacite/schema/**'
    }

    checkstyle {
        configFile = rootProject.resources.text.fromFile('config/checkstyle/checkstyle.xml').asFile()
        showViolations = true
    }

    tasks.withType(Checkstyle).configureEach {
        exclude '**/org/datacite/schema/**'
    }

    tasks.withType(Checkstyle).configureEach {
        reports {
            xml.required = false
            html.required = true
            html.stylesheet rootProject.resources.text.fromFile('config/checkstyle/checkstyle-simple.xsl')
        }
    }

    check.dependsOn(jacocoTestCoverageVerification)
    jacocoTestCoverageVerification.dependsOn(jacocoTestReport)

    jacocoTestCoverageVerification {
        violationRules {
            rule {
                excludes = ['**datacite**']
                limit {
                    counter = 'METHOD'
                    value = 'COVEREDRATIO'
                    minimum = 1.00
                }
            }

            rule {
                excludes = ['**datacite**']
                limit {
                    counter = 'CLASS'
                    value = 'COVEREDRATIO'
                    minimum = 1.00
                }
            }
        }
    }

    tasks.named('check') {
        dependsOn tasks.named('testCodeCoverageReport', JacocoReport)
    }

    reporting {
        reports {
            testCodeCoverageReport(JacocoCoverageReport) {
                testType = TestSuiteType.UNIT_TEST
            }
        }
    }

    java {
        withSourcesJar()
    }

    publishing {
        publications {
            mavenJava(MavenPublication) {
                artifactId = project.name
                from components.java
                versionMapping {
                    usage('java-api') {
                        fromResolutionOf('runtimeClasspath')
                    }
                    usage('java-runtime') {
                        fromResolutionResult()
                    }
                }
            }
        }
    }
}